※現在、「wonderfl build flash online」求人コンテンツ制作に関してのアンケートを実施中です！みなさまのお力添えを頂いて、続々とアンケート結果が集まっていますが、まだまだ募集しております。ご協力のほど、どうぞよろしくお願いいたします！

wonderfl運営事務局
→アンケートページ（※ログインしてからお答えいただけるようになっています。）

 notice: Flash editor updated! Join the development! Thanks to MiniBuilder


embed

noswf download fullscreen
flash swf thumbnail play
reload download fullscreen

FORKED
>sort

直線や線分の交点を計算する forked from: 直線や線分の交点を計算する [diff(1)]

  1. // forked from obanetty's 直線や線分の交点を計算する
  2. package {
  3.     import flash.display.Sprite;
  4.     import flash.events.MouseEvent;
  5.     import flash.geom.Point;
  6.     import flash.display.Graphics;
  7.     public class LineTest extends Sprite {
  9.     //マウスドラッグの始点と終点
  10.     private var s_p:Point;
  11.     private var e_p:Point;
  12.     
  13.     //描画領域
  14.     private var canvas:Sprite;
  15.     //四角形の四辺を格納する配列
  16.     private var lineArray:Array;
  17.     
  18.     function LineTest():void{
  19.         
  20.         //四角形の四隅のポイント
  21.         var leftTop:Point = new Point(stage.stageWidth / 2 - 100, stage.stageHeight / 2 - 100);
  22.         var rightTop:Point = new Point(stage.stageWidth / 2 + 100, stage.stageHeight / 2 - 100);
  23.         var rightBottom:Point = new Point(stage.stageWidth / 2 + 100, stage.stageHeight / 2 + 100);
  24.         var leftBottom:Point = new Point(stage.stageWidth / 2 - 100, stage.stageHeight / 2 + 100);
  26.         //四角形の描画
  27.         var base:Sprite = new Sprite();
  28.         var g:Graphics = base.graphics;
  29.         base.x = base.y = 0;
  30.         stage.addChild(base);    
  31.         g.lineStyle(3, 0x000000);
  32.         g.drawRect(leftTop.x, leftTop.y, 200, 200);
  33.         
  34.         //四角形の４つの辺をLineインスタンスとして作成し、配列に格納
  35.         var line1:Line = new Line(leftTop, rightTop, Line.TYPE_SEGMENT);
  36.         var line2:Line = new Line(rightTop, rightBottom, Line.TYPE_SEGMENT);
  37.         var line3:Line = new Line(rightBottom, leftBottom, Line.TYPE_SEGMENT);
  38.         var line4:Line = new Line(leftBottom, leftTop, Line.TYPE_SEGMENT);
  39.         lineArray = [line1, line2, line3, line4];
  40.         
  41.         //赤線の描画領域を作成
  42.         canvas = new Sprite();
  43.         canvas.x = 0;
  44.         canvas.y = 0;
  45.         stage.addChild(canvas);
  46.         
  47.         stage.addEventListener(MouseEvent.MOUSE_DOWN, onMouseDown);
  48.     }
  49.     
  50.     private function onMouseDown(event:MouseEvent):void{
  51.         stage.removeEventListener(MouseEvent.MOUSE_DOWN, onMouseDown);
  52.         stage.addEventListener(MouseEvent.MOUSE_MOVE, onMouseMove);
  53.         stage.addEventListener(MouseEvent.MOUSE_UP, onMouseUp);
  54.         
  55.         //ドラッグ開始点の保存（線分の始点）
  56.         s_p = new Point(mouseX, mouseY);
  57.     }
  58.     
  59.     private function onMouseMove(event:MouseEvent):void{
  60.         //ドラッグ終了点の保存（線分の終点）
  61.         e_p = new Point(mouseX, mouseY);
  62.         
  63.         //マウスドラッグによりできた線分の描画
  64.         var g:Graphics = canvas.graphics;
  65.         g.clear();
  66.         g.lineStyle(3, 0xff0000);
  67.         g.moveTo(s_p.x, s_p.y);
  68.         g.lineTo(e_p.x, e_p.y);
  69.         
  70.         //描画された線分と四角形の四辺それぞれの交点を計算
  71.         var line:Line = new Line(s_p, e_p, Line.TYPE_SEGMENT);
  72.         lineArray.forEach(function(item:*, index:int, array:Array):void{
  73.             var p:Point = item.getIntersectionPoint(line);
  74.             if(p != null){
  75.                 //交点があれば円を描画
  76.                 g.beginFill(0xff0000);
  77.                 g.drawCircle(p.x, p.y, 10);
  78.             }
  79.         });
  80.     }
  81.     
  82.     private function onMouseUp(event:MouseEvent):void{
  83.         stage.removeEventListener(MouseEvent.MOUSE_MOVE, onMouseMove);
  84.         stage.removeEventListener(MouseEvent.MOUSE_UP, onMouseUp);
  85.         stage.addEventListener(MouseEvent.MOUSE_DOWN, onMouseDown);
  86.     }
  87.     }
  88. }
  90. import flash.geom.Point;
  91. import flash.display.Graphics;
  92.     
  93. class Line
  94. {
  95.     /* ２点を通る直線（終端はない） */
  96.     public static const TYPE_STRAIGHT:String = "straight";
  97.     /* p1からp2の方向に延びる半直線 */
  98.     public static const TYPE_HALF:String = "half";
  99.     /* p1, p2間の線分 */
  100.     public static const TYPE_SEGMENT:String = "segment";
  101.     
  102.     public var p1:Point;
  103.     public var p2:Point;
  104.     public var type:String;
  105.     
  106.     public function Line(p1:Point, p2:Point, type:String=TYPE_STRAIGHT)
  107.     {
  108.         this.p1 = p1;
  109.         this.p2 = p2;
  110.         this.type = type;
  111.     }
  112.     
  113.     /**
  114.      * 2つのLineインスタンスの交点を表わすPointインスタンスを取得する
  115.      * 交点がない場合はnullを返す
  116.      * @param line
  117.      * @return 
  118.      * 
  119.      */
  120.     public function getIntersectionPoint(line:Line):Point{
  121.         var vector1:Point = this.getVector();
  122.         var vector2:Point = line.getVector();
  123.         
  124.         if(cross(vector1, vector2) == 0.0){
  125.             //2直線が並行の場合はnullを返す
  126.             return null;
  127.         }
  128.         
  129.         // 交点を this.p1 + s * vector1 としたとき
  130.         var s:Number = cross(vector2, line.p1.subtract(this.p1)) / cross(vector2, vector1);
  131.         // 交点を line.p1 + t * vector2 としたとき
  132.         var t:Number = cross(vector1, this.p1.subtract(line.p1)) / cross(vector1, vector2);
  133.         
  134.         if(this.validateIntersect(s) && line.validateIntersect(t)){
  135.             vector1.x *= s;
  136.             vector1.y *= s;
  137.             return this.p1.add(vector1);
  138.         }else{
  139.             return null;
  140.         }
  141.     }
  142.     
  143.     public function getVector():Point{
  144.         return p2.subtract(p1);
  145.     }
  146.     
  147.     /**
  148.      * 交点までのベクトルを p1 + n * (p2 - p1) であらわしたとき、
  149.      * nが適切な値の範囲内かどうかを判定する。
  150.      * 
  151.      * 直線の場合：nはどの値でもよい
  152.      * 半直線の場合：nは0以上である必要がある
  153.      * 線分の場合：nは0以上1以下である必要がある
  154.      * @param n
  155.      * @return 
  156.      * 
  157.      */
  158.     private function validateIntersect(n:Number):Boolean{
  159.         if(this.type === TYPE_HALF){
  160.             return (0 <= n);
  161.         }else if(this.type === TYPE_SEGMENT){
  162.             return ((0 <= n) && (n <= 1));
  163.         }else{
  164.             return true;
  165.         }
  166.     }
  167.     
  168.     /**
  169.      * 2つの2次元ベクトルの外積を返す
  170.      * @param vector1 2次ベクトルを表わすPointインスタンス
  171.      * @param vector2 2次ベクトルを表わすPointインスタンス
  172.      * @return 
  173.      * 
  174.      */
  175.     private function cross(vector1:Point, vector2:Point):Number{
  176.         return (vector1.x * vector2.y - vector1.y * vector2.x);
  177.     }
  179.     public function toString():String{
  180.         var str:String = "";
  181.         if(type === TYPE_STRAIGHT){
  182.             str += "---> ";
  183.         }
  184.         str += "(" + p1.x + ", " + p1.y + ") ---> (" + p2.x + ", " + p2.y + ")";
  185.         if(type === TYPE_STRAIGHT || type === TYPE_HALF){
  186.             str += " --->";
  187.         }
  188.         
  189.         return str;
  190.     }
  191. }
noswf
Get Adobe Flash Player