※現在、「wonderfl build flash online」求人コンテンツ制作に関してのアンケートを実施中です！みなさまのお力添えを頂いて、続々とアンケート結果が集まっていますが、まだまだ募集しております。ご協力のほど、どうぞよろしくお願いいたします！

wonderfl運営事務局
→アンケートページ（※ログインしてからお答えいただけるようになっています。）

 notice: Flash editor updated! Join the development! Thanks to MiniBuilder


forked from : miniapp's 布 [diff(40)]

embed

noswf download fullscreen
flash swf thumbnail play
reload download fullscreen

FAVORITE BY
:
graphicsphysical布がゆれる　drawLine関数の中が違います
FORKED
>sort

GraphicsPathCommand使ったバージョン forked from: 布 forked from: GraphicsPathCommand使ったバージョン forked from: 布 [diff(1)]

  1. // forked from miniapp's GraphicsPathCommand使ったバージョン  forked from: 布
  2. /**
  3.  * GraphicsPathCommandでラインを描画するバージョン。
  4.  * drawLine関数の中が違います。
  5.  *
  6.  * 本格的な布のシミュレーションではありません。
  7.  * 
  8.  * ドラッグでマウスに一番近いポイントを移動させる。
  9.  * ctrlキー押しながらドラッグで固定。
  10.  * ダブルクリックで固定を解除。
  11.  */
  12. package {
  13.     import flash.display.GraphicsPathCommand;
  14.     import flash.display.Sprite;
  15.     import flash.display.StageQuality;
  16.     import flash.display.StageScaleMode;
  17.     import flash.events.Event;
  18.     import flash.events.KeyboardEvent;
  19.     import flash.events.MouseEvent;
  21.     [SWF(backgroundColor="0xFFFFFF", width="465", height="465", frameRate="60")]
  22.     public class Cloth_DrawPath extends Sprite {
  23.         
  24.         public static const STAGE_WIDTH:uint = 465;
  25.         public static const STAGE_HEIGHT:uint = 465;
  26.         
  27.         public function Cloth_DrawPath() {
  28.             if (stage) init();
  29.             else addEventListener(Event.ADDED_TO_STAGE, init);
  30.         }
  31.         
  32.         private var _lineColor:uint = 0x000000;
  33.         private var _cols:uint = 16;//横の数
  34.         private var _rows:uint = 16;//縦の数
  35.         private var _diffX:uint = 10;
  36.         private var _diffY:uint = 10;
  37.         private var _isCtrlPress:Boolean = false;
  38.         private var _isMouseDown:Boolean = false;
  39.         private var _draggedPoint:Point;
  40.         private var _isFirst:Boolean = false;
  41.         private var _numJoints:uint;
  42.         private var _joints:Vector.<Joint> = new Vector.<Joint>();
  43.         private var _points:Vector.<Point> = new Vector.<Point>();
  44.         private var _pointsXs:Vector.<Vector.<Point>> = new Vector.<Vector.<Point>>(_rows, true);
  45.         private var _pointsYs:Vector.<Vector.<Point>> = new Vector.<Vector.<Point>>(_cols, true);
  46.         
  47.         private var _vertices:Vector.<Number> = new Vector.<Number>();
  48.         private var _commands:Vector.<int> = new Vector.<int>();
  49.         
  50.         private function init(e:Event = null):void {
  51.             removeEventListener(Event.ADDED_TO_STAGE, init);
  52.             stage.scaleMode = StageScaleMode.NO_SCALE;
  53.             //stage.quality = StageQuality.MEDIUM;
  54.             
  55.             stage.doubleClickEnabled = true;
  56.             stage.addEventListener(MouseEvent.MOUSE_UP, mouseUpHandler);
  57.             stage.addEventListener(MouseEvent.MOUSE_DOWN, mouseDwonHandler);
  58.             stage.addEventListener(MouseEvent.DOUBLE_CLICK, doubleClickHandler);
  59.             stage.addEventListener(KeyboardEvent.KEY_DOWN, keyDonwHandler);
  60.             stage.addEventListener(KeyboardEvent.KEY_UP, keyUpHandler);
  61.             
  62.             putPoint();
  63.             joint();
  64.             
  65.             //上端2つを固定します。
  66.             //左端
  67.             var point1:Point = _pointsXs[0][0];
  68.             point1.x = 100;
  69.             point1.y = 10;
  70.             point1.isPinned = true;
  71.             
  72.             //右端
  73.             var point2:Point = _pointsXs[0][_rows - 1];
  74.             point2.x = STAGE_WIDTH - 100;
  75.             point2.y = 10;
  76.             point2.isPinned = true;
  77.             
  78.             addEventListener(Event.ENTER_FRAME, enterFrameHandler);
  79.         }
  80.         
  81.         /**
  82.          * ポイントを配置します。
  83.          */
  84.         private function putPoint():void {
  85.             //縦方向に並べたポイントを入れる配列を先に用意する
  86.             for (var i:uint = 0; i < _cols; i++) { 
  87.                 var pointsY:Vector.<Point> = new Vector.<Point>(_rows, true);
  88.                 _pointsYs[i] = pointsY;
  89.             }
  90.             
  91.             var clothWidth:Number = (_cols - 1) * _diffX;
  92.             var clothHeight:Number = (_rows - 1) * _diffY;
  93.             var startX:Number = (STAGE_WIDTH - clothWidth) / 2;
  94.             var startY:Number = (STAGE_HEIGHT - clothHeight) / 2;
  95.             
  96.             //ポイントを格子状に配置
  97.             for (i = 0; i < _rows; i++) {
  98.                 var pointsX:Vector.<Point> = new Vector.<Point>(_cols, true);
  99.                 _pointsXs[i] = pointsX;
  100.                 for (var j:uint = 0; j < _cols; j++) {
  101.                     var point:Point = new Point();
  102.                     _points.push(point);
  103.                     point.name = String(i) + "-" + String(j);//デバッグ用
  104.                     point.x = startX + _diffX * j;
  105.                     point.y = startY + _diffY * i;
  106.                     
  107.                     //横に並ぶポイントを入れる
  108.                     pointsX[j] = point;
  109.                     
  110.                     //縦方向に並ぶポイントを入れる
  111.                     pointsY = _pointsYs[j];
  112.                     pointsY[i] = point;
  113.                 }
  114.             }
  115.             _points.fixed = true;
  116.         }
  117.         
  118.         private function joint():void {
  119.             
  120.             //00------01-------02
  121.             //|        |       |
  122.             //|        |       |
  123.             //|        |       |
  124.             //10------11-------12
  125.             //|        |       |
  126.             //|        |       |
  127.             //|        |       |
  128.             //20------21-------22
  129.             
  130.             for (var i:uint = 0; i < _rows; i++) {
  131.                 var up:Boolean = (i - 1) >= 0;//上の行があるか。
  132.                 var down:Boolean = (i + 1) < _rows;//下の行があるか。
  133.                 if (up)
  134.                     var pointsX0:Vector.<Point> = _pointsXs[i - 1];//一つ上の段
  135.                     
  136.                 var pointsX1:Vector.<Point> = _pointsXs[i];
  137.                 
  138.                 if (down)
  139.                     var pointsX2:Vector.<Point> = _pointsXs[i + 1];//一つ下の段
  140.                 
  141.                 for (var j:uint = 0; j < _cols; j++) {
  142.                     var left:Boolean = (j - 1) >= 0;//左の列があるか。
  143.                     var right:Boolean = (j + 1) < _cols;//右の列があるか。
  144.                     
  145.                     var point11:Point = pointsX1[j];//中央のポイント
  146.                     
  147.                     if (up) {
  148.                         var point01:Point = pointsX0[j];//上
  149.                         //trace(point01.name);
  150.                         _joints.push(new Joint(point11, point01));
  151.                     }
  152.                     
  153.                     if (left) { 
  154.                         var point10:Point = pointsX1[j -1];//左
  155.                         //trace(point10.name);
  156.                         _joints.push(new Joint(point11, point10));
  157.                         
  158.                         if (up) {
  159.                             var point00:Point = pointsX0[j - 1]; //左上
  160.                             //trace(point00.name);
  161.                             _joints.push(new Joint(point11, point00));
  162.                         }
  163.                         
  164.                         if (down) {
  165.                             var point20:Point = pointsX2[j -1];//左下
  166.                             //trace(point20.name);
  167.                             _joints.push(new Joint(point11, point20));
  168.                         }
  169.                     }
  170.                     
  171.                     if (right) { 
  172.                         var point12:Point = pointsX1[j + 1];//右
  173.                         //trace(point12.name);
  174.                         _joints.push(new Joint(point11, point12));
  175.                         
  176.                         if (up) {
  177.                             var point02:Point = pointsX0[j + 1];//右上
  178.                             //trace(point02.name);
  179.                             _joints.push(new Joint(point11, point02));
  180.                         }
  181.                         
  182.                         if (down) {
  183.                             var point22:Point = pointsX2[j + 1];//右下
  184.                             //trace(point22.name);
  185.                             _joints.push(new Joint(point11, point22));
  186.                         }
  187.                     }
  188.                     
  189.                     if (down) {
  190.                         var point21:Point = pointsX2[j];//下
  191.                         //trace(point21.name);
  192.                         _joints.push(new Joint(point11, point21));
  193.                     }
  194.                 }
  195.             }
  196.             _numJoints = _joints.length;
  197.             _joints.fixed = true;
  198.         }
  199.         
  200.         /**
  201.          * 一番カーソルに近いポイントを捜す。
  202.          */
  203.         private function searchPoint():Point {
  204.             var lastMinDist:Number = Infinity;
  205.             var target:Point;
  206.             for each(var point:Point in _points) {
  207.                 var dx:Number = point.x - mouseX;
  208.                 var dy:Number = point.y - mouseY;
  209.                 var dist:Number = Math.sqrt(dx * dx + dy * dy);
  210.                 if (dist < lastMinDist) {
  211.                     lastMinDist = dist;
  212.                     target = point;
  213.                 }
  214.             }
  215.             return target;
  216.         }
  217.         
  218.         /**
  219.          * ポイント同士を繋ぐ線を書く
  220.          */
  221.         private function drawLine():void {
  222.             graphics.clear();
  223.             graphics.lineStyle(1, _lineColor);
  224.             
  225.             var dataIndex:uint = 0;
  226.             var commandIndex:uint = 0;
  227.             for each(var pointsX:Vector.<Point> in _pointsXs){
  228.                 //横列のポイントが入った配列にアクセス。
  229.                 var firstBall:Point = pointsX[0];
  230.                 _vertices[dataIndex++] = firstBall.x;
  231.                 _vertices[dataIndex++] = firstBall.y;
  232.                 _commands[commandIndex++] = GraphicsPathCommand.MOVE_TO;
  233.                 
  234.                 for (var i:uint = 1; i < _cols; i++) {
  235.                     var ball:Point = pointsX[i];
  236.                     _vertices[dataIndex++] = ball.x;
  237.                     _vertices[dataIndex++] = ball.y;
  238.                     _commands[commandIndex++] = GraphicsPathCommand.LINE_TO;
  239.                 }
  240.             }
  241.             
  242.             for each(var ballsY:Vector.<Point> in _pointsYs) {
  243.                 firstBall = ballsY[0];
  244.                 _vertices[dataIndex++] = firstBall.x;
  245.                 _vertices[dataIndex++] = firstBall.y;
  246.                 _commands[commandIndex++] = GraphicsPathCommand.MOVE_TO;
  247.                 
  248.                 for (i = 1; i < _rows; i++) {
  249.                     ball = ballsY[i];
  250.                     _vertices[dataIndex++] = ball.x;
  251.                     _vertices[dataIndex++] = ball.y;
  252.                     _commands[commandIndex++] = GraphicsPathCommand.LINE_TO;
  253.                 }
  254.             }
  255.             if(_isFirst){
  256.                 _commands.fixed = _vertices.fixed = true;
  257.                 _isFirst = false;
  258.             }
  259.             graphics.drawPath(_commands, _vertices);
  260.         }
  261.         
  262.         private function enterFrameHandler(e:Event):void {
  263.             if (_isMouseDown) {
  264.                 _draggedPoint.x = mouseX;
  265.                 _draggedPoint.y = mouseY;
  266.             }
  267.             
  268.             for each(var joint:Joint in _joints) {
  269.                 joint.update();
  270.             }
  271.             
  272.             drawLine();
  273.         }
  274.         
  275.         private function keyDonwHandler(e:KeyboardEvent = null):void{
  276.             if(e.ctrlKey) _isCtrlPress = true;
  277.         }
  278.         
  279.         private function keyUpHandler(e:KeyboardEvent = null):void{
  280.             _isCtrlPress = false;
  281.         }
  282.         
  283.         private function doubleClickHandler(e:MouseEvent = null):void{
  284.             searchPoint().isPinned = false;
  285.         }
  286.         
  287.         private function mouseDwonHandler(e:MouseEvent):void {
  288.             _isMouseDown = true;
  289.             _draggedPoint = searchPoint();
  290.             _draggedPoint.isDragging = true;
  291.         }
  292.         
  293.         private function mouseUpHandler(e:MouseEvent):void    {
  294.             _isMouseDown = false;
  295.             if (_isCtrlPress)
  296.                 _draggedPoint.isPinned = true;
  297.             _draggedPoint.isDragging = false;
  298.             _draggedPoint = undefined;
  299.         }
  300.     }
  301. }
  303. class Joint {
  304.     
  305.     public static var SPRING:Number = 0.03;
  306.     public static var FRICTION:Number = 0.97;
  307.     public static var GRAVITY:Number = 0.005;
  308.     
  309.     public function Joint(point:Point, target:Point) { 
  310.         var initDx:Number = target.x - point.x;
  311.         var initDy:Number = target.y - point.y;
  312.         var length:Number = Math.sqrt(initDx * initDx + initDy * initDy);
  313.         var angle:Number = Math.atan2(initDy, initDx);
  314.         
  315.         var tx:Number = length * Math.cos(angle);
  316.         var ty:Number = length * Math.sin(angle);
  317.         
  318.         //バネ運動させる関数
  319.         update = function():void {
  320.             if (point.isDragging || point.isPinned)
  321.                 return;
  322.             
  323.             var dx:Number = target.x - tx - point.x;
  324.             var dy:Number = target.y - ty - point.y;
  325.             point.vx += dx * Joint.SPRING;
  326.             point.vy += dy * Joint.SPRING;
  327.             point.vy += GRAVITY;
  328.             point.x += (point.vx *= FRICTION);
  329.             point.y += (point.vy *= FRICTION);
  330.         }
  331.     }
  332.     
  333.     public var update:Function;
  334. }
  336. class Point {
  337.     public var name:String;
  338.     public var x:Number;
  339.     public var y:Number;
  340.     public var vx:Number = 0;
  341.     public var vy:Number = 0;
  342.     public var isPinned:Boolean = false;
  343.     public var isDragging:Boolean = false;
  344. }
noswf
Get Adobe Flash Player