notice: Flash editor updated! Join the development! Thanks to MiniBuilder


forked from : fladdict's FITC: Cool Japan side A / Particle sample of SMOKE [diff(2)]

embed

noswf download fullscreen
flash swf thumbnail play
download fullscreen
FORKED
>sort

forked from: FITC: Cool Japan side A / Particle sample of SMOKE without blur effect forked from: forked from: FITC: Cool Japan side A / Particle sample of SMOKE without blur effect [diff(1)]

  1. // forked from fladdict's forked from: FITC: Cool Japan side A / Particle sample of SMOKE without blur effect
  2. // forked from fladdict's FITC: Cool Japan side A / Particle sample of SMOKE
  3. /**
  4. * 
  5. * Sample code for FITC
  6. * Smoke particle effect
  7. * 
  8. */
  9. package {
  10.     import flash.display.Sprite;    
  11.     import flash.display.Bitmap;
  12.     import flash.display.BitmapData;
  13.     import flash.display.BlendMode;
  14.     import flash.events.Event;
  15.     import flash.filters.BlurFilter;
  16.     import flash.geom.ColorTransform;
  17.     import flash.geom.Matrix;
  18.     import flash.geom.Point;
  19.     import flash.utils.ByteArray;
  20.     
  21.     public class FlashTest extends Sprite {
  22.        //View
  23.         protected var canvas:BitmapData;
  24.         protected var canvasBitmap:Bitmap;
  25.         
  26.         //BitmapData that contains the actual froce that is applied to particles.
  27.         protected var forceMap:BitmapData;
  28.         
  29.         //BitmapData that contains the force of the storm.
  30.         protected var stormMap0:BitmapData;
  31.         protected var stormMap1:BitmapData;
  32.         
  33.         //BitmapData that contains the mouse repulsion force of the stage.
  34.         protected var repulsionMap:BitmapData;
  35.         protected var repulsionHistoryMap:BitmapData;
  36.         protected var repulsionFadeMap:BitmapData;
  37.         
  38.         //the number of particles. 5000-200000
  39.         protected var particleNum:int = 10000;
  40.         protected var particles:Vector.<Particle>
  41.         
  42.         //
  43.         protected var stormScaleRatioX:Number;
  44.         protected var stormScaleRatioY:Number;
  45.         protected var stormCycle:Number = 0;
  46.         
  47.         //color transform that guradually changes canvas.
  48.         protected var fadeCanvasColt:ColorTransform;
  49.         protected var canvasBlurFilter:BlurFilter;
  50.         
  51.         //temporaly variables
  52.         protected var tempColt:ColorTransform = new ColorTransform();
  53.         protected var tempPt:Point = new Point();
  54.         protected var tempMat:Matrix = new Matrix();
  55.         
  56.         public function FlashTest() {
  57.             init();
  58.             reset();
  59.         }
  60.         
  61.         protected function init():void
  62.         {
  63.             //build View
  64.             canvasBitmap = new Bitmap(null, "auto", false);
  65.             // because canvas is 25% size of screen, we make view 400% bigger.
  66.             canvasBitmap.scaleX = 4;
  67.             canvasBitmap.scaleY = 4;
  68.             addChild(canvasBitmap);
  69.             
  70.             //initialize the map that contains force of the storm;
  71.             stormMap0 = new BitmapData(256,256,false,0x000000);
  72.             stormMap0.perlinNoise(128,128,3,Math.random()*100,false,true,3,false);
  73.             stormMap1 = new BitmapData(256,256,false,0x000000);
  74.             stormMap1.perlinNoise(128,128,3,Math.random()*100,false,true,3,false);
  75.             
  76.             //
  77.             forceMap = new BitmapData(256,256,false,0x000000);
  78.             
  79.             //initialize repulsionMap
  80.             repulsionHistoryMap = new BitmapData(256,256,false,0x000000);
  81.             repulsionFadeMap = new BitmapData(256,256,true,0x20808000);
  82.             repulsionMap = new BitmapData(256,256,false,0);
  83.             
  84.             /**
  85.             * First we preculculate the repulsion force field that mouse cursor generates as a bitmapdata. 
  86.             * Red channel of bitmap data contains horizontal force.
  87.             * Green channel of bitmap data contains vertical force. 
  88.             */
  89.             var dx:int, dy:int;
  90.             var dist:Number, fx:Number, fy:Number;
  91.             var col:int;
  92.             for(var yy:int=0; yy<256; yy++)
  93.             {
  94.                 for(var xx:int=0; xx<256; xx++){
  95.                     dx = xx-128;
  96.                     dy = yy-128;
  97.                     dist = Math.sqrt(dx*dx+dy*dy);
  98.                     if(dist<1){
  99.                         fx = 0;
  100.                         fy = 0;
  101.                     }else{
  102.                         fx = dx / dist / dist / dist * 50000;
  103.                         fy = dy / dist / dist / dist * 50000;
  104.                     }
  105.                     fx = (fx<-128)? -128 : (fx>127)? 127 : fx;
  106.                     fy = (fy<-128)? -128 : (fy>127)? 127 : fy;
  107.                     fx += 128;
  108.                     fy += 128;
  109.                     col = (fx<<16) + (fy<<8)
  110.                     repulsionMap.setPixel(xx,yy,col);
  111.                 }
  112.             }
  113.             //You can see 
  114.             canvasBitmap.bitmapData = repulsionMap;
  115.             
  116.             //initialize particle
  117.             particles = new Vector.<Particle>(particleNum);
  118.             
  119.             var particle:Particle;
  120.             var rr:int;
  121.             for(var i:int=0; i<particleNum; i++)
  122.             {
  123.                 particle = new Particle();
  124.                 particle.x = Math.random() * stage.stageWidth >> 2;
  125.                 particle.y = Math.random() * stage.stageHeight >> 2;
  126.                 
  127.                 //Customize the range of the particle color according to the amount of the particle and stage size.
  128.                 particle.r = particle.g = particle.b = Math.min(Math.random()*8+4,255);  
  129.                 
  130.                 //Customize the rage of the scaleFactor according to the amount of the particle and stage size.
  131.                 particle.scaleFactor = (Math.random()*0.1 + 0.95) * 0.003;
  132.                 particles[i] = particle;
  133.             }
  134.             
  135.             fadeCanvasColt = new ColorTransform(1,1,1,1,-2,-1,-1,0);
  136.             canvasBlurFilter = new BlurFilter(2,2,3);
  137.             
  138.             //set event listeners
  139.             stage.addEventListener(Event.ENTER_FRAME, enterFrameHandler);
  140.             stage.addEventListener(Event.RESIZE, resizeHandler);
  141.         }
  142.         
  143.         /**
  144.         *
  145.         * Called when you need reset the view. E.G. resizing screen.
  146.         */
  147.         protected function reset():void
  148.         {
  149.             if(canvas)
  150.                 canvas.dispose();
  151.                 
  152.             //build view, to optimize we use 25% size BitmapData of actual screensize.
  153.             canvas = new BitmapData((stage.stageWidth>>2)+1, (stage.stageHeight>>2)+1, false, 0x000000);
  154.             canvasBitmap.bitmapData = canvas;
  155.             
  156.             //precalculate ratio that converts screen coordinate to stomMapBitmap coodinate;
  157.             stormScaleRatioX = 1 / (stage.stageWidth>>2)*255;
  158.             stormScaleRatioY = 1 / (stage.stageHeight>>2)*255;
  159.             
  160.            //canvasBitmap.bitmapData = stormMap1;  //if you want to see stormMap;
  161.            //canvasBitmap.bitmapData = repulsionHistoryMap;
  162.            //canvasBitmap.bitmapData = forceMap; //if you want to see forceMap;
  163.            
  164.            //canvasBitmap.scaleX = 1;
  165.            //canvasBitmap.scaleY = 1;
  166.         }
  167.         
  168.         
  169.         //We rebuild screen when swf is reseized.
  170.         //It is not required if you only run it on wonderfl.
  171.         protected function resizeHandler(e:Event):void
  172.         {
  173.             reset();
  174.         }
  176.         
  177.         //Update storm and particle every frame.
  178.         protected function enterFrameHandler(e:Event):void
  179.         { 
  180.            updateStormMap();
  181.            updateRepulsionMap();
  182.            updateForceMap();
  183.            updateParticles();
  184.         }
  185.         
  186.         /**
  187.         * We calculate current forcefielde's state by blending two stormMap.
  188.         * Therefore force field gradually changes every frame.
  189.         */
  190.         protected function updateStormMap():void
  191.         {
  192.             stormCycle++;
  193.             if(stormCycle == 180){
  194.                 stormMap0.perlinNoise(256,256,3,Math.random()*100,false,true,3,false);
  195.             }else if(stormCycle==360){
  196.                 stormMap1.perlinNoise(256,256,3,Math.random()*100,false,true,3,false);
  197.                 stormCycle = 0;
  198.             }
  199.         }
  200.         
  201.         /**
  202.         * We update repulsionMap according to the current mouse position.
  203.         */
  204.         protected function updateRepulsionMap():void
  205.         {
  206.             tempMat.a = 1;
  207.             tempMat.b = 0;
  208.             tempMat.c = 0;
  209.             tempMat.d = 1;
  210.             tempMat.tx = 0;
  211.             tempMat.ty = 0;
  212.             
  213.             repulsionHistoryMap.draw(repulsionFadeMap, tempMat);
  214.             
  215.             tempMat.translate(-128,-128);
  216.             tempMat.translate(mouseX, mouseY);
  217.             tempMat.scale(1/stormScaleRatioX, 1/stormScaleRatioY);
  218.             repulsionHistoryMap.draw(repulsionMap, tempMat, null, BlendMode.HARDLIGHT);
  219.         }
  220.         
  221.         protected function updateForceMap():void
  222.         {
  223.             //generate current force fieldes state with blending two stormMaps.
  224.             forceMap.copyPixels(stormMap1, stormMap0.rect, tempPt);
  225.             tempColt.alphaMultiplier = Math.cos(stormCycle*Math.PI/180)*0.5+0.5;
  226.             forceMap.draw(stormMap0, null, tempColt);
  227.             
  228.             //add mouse repulsion force
  229.             forceMap.draw(repulsionHistoryMap,null,null,BlendMode.HARDLIGHT);
  230.             forceMap.draw(repulsionHistoryMap,null,null,BlendMode.HARDLIGHT);
  231.         }
  232.         
  233.         protected function updateParticles():void
  234.         {
  235.             var forceBytes:ByteArray = forceMap.getPixels(forceMap.rect);
  236.             
  237.             var stageW:int = canvas.width;
  238.             var stageH:int = canvas.height;
  239.             var loopW:int = stageW-1;
  240.             var loopH:int = stageH-1;
  241.             var byteIndex:int;
  242.             
  243.             canvas.lock();
  244.             canvas.colorTransform(canvas.rect, fadeCanvasColt);
  245.             
  246.             //Update Paritcle position and draw.
  247.             var col:int, r:int, g:int, b:int;
  248.             for(var i:int=0; i<particleNum; i++)
  249.             {
  250.                 var prt:Particle = particles[i];
  251.                 byteIndex = (int(prt.y*stormScaleRatioY)*256 + int(prt.x*stormScaleRatioX))<<2;
  252.                 prt.vx = prt.vx * 0.96 + (forceBytes[byteIndex+1]-128)*prt.scaleFactor;
  253.                 prt.vy = prt.vy * 0.96 + (forceBytes[byteIndex+2]-128)*prt.scaleFactor;
  254.                 prt.x += prt.vx;
  255.                 prt.y += prt.vy;
  256.                 if(prt.x<0){
  257.                     prt.x = loopW;
  258.                 }else if(prt.x > loopW){
  259.                     prt.x = 1;
  260.                 }
  261.                 if(prt.y<0){
  262.                     prt.y = loopH;
  263.                 }else if(prt.y > loopH){
  264.                     prt.y = 1;
  265.                 }
  266.                 
  267.                 //Self implimentation of addtive color blend mode.
  268.                 //Because there is too many particle, blending particle with low brightness color is much effective.
  269.                 col = canvas.getPixel(int(prt.x), int(prt.y));
  270.                 r = (col>>16&0xff) + prt.r;
  271.                 g = (col>>8&0xff) + prt.g;
  272.                 b = (col&0xff) + prt.b;
  273.                 r = (r<0xff)? r : 0xff;
  274.                 g = (g<0xff)? g : 0xff;
  275.                 b = (b<0xff)? b : 0xff;
  276.                 canvas.setPixel(int(prt.x), int(prt.y), (r<<16)|(g<<8)|b);
  277.             }
  278.             canvas.unlock();
  279.         }
  280.     }
  281.     
  282. }
  285. class Particle
  286. {
  287.     //particle position
  288.     public var x:Number = 0;
  289.     public var y:Number = 0;
  290.     public var vx:Number = 0;
  291.     public var vy:Number = 0;
  292.     
  293.     //particle color
  294.     public var r:int;
  295.     public var g:int;
  296.     public var b:int;
  297.     
  298.     //scale factor that affects the force applied to the particle.
  299.     public var scaleFactor:Number;
  300. }
noswf

forked from: FITC: Cool Japan side A / Particle sample of SMOKE without blur effect forked from: forked from: FITC: Cool Japan side A / Particle sample of SMOKE without blur effect [diff(1)]

  1. // forked from fladdict's forked from: FITC: Cool Japan side A / Particle sample of SMOKE without blur effect
  2. // forked from fladdict's FITC: Cool Japan side A / Particle sample of SMOKE
  3. /**
  4. * 
  5. * Sample code for FITC
  6. * Smoke particle effect
  7. * 
  8. */
  9. package {
  10.     import flash.display.Sprite;    
  11.     import flash.display.Bitmap;
  12.     import flash.display.BitmapData;
  13.     import flash.display.BlendMode;
  14.     import flash.events.Event;
  15.     import flash.filters.BlurFilter;
  16.     import flash.geom.ColorTransform;
  17.     import flash.geom.Matrix;
  18.     import flash.geom.Point;
  19.     import flash.utils.ByteArray;
  20.     
  21.     public class FlashTest extends Sprite {
  22.        //View
  23.         protected var canvas:BitmapData;
  24.         protected var canvasBitmap:Bitmap;
  25.         
  26.         //BitmapData that contains the actual froce that is applied to particles.
  27.         protected var forceMap:BitmapData;
  28.         
  29.         //BitmapData that contains the force of the storm.
  30.         protected var stormMap0:BitmapData;
  31.         protected var stormMap1:BitmapData;
  32.         
  33.         //BitmapData that contains the mouse repulsion force of the stage.
  34.         protected var repulsionMap:BitmapData;
  35.         protected var repulsionHistoryMap:BitmapData;
  36.         protected var repulsionFadeMap:BitmapData;
  37.         
  38.         //the number of particles. 5000-200000
  39.         protected var particleNum:int = 10000;
  40.         protected var particles:Vector.<Particle>
  41.         
  42.         //
  43.         protected var stormScaleRatioX:Number;
  44.         protected var stormScaleRatioY:Number;
  45.         protected var stormCycle:Number = 0;
  46.         
  47.         //color transform that guradually changes canvas.
  48.         protected var fadeCanvasColt:ColorTransform;
  49.         protected var canvasBlurFilter:BlurFilter;
  50.         
  51.         //temporaly variables
  52.         protected var tempColt:ColorTransform = new ColorTransform();
  53.         protected var tempPt:Point = new Point();
  54.         protected var tempMat:Matrix = new Matrix();
  55.         
  56.         public function FlashTest() {
  57.             init();
  58.             reset();
  59.         }
  60.         
  61.         protected function init():void
  62.         {
  63.             //build View
  64.             canvasBitmap = new Bitmap(null, "auto", false);
  65.             // because canvas is 25% size of screen, we make view 400% bigger.
  66.             canvasBitmap.scaleX = 4;
  67.             canvasBitmap.scaleY = 4;
  68.             addChild(canvasBitmap);
  69.             
  70.             //initialize the map that contains force of the storm;
  71.             stormMap0 = new BitmapData(256,256,false,0x000000);
  72.             stormMap0.perlinNoise(128,128,3,Math.random()*100,false,true,3,false);
  73.             stormMap1 = new BitmapData(256,256,false,0x000000);
  74.             stormMap1.perlinNoise(128,128,3,Math.random()*100,false,true,3,false);
  75.             
  76.             //
  77.             forceMap = new BitmapData(256,256,false,0x000000);
  78.             
  79.             //initialize repulsionMap
  80.             repulsionHistoryMap = new BitmapData(256,256,false,0x000000);
  81.             repulsionFadeMap = new BitmapData(256,256,true,0x20808000);
  82.             repulsionMap = new BitmapData(256,256,false,0);
  83.             
  84.             /**
  85.             * First we preculculate the repulsion force field that mouse cursor generates as a bitmapdata. 
  86.             * Red channel of bitmap data contains horizontal force.
  87.             * Green channel of bitmap data contains vertical force. 
  88.             */
  89.             var dx:int, dy:int;
  90.             var dist:Number, fx:Number, fy:Number;
  91.             var col:int;
  92.             for(var yy:int=0; yy<256; yy++)
  93.             {
  94.                 for(var xx:int=0; xx<256; xx++){
  95.                     dx = xx-128;
  96.                     dy = yy-128;
  97.                     dist = Math.sqrt(dx*dx+dy*dy);
  98.                     if(dist<1){
  99.                         fx = 0;
  100.                         fy = 0;
  101.                     }else{
  102.                         fx = dx / dist / dist / dist * 50000;
  103.                         fy = dy / dist / dist / dist * 50000;
  104.                     }
  105.                     fx = (fx<-128)? -128 : (fx>127)? 127 : fx;
  106.                     fy = (fy<-128)? -128 : (fy>127)? 127 : fy;
  107.                     fx += 128;
  108.                     fy += 128;
  109.                     col = (fx<<16) + (fy<<8)
  110.                     repulsionMap.setPixel(xx,yy,col);
  111.                 }
  112.             }
  113.             //You can see 
  114.             canvasBitmap.bitmapData = repulsionMap;
  115.             
  116.             //initialize particle
  117.             particles = new Vector.<Particle>(particleNum);
  118.             
  119.             var particle:Particle;
  120.             var rr:int;
  121.             for(var i:int=0; i<particleNum; i++)
  122.             {
  123.                 particle = new Particle();
  124.                 particle.x = Math.random() * stage.stageWidth >> 2;
  125.                 particle.y = Math.random() * stage.stageHeight >> 2;
  126.                 
  127.                 //Customize the range of the particle color according to the amount of the particle and stage size.
  128.                 particle.r = particle.g = particle.b = Math.min(Math.random()*8+4,255);  
  129.                 
  130.                 //Customize the rage of the scaleFactor according to the amount of the particle and stage size.
  131.                 particle.scaleFactor = (Math.random()*0.1 + 0.95) * 0.003;
  132.                 particles[i] = particle;
  133.             }
  134.             
  135.             fadeCanvasColt = new ColorTransform(1,1,1,1,-2,-1,-1,0);
  136.             canvasBlurFilter = new BlurFilter(2,2,3);
  137.             
  138.             //set event listeners
  139.             stage.addEventListener(Event.ENTER_FRAME, enterFrameHandler);
  140.             stage.addEventListener(Event.RESIZE, resizeHandler);
  141.         }
  142.         
  143.         /**
  144.         *
  145.         * Called when you need reset the view. E.G. resizing screen.
  146.         */
  147.         protected function reset():void
  148.         {
  149.             if(canvas)
  150.                 canvas.dispose();
  151.                 
  152.             //build view, to optimize we use 25% size BitmapData of actual screensize.
  153.             canvas = new BitmapData((stage.stageWidth>>2)+1, (stage.stageHeight>>2)+1, false, 0x000000);
  154.             canvasBitmap.bitmapData = canvas;
  155.             
  156.             //precalculate ratio that converts screen coordinate to stomMapBitmap coodinate;
  157.             stormScaleRatioX = 1 / (stage.stageWidth>>2)*255;
  158.             stormScaleRatioY = 1 / (stage.stageHeight>>2)*255;
  159.             
  160.            //canvasBitmap.bitmapData = stormMap1;  //if you want to see stormMap;
  161.            //canvasBitmap.bitmapData = repulsionHistoryMap;
  162.            //canvasBitmap.bitmapData = forceMap; //if you want to see forceMap;
  163.            
  164.            //canvasBitmap.scaleX = 1;
  165.            //canvasBitmap.scaleY = 1;
  166.         }
  167.         
  168.         
  169.         //We rebuild screen when swf is reseized.
  170.         //It is not required if you only run it on wonderfl.
  171.         protected function resizeHandler(e:Event):void
  172.         {
  173.             reset();
  174.         }
  176.         
  177.         //Update storm and particle every frame.
  178.         protected function enterFrameHandler(e:Event):void
  179.         { 
  180.            updateStormMap();
  181.            updateRepulsionMap();
  182.            updateForceMap();
  183.            updateParticles();
  184.         }
  185.         
  186.         /**
  187.         * We calculate current forcefielde's state by blending two stormMap.
  188.         * Therefore force field gradually changes every frame.
  189.         */
  190.         protected function updateStormMap():void
  191.         {
  192.             stormCycle++;
  193.             if(stormCycle == 180){
  194.                 stormMap0.perlinNoise(256,256,3,Math.random()*100,false,true,3,false);
  195.             }else if(stormCycle==360){
  196.                 stormMap1.perlinNoise(256,256,3,Math.random()*100,false,true,3,false);
  197.                 stormCycle = 0;
  198.             }
  199.         }
  200.         
  201.         /**
  202.         * We update repulsionMap according to the current mouse position.
  203.         */
  204.         protected function updateRepulsionMap():void
  205.         {
  206.             tempMat.a = 1;
  207.             tempMat.b = 0;
  208.             tempMat.c = 0;
  209.             tempMat.d = 1;
  210.             tempMat.tx = 0;
  211.             tempMat.ty = 0;
  212.             
  213.             repulsionHistoryMap.draw(repulsionFadeMap, tempMat);
  214.             
  215.             tempMat.translate(-128,-128);
  216.             tempMat.translate(mouseX, mouseY);
  217.             tempMat.scale(1/stormScaleRatioX, 1/stormScaleRatioY);
  218.             repulsionHistoryMap.draw(repulsionMap, tempMat, null, BlendMode.HARDLIGHT);
  219.         }
  220.         
  221.         protected function updateForceMap():void
  222.         {
  223.             //generate current force fieldes state with blending two stormMaps.
  224.             forceMap.copyPixels(stormMap1, stormMap0.rect, tempPt);
  225.             tempColt.alphaMultiplier = Math.cos(stormCycle*Math.PI/180)*0.5+0.5;
  226.             forceMap.draw(stormMap0, null, tempColt);
  227.             
  228.             //add mouse repulsion force
  229.             forceMap.draw(repulsionHistoryMap,null,null,BlendMode.HARDLIGHT);
  230.             forceMap.draw(repulsionHistoryMap,null,null,BlendMode.HARDLIGHT);
  231.         }
  232.         
  233.         protected function updateParticles():void
  234.         {
  235.             var forceBytes:ByteArray = forceMap.getPixels(forceMap.rect);
  236.             
  237.             var stageW:int = canvas.width;
  238.             var stageH:int = canvas.height;
  239.             var loopW:int = stageW-1;
  240.             var loopH:int = stageH-1;
  241.             var byteIndex:int;
  242.             
  243.             canvas.lock();
  244.             canvas.colorTransform(canvas.rect, fadeCanvasColt);
  245.             
  246.             //Update Paritcle position and draw.
  247.             var col:int, r:int, g:int, b:int;
  248.             for(var i:int=0; i<particleNum; i++)
  249.             {
  250.                 var prt:Particle = particles[i];
  251.                 byteIndex = (int(prt.y*stormScaleRatioY)*256 + int(prt.x*stormScaleRatioX))<<2;
  252.                 prt.vx = prt.vx * 0.96 + (forceBytes[byteIndex+1]-128)*prt.scaleFactor;
  253.                 prt.vy = prt.vy * 0.96 + (forceBytes[byteIndex+2]-128)*prt.scaleFactor;
  254.                 prt.x += prt.vx;
  255.                 prt.y += prt.vy;
  256.                 if(prt.x<0){
  257.                     prt.x = loopW;
  258.                 }else if(prt.x > loopW){
  259.                     prt.x = 1;
  260.                 }
  261.                 if(prt.y<0){
  262.                     prt.y = loopH;
  263.                 }else if(prt.y > loopH){
  264.                     prt.y = 1;
  265.                 }
  266.                 
  267.                 //Self implimentation of addtive color blend mode.
  268.                 //Because there is too many particle, blending particle with low brightness color is much effective.
  269.                 col = canvas.getPixel(int(prt.x), int(prt.y));
  270.                 r = (col>>16&0xff) + prt.r;
  271.                 g = (col>>8&0xff) + prt.g;
  272.                 b = (col&0xff) + prt.b;
  273.                 r = (r<0xff)? r : 0xff;
  274.                 g = (g<0xff)? g : 0xff;
  275.                 b = (b<0xff)? b : 0xff;
  276.                 canvas.setPixel(int(prt.x), int(prt.y), (r<<16)|(g<<8)|b);
  277.             }
  278.             canvas.unlock();
  279.         }
  280.     }
  281.     
  282. }
  285. class Particle
  286. {
  287.     //particle position
  288.     public var x:Number = 0;
  289.     public var y:Number = 0;
  290.     public var vx:Number = 0;
  291.     public var vy:Number = 0;
  292.     
  293.     //particle color
  294.     public var r:int;
  295.     public var g:int;
  296.     public var b:int;
  297.     
  298.     //scale factor that affects the force applied to the particle.
  299.     public var scaleFactor:Number;
  300. }
noswf
Get Adobe Flash Player