※現在、「wonderfl build flash online」求人コンテンツ制作に関してのアンケートを実施中です！みなさまのお力添えを頂いて、続々とアンケート結果が集まっていますが、まだまだ募集しております。ご協力のほど、どうぞよろしくお願いいたします！

wonderfl運営事務局
→アンケートページ（※ログインしてからお答えいただけるようになっています。）

 notice: Flash editor updated! Join the development! Thanks to MiniBuilder


embed

noswf download fullscreen
flash swf thumbnail play
reload download fullscreen

FORKED
>sort

TextField 用 行スクロールバー forked from: TextField 用 行スクロールバー [diff(1)]

  1. // forked from taiga's TextField 用 行スクロールバー
  2. package {
  3.     import flash.display.DisplayObject;
  4.     import flash.display.Graphics;
  5.     import flash.display.Shape;
  6.     import flash.display.Sprite;
  7.     import flash.events.Event;
  8.     import flash.events.MouseEvent;
  9.     import flash.geom.ColorTransform;
  10.     import flash.text.TextField;
  11.     import flash.text.TextFieldType;
  12.     [SWF (backgroundColor="0xcccccc")]
  13.     /**
  14.      * TextField 用 行スクロールバー
  15.      * @author taiga
  16.      */
  17.     public class TextFieldScrollTest extends Sprite {
  18.         /** @private */
  19.         private var _sampleText                    :String;
  20.         /** @private */
  21.         private var _lineHeight                    :int;
  22.         /** @private */
  23.         private var _isScrollDown                  :Boolean;
  24.         /** @private */
  25.         private var _scrollClickPointY             :int;
  26.         /** @private */
  27.         private var _enabledColor                  :uint;
  28.         /** @private */
  29.         private var _disabledColor                 :uint;
  30.         /** TextField インスタンスです。 */
  31.         protected var textField                    :TextField;
  32.         /** Sprite インスタンスです。 */
  33.         protected var textFieldScrollBar           :Sprite;
  34.         /** Shape インスタンスです。 */
  35.         protected var textFieldScroolBarBackground :Shape;
  36.         /** ResetButton インスタンスです。 */
  37.         protected var resetButton                  :ResetButton;
  38.         /**
  39.          * コンストラクタ
  40.          */
  41.         public function TextFieldScrollTest() {
  42.             super();
  43.             _sampleText    = "TextField クラスは、テキストの表示と入力用の表示オブジェクトを作成するために使用されます。SWF ファイルのダイナミックテキストフィールドおよびテキスト入力フィールドは、すべて TextField クラスのインスタンスです。TextField クラスを使用すると、低レベルでのテキストレンダリングが可能になります。ただし、Flex では一般的に Label、Text、TextArea、TextInput コントロールを使用して、テキスト処理を行います。\n\n" +
  44.                              "テキストフィールドを動的に作成する場合は、TextField() コンストラクタを使用します。\n\n" +
  45.                              "TextField クラスのメソッドを使用すると、オーサリング時または実行時に作成したダイナミックテキストフィールドやテキスト入力フィールドにテキストを設定、選択、および操作できます。\n\n" +
  46.                              "ActionScript には、テキストを実行時にフォーマットする方法がいくつか用意されています。TextFormat クラスでは、TextField オブジェクトの文字フォーマットと段落フォーマットを設定できます。TextField.styleSheet プロパティおよび StyleSheet クラスを使用して、テキストフィールドに CSS (Cascading Style Sheet) スタイルを適用できます。CSS を使用すると、ビルトイン HTML タグのスタイル設定、新しいフォーマットタグの定義、またはスタイルの適用を行うことができます。HTML 形式のテキスト（CSS スタイルを使用している場合も可）をテキストフィールドに直接割り当てることができます。テキストフィールドに割り当てる HTML テキストに埋め込みメディア（ムービークリップ、SWF ファイル、GIF ファイル、PNG ファイル、および JPEG ファイル）を含めることができます。この場合テキストは、Web ブラウザ上で HTML ドキュメントの埋め込みメディアの周りをテキストが囲むのと同じように、埋め込みメディアの周りを囲みます。\n\n" +
  47.                              "Flash Player では、テキストのフォーマットに利用できる HTML タグのサブセットをサポートしています。htmlText プロパティの説明の、サポートされている HTML タグのリストを参照してください。 ";
  48.             _enabledColor  = 0x333333;
  49.             _disabledColor = 0x999999;
  50.             createChildren();
  51.         }
  52.         /** 子表示オブジェクトを生成します。 */
  53.         protected function createChildren():void {
  55.             if(stage != null) {
  56.                 stage.addEventListener(MouseEvent.MOUSE_MOVE, scrollMouseMoveHandler, false, 0, true);
  57.                 stage.addEventListener(MouseEvent.MOUSE_UP,   scrollMouseUpHandler,   false, 0, true);
  58.             }
  60.             textField            = addChildAt(new TextField(), 0) as TextField;
  61.             textField.multiline  = true;
  62.             textField.wordWrap   = true;
  63.             textField.background = true;
  64.             textField.border     = true;
  65.             textField.type       = TextFieldType.INPUT;
  66.             textField.addEventListener(Event.CHANGE, textFieldChangeHandler,    false, 0, true);
  68.             textFieldScrollBar = addChildAt(new Sprite(), 0) as Sprite;
  70.             textFieldScroolBarBackground = addChildAt(new Shape(), 0) as Shape;
  72.             resetButton = addChildAt(new ResetButton(), 0) as ResetButton;
  73.             resetButton.addEventListener(MouseEvent.CLICK, resetButtonClickHandler, false, 0, true);
  75.             updateDisplayList();
  77.         }
  78.         /** 表示リスト上のオブジェクトを再描画します。 */
  79.         protected function updateDisplayList():void {
  80.             const TEXTFIELD_WIDTH  :int = 435;
  81.             const TEXTFIELD_HEIGHT :int = 350;
  82.             if(textField != null) {
  83.                 textField.text                   = "あj";
  84.                 _lineHeight                      = textField.getLineMetrics(0).height;
  85.                 textField.text                   = _sampleText;
  86.                 textField.width                  = TEXTFIELD_WIDTH;
  87.                 textField.height                 = TEXTFIELD_HEIGHT;
  88.                 textField.x                      = 10;
  89.                 textField.y                      = 10;
  90.             }
  91.             checkNumLines(textField);
  93.             if(textFieldScrollBar != null) {
  94.                 textFieldScrollBar.x             = textField.x + textField.width + 2;
  95.                 textFieldScrollBar.y             = textField.y;
  96.                 drawScrollBar(textFieldScrollBar);
  97.             }
  98.             if(textFieldScroolBarBackground != null) {
  99.                 textFieldScroolBarBackground.x   = textFieldScrollBar.x + (textFieldScrollBar.width / 2);
  100.                 textFieldScroolBarBackground.y   = textField.y;
  101.                 drawScrollBarBackground(textFieldScroolBarBackground);
  102.             }
  103.             if(resetButton != null) {
  104.                 resetButton.x = textField.x + textField.width - resetButton.width;
  105.                 resetButton.y = textField.x + textField.height + 5;
  106.             }
  107.         }
  108.         /** TextField インスタンスの CHANGE ハンドラです。 */
  109.         protected function textFieldChangeHandler(event:Event):void {
  110.             drawScrollBar(textFieldScrollBar);
  111.             checkNumLines(event.currentTarget as TextField);
  112.         }
  113.         /** TextField インスタンスの表示行数を取得します。 */
  114.         protected function getShowNumLines(target:TextField):int {
  115.             return int((target.height - 4) / _lineHeight);
  116.         }
  117.         /** スクロールバーとステージのマウスアップ処理です。 */
  118.         protected function scrollMouseUpHandler(event:MouseEvent):void   {
  119.             textField.addEventListener(Event.SCROLL, textFieldKeyScrollHandler, true, int.MAX_VALUE, true);
  120.             _isScrollDown = false;
  121.         }
  122.         /** スクロールバーのマウスダウン処理です。 */
  123.         protected function scrollMouseDownHandler(event:MouseEvent):void {
  124.             textField.removeEventListener(Event.SCROLL, textFieldKeyScrollHandler, true);
  125.             _isScrollDown = true;
  126.             _scrollClickPointY = mouseY;
  127.         }
  128.         /** スクロールバーをマウスダウン中に動かすときの処理です。 */
  129.         protected function scrollMouseMoveHandler(event:MouseEvent):void {
  130.             var scrollRectHeight_   :int;
  131.             var scrollPaneHeight_   :int;
  132.             var invisibledNumLines_ :int;
  133.             var minY_               :int;
  134.             var maxY_               :int;
  135.             var dY_                 :int;
  136.             var dScrollV_           :Number;
  138.             scrollRectHeight_ = textField.height;
  139.             scrollPaneHeight_ = textField.textHeight;
  141.             if(scrollRectHeight_ > scrollPaneHeight_ || !_isScrollDown) {
  142.                 return;
  143.             }
  145.             invisibledNumLines_ = textField.numLines - getShowNumLines(textField);
  146.             minY_ = textField.y;
  147.             maxY_ = scrollRectHeight_ - textFieldScrollBar.height + textField.y;
  148.             dY_   = textFieldScrollBar.y + (mouseY - _scrollClickPointY);
  150.             if(dY_  <= minY_) {
  151.                 textFieldScrollBar.y = minY_;
  152.                 dScrollV_ = 0;
  153.             }
  154.             else if(dY_ >= maxY_) {
  155.                 textFieldScrollBar.y = maxY_;
  156.                 dScrollV_ = invisibledNumLines_;
  157.             }
  158.             else {
  159.                 textFieldScrollBar.y = dY_;
  160.                 dScrollV_ = Math.ceil(dY_ / (maxY_ / invisibledNumLines_));
  161.             }
  163.             textField.scrollV = dScrollV_ + 1;
  165.             _scrollClickPointY = mouseY;
  167.             event.updateAfterEvent();
  169.         }
  170.         /** TextField インスタンスのキースクロール処理です。 */
  171.         protected function textFieldKeyScrollHandler(event:Event):void {
  172.             if(_isScrollDown) {
  173.                 return;
  174.             }
  175.             revisionPoint(event.currentTarget as TextField);
  176.         }
  177.         /** ResetButton インスタンスの CLICK ハンドラです。*/
  178.         protected function resetButtonClickHandler(event:MouseEvent):void {
  179.             textField.text = _sampleText;
  180.             drawScrollBar(textFieldScrollBar);
  181.             checkNumLines(textField);
  182.         }
  183.         /** スクロールバーの表示 / 非表示 を制御します。*/
  184.         protected function checkNumLines(target:TextField):void {
  185.             revisionPoint(textField);
  186.             if(target.height < target.textHeight + 4) {
  187.                 textField.addEventListener(Event.SCROLL, textFieldKeyScrollHandler, false, 0, true);
  188.                 textFieldScrollBar.useHandCursor = true;
  189.                 textFieldScrollBar.buttonMode    = true;
  190.                 textFieldScrollBar.addEventListener(MouseEvent.MOUSE_UP,   scrollMouseUpHandler,   false, 0, true);
  191.                 textFieldScrollBar.addEventListener(MouseEvent.MOUSE_DOWN, scrollMouseDownHandler, false, 0, true);
  192.                 textFieldScrollBar.addEventListener(MouseEvent.MOUSE_MOVE, scrollMouseMoveHandler, false, 0, true);
  193.                 hexToRGB(textFieldScrollBar,           _enabledColor);
  194.                 hexToRGB(textFieldScroolBarBackground, _enabledColor);
  195.             }
  196.             else {
  197.                 textField.removeEventListener(Event.SCROLL, textFieldKeyScrollHandler, false);
  198.                 textFieldScrollBar.useHandCursor = false;
  199.                 textFieldScrollBar.buttonMode    = false;
  200.                 textFieldScrollBar.removeEventListener(MouseEvent.MOUSE_UP,   scrollMouseUpHandler,   false);
  201.                 textFieldScrollBar.removeEventListener(MouseEvent.MOUSE_DOWN, scrollMouseDownHandler, false);
  202.                 textFieldScrollBar.removeEventListener(MouseEvent.MOUSE_MOVE, scrollMouseMoveHandler, false);
  203.                 hexToRGB(textFieldScrollBar,           _disabledColor);
  204.                 hexToRGB(textFieldScroolBarBackground, _disabledColor);
  205.             }
  206.         }
  207.         /** スクロールバーの座標を補正します。 */
  208.         protected function revisionPoint(target:TextField):void {
  209.             var dHeight_     :int    = target.height - textFieldScrollBar.height;
  210.             var dScrollV_    :int    = target.scrollV - 1;
  211.             var resultY_     :Number = dHeight_ / (target.numLines - getShowNumLines(target)) * dScrollV_;
  212.             var y_           :Number = resultY_ + target.y
  213.             if(y_ + textFieldScrollBar.height > target.y + target.height) {
  214.                 y_ = target.y + target.height - textFieldScrollBar.height;
  215.             }
  216.             if(y_ < target.y || isNaN(y_)) {
  217.                 y_ = target.y;
  218.             }
  219.             textFieldScrollBar.y = y_;
  220.         }
  221.         /** スクロールバーの外観を描画します。 */
  222.         protected function drawScrollBar(target:Sprite):void {
  223.             var g         :Graphics = target.graphics;
  224.             var minHeight_:int      = 20;
  225.             var height_   :Number   = textField.height * (getShowNumLines(textField) / textField.numLines);
  226.             if(height_ > textField.height) {
  227.                 height_ = textField.height;
  228.             }
  229.             else if(height_ < minHeight_) {
  230.                 height_ = minHeight_;
  231.             }
  232.             g.clear();
  233.             g.beginFill(_enabledColor);
  234.             g.drawRoundRect(0, 0, 8, height_, 10, 10);
  235.             g.endFill();
  236.         }
  237.         /** スクロールバーの下地の外観を描画します。 */
  238.         protected function drawScrollBarBackground(target:Shape):void {
  239.             var g:Graphics = target.graphics;
  240.             g.clear();
  241.             g.beginFill(_enabledColor);
  242.             g.drawRect(0, 0, 0.5, textField.height);
  243.             g.endFill();
  244.         }
  245.         /** 指定ターゲットの色を指定カラーに変更します。 */
  246.         protected function hexToRGB(target:DisplayObject, v:uint):void {
  247.             var r:uint = (v >> 16) & 0xff;
  248.             var g:uint = (v >> 8) & 0xff;
  249.             var b:uint = v & 0xff;
  250.             target.transform.colorTransform = new ColorTransform(0, 0, 0, 1, r, g, b);
  251.         }
  252.     }
  253. }
  254. import flash.display.DisplayObject;
  255. import flash.display.GradientType;
  256. import flash.display.Graphics;
  257. import flash.display.Shape;
  258. import flash.display.SimpleButton;
  259. import flash.geom.Matrix;
  260. /**
  261.  * ResetButton クラスは SimpleButton のサブクラスです。
  262.  * サイズは固定です。外部からの編集はしません。
  263.  */
  264. class ResetButton extends SimpleButton {
  265.     /** upState の Shape です。 */
  266.     protected var upStateSkin      :Shape;
  267.     /** overStateShape の Shape です。 */
  268.     protected var overStateSkin    :Shape;
  269.     /** downState の Shape です。 */
  270.     protected var downStateSkin    :Shape;
  271.     /** hitTestState の Shape です。 */
  272.     protected var hitTestStateSkin :Shape;
  273.     /**
  274.      * コンストラクタ
  275.      */
  276.     public function ResetButton(upState:DisplayObject=null, overState:DisplayObject=null, downState:DisplayObject=null, hitTestState:DisplayObject=null) {
  277.         super(upState, overState, downState, hitTestState);
  279.         upStateSkin          = new Shape();
  280.         overStateSkin        = new Shape();
  281.         downStateSkin        = new Shape();
  282.         hitTestStateSkin     = new Shape();
  284.         super.upState        = createShape(upStateSkin,      [0x333333, 0x666666], [0xeeeeee, 0xcccccc], 0x000000);
  285.         super.overState      = createShape(overStateSkin,    [0x666666, 0x999999], [0xffffff, 0xdddddd], 0x666666);
  286.         super.downState      = createShape(downStateSkin,    [0x999999, 0x666666], [0xaaaaaa, 0x999999], 0x333333);
  287.         super.hitTestState   = createHitTestShape(hitTestStateSkin);
  288.         super.hitTestState.x = 0;
  289.         super.hitTestState.y = 0;
  290.         super.useHandCursor  = true;
  292.     }
  293.     /** コンポーネントの外観を作成します。 */
  294.     protected function createShape(target:Shape, backgroundColors:Array, fillColors:Array, arrowColor:uint):Shape {
  295.         const PI :Number   = Math.PI;
  296.         var w    :int      = 60;
  297.         var h    :int      = 13;
  298.         var r    :int      = 10;
  299.         var g    :Graphics = target.graphics;
  300.         var m    :Matrix   = new Matrix();
  301.         var rad  :Number   = PI / 180;
  303.         m.createGradientBox(w, h, PI / 2, 0, 0);
  305.         g.beginGradientFill(GradientType.LINEAR, backgroundColors, [100, 100], [0, 255], m);
  306.         g.drawRoundRect(0, 0, w, h, r, r);
  307.         g.endFill();
  309.         g.beginGradientFill(GradientType.LINEAR, fillColors,       [100, 100], [0, 255], m);
  310.         g.drawRoundRect(1, 1, w - 2, h - 2, r - 1, r - 1);
  311.         g.endFill();
  313.         return target;
  314.     }
  315.     /** ボタン領域用表示オブジェクトを作成します。 */
  316.     protected function createHitTestShape(target:Shape):Shape {
  317.         var w :int      = 60;
  318.         var h :int      = 13;
  319.         var g :Graphics = target.graphics;
  321.         g.beginFill(0);
  322.         g.drawRect(0, 0, w, h);
  323.         g.endFill();
  325.         return target;
  326.     }
  327. }
noswf
Get Adobe Flash Player