※現在、「wonderfl build flash online」求人コンテンツ制作に関してのアンケートを実施中です！みなさまのお力添えを頂いて、続々とアンケート結果が集まっていますが、まだまだ募集しております。ご協力のほど、どうぞよろしくお願いいたします！

wonderfl運営事務局
→アンケートページ（※ログインしてからお答えいただけるようになっています。）

 notice: Flash editor updated! Join the development! Thanks to MiniBuilder


forked from : osamX's ワンダフルクエスト [diff(749)]

embed

noswf download fullscreen
flash swf thumbnail play
reload download fullscreen

FAVORITE BY
:
:
dot3D Dot
:
:
*reference3DALternativa3D面白い！！
:
:
:
:
墓標っぽいのが・・・なんだサボテンか。。。
:
:
Alternativa3D3Dなんかモンスターぽいのが・・・なんだサボテンか。。。
:
:
:
すげぇ・・・（汗
:
あれっ、見たコトあるモノが。。。
:
やべぇ！
:
WonderflQuest 第二章 そして舞台は3Dへ
:
毒でﾃﾞｭｸｼｯってなりたい。
:
:
仕事がはやいｗ
:
すごー！
:
つくるのはやッ
:
FORKED
>sort

[Alternativa3D] Wonderfl Quest 3D forked from: [Alternativa3D] Wonderfl Quest 3D [diff(13)]

  1. // forked from clockmaker's [Alternativa3D] Wonderfl Quest 3D
  2. // forked from osamX's ワンダフルクエスト
  3. // forked from nengafl's nengafl
  4. /**=====================================================
  5.  * osamXさんのワンダフルクエストをfolkして3Dにしました。
  6.  * 3Dの実装はAlternativa3Dというライブラリを使っています。
  7.  *
  8.  * Papervision3Dと比べてポリゴン欠けが発生しづらいのが特徴で
  9.  * 今回の実装には向いていました。
  10.  *
  11.  * [How to Play]
  12.  * up, w    : move up
  13.  * down, s  : move down
  14.  * left, a  : move left
  15.  * right, d : move right
  16.  *
  17.  * [Hint]
  18.  * You can change map with edit MAP_DATA
  19.  * ===================================================== */
  20. package {
  21.     import com.bit101.components.ProgressBar;
  22.     import flash.display.*;
  23.     import flash.events.*;
  24.     import flash.geom.Point;
  25.     import flash.net.URLRequest;
  26.     import flash.system.LoaderContext;
  27.     import flash.ui.Keyboard;
  28.     import alternativa.engine3d.materials.MovieClipMaterial;
  29.     import alternativa.engine3d.materials.TextureMaterial;
  30.     import alternativa.engine3d.primitives.Plane;
  31.     import alternativa.types.Texture;
  32.     import alternativa.utils.MathUtils;
  33.     import jp.progression.commands.lists.SerialList;
  34.     import jp.progression.data.Resource;
  35.     import jp.progression.data.getResourceById;
  36.     import org.si.sion.*;
  37.     
  38.     [SWF(width="465", height="465", frameRate="60", backgroundColor="0x000000")]
  39.     public class WonderflQuest extends Sprite {
  40.         private static const FLDSIZE:uint = 48; //フィールド（マップ上の1マス）の横・縦のドット数
  41.         private static const MAPSIZE:uint = 32; //マップの横・縦のマスの個数
  43.         /**-----------------------------------------------------
  44.          * マップのデータ（ここが木で、あそこが芝生で．．．ってやつ）が入ってます。
  45.          * ここをいじると、マップが変わります。上のfieldListのコメント参照。
  46.          * ----------------------------------------------------- */
  47.         private static const MAP_DATA:Array =
  48.             [
  49.             [9, 9, 9, 9, 9, 9, 9, 1, 1, 1, 2, 1, 1, 1, 1, 1, 0, 6, 1, 1, 1, 1, 1, 1, 1, 1, 2, 1, 1, 1, 1, 9],
  50.             [9, 9, 9, 9, 0, 0, 0, 0, 0, 1, 0, 1, 3, 3, 1, 1, 0, 0, 1, 1, 0, 0, 0, 0, 0, 1, 0, 1, 3, 3, 1, 9],
  51.             [9, 9, 9, 9, 0, 0, 0, 0, 0, 1, 0, 1, 3, 8, 3, 3, 0, 0, 1, 1, 0, 0, 0, 0, 0, 1, 0, 1, 3, 8, 3, 9],
  52.             [9, 9, 9, 9, 0, 0, 0, 0, 0, 1, 0, 1, 3, 3, 3, 3, 7, 0, 1, 1, 0, 0, 0, 0, 0, 1, 0, 1, 3, 3, 3, 9],
  53.             [9, 9, 9, 1, 1, 1, 1, 1, 0, 1, 0, 1, 3, 1, 1, 1, 0, 0, 1, 1, 1, 1, 1, 1, 0, 1, 0, 1, 3, 1, 1, 9],
  54.             [9, 9, 1, 1, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 1, 1, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 9],
  55.             [9, 9, 1, 1, 0, 0, 0, 7, 0, 0, 0, 1, 1, 1, 1, 1, 0, 0, 1, 1, 0, 0, 0, 7, 0, 0, 0, 1, 1, 1, 1, 9],
  56.             [9, 9, 1, 1, 0, 0, 0, 0, 0, 0, 6, 0, 0, 0, 0, 1, 0, 0, 1, 1, 0, 0, 0, 0, 0, 0, 6, 0, 0, 0, 0, 9],
  57.             [9, 9, 1, 1, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 1, 1, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 9],
  58.             [9, 9, 1, 1, 1, 1, 0, 1, 0, 0, 0, 1, 0, 0, 0, 0, 1, 0, 1, 1, 1, 1, 0, 1, 0, 0, 0, 1, 0, 0, 0, 9],
  59.             [9, 9, 1, 1, 1, 1, 1, 1, 0, 0, 0, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 0, 0, 0, 1, 1, 1, 1, 9],
  60.             [9, 9, 9, 9, 9, 9, 9, 9, 4, 4, 9, 9, 9, 9, 9, 9, 1, 1, 9, 9, 9, 9, 9, 9, 4, 4, 9, 9, 9, 9, 9, 9],
  61.             [9, 9, 0, 0, 0, 9, 9, 0, 0, 0, 0, 6, 0, 6, 6, 7, 1, 1, 0, 0, 0, 9, 9, 0, 0, 0, 0, 6, 0, 0, 0, 9],
  62.             [9, 9, 1, 0, 0, 5, 5, 0, 0, 0, 0, 0, 0, 0, 7, 0, 1, 1, 1, 0, 0, 5, 5, 0, 0, 0, 0, 0, 0, 0, 0, 9],
  63.             [9, 9, 1, 1, 9, 9, 9, 9, 0, 0, 1, 1, 0, 0, 6, 0, 1, 8, 1, 1, 9, 9, 9, 9, 0, 0, 1, 1, 0, 0, 6, 9],
  64.             [9, 9, 1, 9, 9, 9, 9, 9, 9, 9, 9, 9, 1, 1, 1, 0, 1, 1, 1, 9, 9, 9, 9, 9, 9, 9, 9, 9, 1, 1, 1, 9],
  65.             [9, 9, 1, 1, 1, 1, 1, 1, 1, 1, 2, 1, 1, 1, 1, 1, 0, 6, 1, 1, 1, 1, 1, 1, 1, 1, 2, 1, 1, 1, 1, 9],
  66.             [9, 9, 1, 1, 0, 0, 0, 0, 0, 1, 0, 1, 3, 3, 1, 1, 0, 0, 1, 1, 0, 0, 0, 0, 0, 1, 0, 1, 3, 3, 1, 9],
  67.             [9, 9, 1, 1, 0, 0, 0, 0, 0, 1, 0, 1, 3, 8, 3, 3, 0, 0, 1, 1, 0, 0, 0, 0, 0, 1, 0, 1, 3, 8, 3, 9],
  68.             [9, 9, 1, 1, 0, 0, 0, 0, 0, 1, 0, 1, 3, 3, 3, 3, 7, 0, 1, 1, 0, 0, 0, 0, 0, 1, 0, 1, 3, 3, 3, 9],
  69.             [9, 9, 1, 1, 1, 1, 1, 1, 0, 1, 0, 1, 3, 1, 1, 1, 0, 0, 1, 1, 1, 1, 1, 1, 0, 1, 0, 1, 3, 1, 1, 9],
  70.             [9, 9, 1, 1, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 1, 1, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 9],
  71.             [9, 9, 1, 1, 0, 0, 0, 7, 0, 0, 0, 1, 1, 1, 1, 1, 0, 0, 1, 1, 0, 0, 0, 7, 0, 0, 0, 1, 1, 1, 1, 9],
  72.             [9, 9, 1, 1, 0, 0, 0, 0, 0, 0, 6, 0, 0, 0, 0, 1, 0, 0, 1, 1, 0, 0, 0, 0, 0, 0, 6, 0, 0, 0, 0, 9],
  73.             [9, 9, 1, 1, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 1, 1, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 9],
  74.             [9, 9, 1, 1, 1, 1, 0, 1, 0, 0, 0, 1, 0, 0, 0, 0, 1, 0, 1, 1, 1, 1, 0, 1, 0, 0, 0, 1, 0, 0, 0, 9],
  75.             [9, 9, 1, 1, 1, 1, 1, 1, 0, 0, 0, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 0, 0, 0, 1, 1, 1, 1, 9],
  76.             [9, 9, 9, 9, 9, 9, 9, 9, 4, 4, 9, 9, 9, 9, 9, 9, 9, 9, 9, 9, 9, 9, 9, 9, 9, 9, 9, 9, 9, 9, 9, 9],
  77.             [9, 9, 0, 0, 0, 9, 9, 0, 0, 0, 0, 6, 0, 6, 0, 7, 1, 1, 0, 0, 9, 9, 9, 0, 0, 0, 0, 6, 0, 0, 0, 9],
  78.             [9, 9, 1, 0, 0, 5, 5, 0, 0, 0, 0, 0, 0, 0, 0, 0, 1, 1, 1, 0, 5, 5, 5, 0, 0, 0, 0, 0, 0, 0, 0, 9],
  79.             [9, 9, 9, 9, 9, 9, 9, 9, 9, 9, 9, 9, 9, 9, 9, 9, 9, 9, 9, 9, 9, 9, 9, 9, 9, 9, 9, 9, 9, 9, 9, 9],
  80.             [9, 9, 9, 9, 9, 9, 9, 9, 9, 9, 9, 9, 9, 9, 9, 9, 9, 9, 9, 9, 9, 9, 9, 9, 9, 9, 9, 9, 9, 9, 9, 9],
  82.             ];
  83.         private static const SCALE:Number = 3; //勇者やフィールドの拡大率
  84.         private static const SIZE:Number = 465; //ステージの大きさ
  85.         // 空の画像
  86.         private static const SKY_URL:String = "http://clockmaker.jp/labs/100109_wonderfl_quest/imgs/sky.png";
  87.         private static const SPEED:Number = 3; //勇者が歩くスピード FLDSIZEの約数にしてください
  89.         /**-----------------------------------------------------
  90.          * コンストラクタ。　ここが最初に処理されます。
  91.          * ----------------------------------------------------- */
  92.         public function WonderflQuest():void {
  93.             stage.quality = StageQuality.LOW;
  95.             _progress = new ProgressBar();
  96.             addChild(_progress);
  97.             _progress.x = (stage.stageWidth - _progress.width) / 2 >> 0
  98.             _progress.y = (stage.stageHeight - _progress.height) / 2 >> 0
  100.             createMap(); //マップを作る
  102.             yuusha = new Yuusha(); //勇者を作る
  103.             yuusha.scaleX = yuusha.scaleY = SCALE; //勇者を拡大表示
  104.             yuusha.x = yuusha.y = (SIZE - FLDSIZE) / 2; //中央に配置
  106.             yuushaPos = new Point(16 * FLDSIZE, 26 * FLDSIZE); //勇者初期位置
  107.             moveMap(yuushaPos); //マップ移動
  108.         }
  110.         /**-----------------------------------------------------
  111.          * マップの1マス（フィールド）のリストです。
  112.          * ここをいじると好きな画像をマップ上に貼ることができます。
  113.          * 画像のサイズは、基本的に16*16ピクセルです。
  114.          * 形式はjpeg,gif,pngのどれかにしてください。
  115.          * Twitterのアイコン画像取得は、こちらのAPIを使わせてもらってます。
  116.          * http://usericons.relucks.org/
  117.          * ----------------------------------------------------- */
  118.         private const FIELD_IMG_URLS:Array = [
  119.             new Field("http://flash-scope.com/wonderfl/WonderflQuest/map/map0.png", false), //[ 0]: 芝生
  120.             new Field("http://flash-scope.com/wonderfl/WonderflQuest/map/map1.png", false), //[ 1]: 砂
  121.             new Field("http://flash-scope.com/wonderfl/WonderflQuest/map/map2.png", false), //[ 2]: 石畳
  122.             new Field("http://flash-scope.com/wonderfl/WonderflQuest/map/map3.png", false), //[ 3]: フローリング
  123.             new Field("http://flash-scope.com/wonderfl/WonderflQuest/map/map4.png", false), //[ 4]: 橋（縦）
  124.             new Field("http://flash-scope.com/wonderfl/WonderflQuest/map/map5.png", false), //[ 5]: 橋（横）
  125.             new Field("http://clockmaker.jp/labs/100109_wonderfl_quest/imgs/map6.png", true), //[ 6]: 木（小）
  126.             new Field("http://clockmaker.jp/labs/100109_wonderfl_quest/imgs/map7.png", true), //[ 7]: 木（大）
  127.             new Field("http://clockmaker.jp/labs/100109_wonderfl_quest/imgs/ton.png", true), //[ 8]: サボテン
  128.             new Field("http://flash-scope.com/wonderfl/WonderflQuest/map/map9.png", true), //[ 9]: 水
  129.             ];
  130.         /**-----------------------------------------------------
  131.          * 勇者の画像のURLリスト
  132.          * ----------------------------------------------------- */
  133.         private const YUUSHA_IMG_URLS:Array = [
  134.             "http://flash-scope.com/wonderfl/WonderflQuest/yuusha/yuushaF1.png", //前向き1
  135.             "http://flash-scope.com/wonderfl/WonderflQuest/yuusha/yuushaF2.png", //前向き2
  136.             "http://flash-scope.com/wonderfl/WonderflQuest/yuusha/yuushaB1.png", //後ろ向き1
  137.             "http://flash-scope.com/wonderfl/WonderflQuest/yuusha/yuushaB2.png", //後ろ向き2
  138.             "http://flash-scope.com/wonderfl/WonderflQuest/yuusha/yuushaL1.png", //左向き1
  139.             "http://flash-scope.com/wonderfl/WonderflQuest/yuusha/yuushaL2.png", //左向き2
  140.             "http://flash-scope.com/wonderfl/WonderflQuest/yuusha/yuushaR1.png", //右向き1
  141.             "http://flash-scope.com/wonderfl/WonderflQuest/yuusha/yuushaR2.png" //右向き2
  142.             ];
  144.         private var _progress:ProgressBar;
  145.         private var _world:BasicTemplate; // Alternativa3Dのテンプレート
  147.         private var _yuusha3D:Plane;
  148.         private var bMapData:Array = []; //フィールドが障害物か否かを記憶
  149.         private var frameCount:Number = 0; //onEnterFrameで使用
  150.         private var keyFlags:Array = [false, false, false, false]; //下上左右のキーが押されているか
  151.         private var map:MovieClip; //マップ本体　これを動かして勇者が移動しているように見せる
  152.         private var walkDirection:int = 4; //歩いていく方向 （0～3：下上左右  4:止）
  154.         private var yuusha:Yuusha; //勇者
  155.         private var yuushaPos:Point; //勇者のマップ上の座標
  157.         /**-----------------------------------------------------
  158.          * マップを作ります。
  159.          * この実装方法は良くないです。遅いし、何回も同じ画像をロードしてます。
  160.          * 画像が別ドメインにある時に、crossdomain.xmlがなくても大丈夫なようにしています。
  161.          * ----------------------------------------------------- */
  162.         private function createMap():void {
  163.             var i:int;
  164.             var cmd:IllegalLoadBitmapData;
  166.             map = new MovieClip();
  167.             bMapData = [];
  169.             var list:SerialList = new SerialList();
  171.             // update progress bar
  172.             list.onPosition = function():void {
  173.                 _progress.value = list.position / list.numCommands;
  174.             };
  176.             // Load Field Images
  177.             for (i = 0; i < FIELD_IMG_URLS.length; i++) {
  178.                 cmd = new IllegalLoadBitmapData(new URLRequest(FIELD_IMG_URLS[i].url));
  179.                 cmd.context = new LoaderContext(true);
  180.                 cmd.catchError = function(target:Object, error:Error):void {
  181.                     target.executeComplete();
  182.                 };
  183.                 list.addCommand(cmd);
  184.             }
  186.             // Load Yuusha Images
  187.             for (i = 0; i < YUUSHA_IMG_URLS.length; i++) {
  188.                 cmd = new IllegalLoadBitmapData(new URLRequest(YUUSHA_IMG_URLS[i]));
  189.                 cmd.context = new LoaderContext(true);
  190.                 cmd.catchError = function(target:Object, error:Error):void {
  191.                     target.executeComplete();
  192.                 };
  193.                 list.addCommand(cmd);
  194.             }
  196.             // SKY IMAGE
  197.             list.addCommand(new IllegalLoadBitmapData(new URLRequest(SKY_URL), {context: new LoaderContext(true)}));
  199.             // init
  200.             list.addCommand(
  201.                 function():void {
  202.                     for (var i:uint = 0; i < MAPSIZE; i++) {
  203.                         bMapData[i] = [];
  204.                         for (var j:uint = 0; j < MAPSIZE; j++) {
  205.                             var field:Field = FIELD_IMG_URLS[MAP_DATA[j][i]];
  206.                             bMapData[i][j] = field.isObstacle;
  207.                             switch (MAP_DATA[j][i]) {
  208.                                 case 6:
  209.                                 case 7:
  210.                                     field = FIELD_IMG_URLS[0];
  211.                                     break;
  212.                                 case 8:
  213.                                     field = FIELD_IMG_URLS[1];
  214.                                     break;
  215.                             }
  217.                             var res:Resource = getResourceById(field.url);
  218.                             if (res) {
  219.                                 var bmp:Bitmap = new Bitmap(res.toBitmapData());
  220.                                 bmp.x = FLDSIZE * i;
  221.                                 bmp.y = FLDSIZE * j;
  222.                                 bmp.scaleX = bmp.scaleY = SCALE;
  223.                                 map.addChild(bmp);
  224.                             }
  225.                         }
  226.                     }
  228.                     // build bitmap object from images
  229.                     yuusha.build(YUUSHA_IMG_URLS);
  231.                     // 3Dの初期化
  232.                     init3D();
  234.                     //イベントリスナーの登録
  235.                     addEventListener(Event.ENTER_FRAME, loop);
  236.                 }
  237.                 );
  238.             list.execute();
  239.         }
  241.         /**
  242.          * Init Alternativa3D
  243.          *
  244.          */
  245.         private var driver:SiONDriver = new SiONDriver();
  246.         private function init3D():void {
  247.             removeChild(_progress); //ロード画面非表示
  248.             stage.addEventListener(KeyboardEvent.KEY_DOWN, onKeyDown); //イベントリスナーの登録
  249.             stage.addEventListener(KeyboardEvent.KEY_UP, onKeyUp); //イベントリスナーの登録
  251.             var res:Resource = getResourceById(SKY_URL);
  252.             addChild(new Bitmap(res.toBitmapData()));
  254.             // Alternativa3Dを初期化
  255.             _world = new BasicTemplate(465, 465, true);
  256.             addChild(_world);
  258.             var bmd:BitmapData = new BitmapData(map.width, map.height);
  259.             bmd.draw(map);
  261.             var tex:Texture = new Texture(bmd);
  262.             var mat:TextureMaterial = new TextureMaterial(tex);
  264.             var fieldPlane:Plane = new Plane(map.width, map.height, 1, 1);
  265.             fieldPlane.cloneMaterialToAllSurfaces(mat);
  266.             _world.scene.root.addChild(fieldPlane);
  267.             fieldPlane.x = +map.width / 2 >> 0;
  268.             fieldPlane.y = +map.height / 2 >> 0;
  270.             var mcMat:MovieClipMaterial = new MovieClipMaterial(yuusha, FLDSIZE / SCALE, FLDSIZE / SCALE);
  271.             _yuusha3D = new Plane(FLDSIZE, FLDSIZE, 1, 1);
  272.             _yuusha3D.cloneMaterialToAllSurfaces(mcMat);
  274.             _yuusha3D.z = -yuusha.height / 2;
  275.             _yuusha3D.rotationX = MathUtils.toRadian(90);
  277.             _world.scene.root.addChild(_yuusha3D);
  278.             _world.camera.z = -40;
  280.             _world.camera.rotationY = MathUtils.toRadian(180);
  281.             _world.camera.rotationX = MathUtils.toRadian(-100);
  282.             _world.camera.rotationZ = MathUtils.toRadian(180);
  284.             var field:Field;
  285.             var mat2:TextureMaterial;
  286.             var tree:Plane;
  288.             // 木とさぼ㌧だけ立体にする
  289.             for (var i:uint = 0; i < MAPSIZE; i++) {
  290.                 for (var j:uint = 0; j < MAPSIZE; j++) {
  291.                     switch (MAP_DATA[i][j]) {
  292.                         case 6:
  293.                         case 7:
  294.                         case 8:
  295.                             field = FIELD_IMG_URLS[MAP_DATA[i][j]];
  296.                             res = getResourceById(field.url);
  297.                             if (res) {
  298.                                 mat2 = new TextureMaterial(new Texture(res.toBitmapData()));
  299.                                 tree = new Plane(FLDSIZE, FLDSIZE, 1, 1, true);
  300.                                 tree.cloneMaterialToAllSurfaces(mat2);
  301.                                 _world.scene.root.addChild(tree);
  302.                                 tree.x = FLDSIZE * j + FLDSIZE / 2;
  303.                                 tree.y = FLDSIZE * i + FLDSIZE / 2;
  304.                                 tree.z = -FLDSIZE / 2;
  305.                                 tree.rotationX = MathUtils.toRadian(90);
  306.                             }
  307.                             break;
  308.                     }
  309.                 }
  310.             }
  311.             
  312.             var mml:String;
  313.             mml ="#REV;t120;";
  314.             mml+="%1@2s30@f100l4v9o6 $q7d2a2gfecd2>c<g8a8fg8f8ecd1&d1redae1redag2ec<a+6>c6d6<ag>c2<aga2&a8a8>d8e8a1;";
  315.             mml+="%1@4s30l8v7 $q3fafaeaeadadacgcgfafaeaeadadacgcgq7f+1f1q3f16a16>d<fadfa>d<e16a16>c<ea>c<ea>c<d16f16adf<a+>dfae16g16>c<eg<a>ceg<a+16>d16f<a+>d<ga+>d<a+g16a+16>d+<ga+>c+d+<a+>c+c+16e16>c+<c+e>c+<deae16g16>c+<eg>c+<eg>c+;";
  316.             mml+="%1@8s60l8@v126v14 $q5df<d>fce<c>e<a+>d<<a+>>d<a>cq8<<aq4>>cdfq8<dq4>fceq8<cq4>e<a+>dq8<<a+q4>>d<a>cq8<<aq4>>cq4< [da>d<a]4 q8dq4>dr4.<drdq8cq4>cr4.<crcq8<a+q4>a+r4.<a+ra+q8aq4>ar4.<araq8gq4>gr4.<grgq8>d+q4d+r4.d+rd+q8<aq4>ar4.areq8<aq4>ar4.ar<a;";
  318.             var playData:SiONData = driver.compile(mml);
  319.             driver.play(playData);
  320.         }
  322.         /**-----------------------------------------------------
  323.          * 毎フレームの処理。
  324.          * ----------------------------------------------------- */
  325.         private function loop(event:Event):void {
  326.             _yuusha3D.x = yuushaPos.x + FLDSIZE / 2;
  327.             _yuusha3D.y = yuushaPos.y + FLDSIZE / 2;
  329.             _world.camera.x = yuushaPos.x + FLDSIZE / 2;
  330.             _world.camera.y = yuushaPos.y + FLDSIZE + 100;
  332.             //20フレーム毎に処理する
  333.             if (frameCount++ > 20) {
  334.                 frameCount = 0;
  335.                 yuusha.walk();
  336.             }
  338.             //マップ（勇者）をどの方向に動かすか判定
  339.             if (yuushaPos.x % FLDSIZE == 0 && yuushaPos.y % FLDSIZE == 0) {
  340.                 var mapPosX:int = int(yuushaPos.x / FLDSIZE), mapPosY:int = int(yuushaPos.y / FLDSIZE);
  341.                 walkDirection = 4; //止まる
  342.                 switch (true) {
  343.                     case keyFlags[0]: //下
  344.                         if (yuushaPos.y < (MAPSIZE - 1) * FLDSIZE && !bMapData[mapPosX][mapPosY + 1])
  345.                             walkDirection = 0;
  346.                         yuusha.changeDirection(0);
  347.                         break;
  348.                     case keyFlags[1]: //上
  349.                         if (yuushaPos.y > 0 && !bMapData[mapPosX][mapPosY - 1])
  350.                             walkDirection = 1;
  351.                         yuusha.changeDirection(1);
  352.                         break;
  353.                     case keyFlags[2]: //左
  354.                         if (yuushaPos.x > 0 && !bMapData[mapPosX - 1][mapPosY])
  355.                             walkDirection = 2;
  356.                         yuusha.changeDirection(2);
  357.                         break;
  358.                     case keyFlags[3]: //右
  359.                         if (yuushaPos.x < (MAPSIZE - 1) * FLDSIZE && !bMapData[mapPosX + 1][mapPosY])
  360.                             walkDirection = 3;
  361.                         yuusha.changeDirection(3);
  362.                         break;
  363.                 }
  364.             }
  366.             //次のマスまで自動的に勇者を歩かせる
  367.             switch (walkDirection) {
  368.                 case 0:
  369.                     yuushaPos.y += SPEED;
  370.                     break;
  371.                 case 1:
  372.                     yuushaPos.y -= SPEED;
  373.                     break;
  374.                 case 2:
  375.                     yuushaPos.x -= SPEED;
  376.                     break;
  377.                 case 3:
  378.                     yuushaPos.x += SPEED;
  379.                     break;
  380.             }
  381.             if (walkDirection < 4)
  382.                 moveMap(yuushaPos);
  383.         }
  385.         /**-----------------------------------------------------
  386.          * マップの座標計算。
  387.          * ----------------------------------------------------- */
  388.         private function moveMap(pos:Point):void {
  389.             map.x = (SIZE - FLDSIZE) / 2 - yuushaPos.x;
  390.             map.y = (SIZE - FLDSIZE) / 2 - yuushaPos.y;
  391.         }
  393.         /**-----------------------------------------------------
  394.          * キーボードのキーが押された時の処理。
  395.          * ----------------------------------------------------- */
  396.         private function onKeyDown(event:KeyboardEvent):void {
  397.             switch (event.keyCode) {
  398.                 case Keyboard.DOWN:
  399.                 case "s".charAt(0): //↓ s
  400.                     keyFlags[0] = true;
  401.             }
  402.             switch (event.keyCode) {
  403.                 case Keyboard.UP:
  404.                 case "w".charAt(0): //↑ w
  405.                     keyFlags[1] = true;
  406.             }
  407.             switch (event.keyCode) {
  408.                 case Keyboard.LEFT:
  409.                 case "a".charAt(0): //← a
  410.                     keyFlags[2] = true;
  411.             }
  412.             switch (event.keyCode) {
  413.                 case Keyboard.RIGHT:
  414.                 case "d".charAt(0): //→ d
  415.                     keyFlags[3] = true;
  416.             }
  417.         }
  419.         /**-----------------------------------------------------
  420.          * キーボードのキーが離された時の処理。
  421.          * ----------------------------------------------------- */
  422.         private function onKeyUp(event:KeyboardEvent):void {
  423.             switch (event.keyCode) {
  424.                 case Keyboard.DOWN:
  425.                 case "s".charAt(0): //↓ s
  426.                     keyFlags[0] = false;
  427.             }
  428.             switch (event.keyCode) {
  429.                 case Keyboard.UP:
  430.                 case "w".charAt(0): //↑ w
  431.                     keyFlags[1] = false;
  432.             }
  433.             switch (event.keyCode) {
  434.                 case Keyboard.LEFT:
  435.                 case "a".charAt(0): //← a
  436.                     keyFlags[2] = false;
  437.             }
  438.             switch (event.keyCode) {
  439.                 case Keyboard.RIGHT:
  440.                 case "d".charAt(0): //→ d
  441.                     keyFlags[3] = false;
  442.             }
  443.         }
  444.     }
  445. }
  447. import flash.display.*;
  448. import flash.errors.*;
  449. import flash.events.*;
  450. import flash.net.URLRequest;
  451. import flash.system.LoaderContext;
  452. import alternativa.engine3d.controllers.CameraController;
  453. import alternativa.engine3d.core.Camera3D;
  454. import alternativa.engine3d.core.Object3D;
  455. import alternativa.engine3d.core.Scene3D;
  456. import alternativa.engine3d.display.View;
  457. import jp.progression.commands.lists.SerialList;
  458. import jp.progression.commands.net.LoadCommand;
  459. import jp.progression.data.Resource;
  460. import jp.progression.data.getResourceById;
  462. /**-----------------------------------------------------
  463.  * 勇者クラスです。勇者を作ったり、足踏させたり、向きを変えたりします。
  464.  * ----------------------------------------------------- */
  465. class Yuusha extends MovieClip {
  466.     /**-----------------------------------------------------
  467.      * コンストラクタ。
  468.      * ----------------------------------------------------- */
  469.     public function Yuusha():void {
  470.     }
  472.     public var direction:int = 0; //向き　（0:前　1：後　2：左　3：右）
  473.     private var walkFlag:Boolean = true; //足踏み用
  474.     private var yuushaImages:Array = []; //勇者の画像集
  476.     public function build(ImageURL:Array):void {
  477.         for (var i:uint = 0; i < 8; i++) {
  478.             var res:Resource = getResourceById(ImageURL[i]);
  479.             if (res) {
  480.                 var bmp:Bitmap = new Bitmap(res.toBitmapData());
  481.                 yuushaImages.push(bmp);
  482.                 if (i)
  483.                     yuushaImages[i].visible = false;
  484.                 addChild(yuushaImages[i]);
  485.             }
  486.         }
  487.     }
  489.     /**-----------------------------------------------------
  490.      * 向きを変更します。
  491.      * numは勇者の向きを表します。（0～3）
  492.      * ----------------------------------------------------- */
  493.     public function changeDirection(num:int):void {
  494.         direction = num;
  495.         for (var i:uint = 0; i < 8; i++) {
  496.             yuushaImages[i].visible = i == 2 * direction + int(walkFlag);
  497.         }
  498.     }
  500.     /**-----------------------------------------------------
  501.      * 足踏みさせます。
  502.      * ----------------------------------------------------- */
  503.     public function walk():void {
  504.         walkFlag = !walkFlag;
  505.         for (var i:uint = 0; i < 8; i++) {
  506.             yuushaImages[i].visible = i == 2 * direction + int(walkFlag);
  507.         }
  508.     }
  509. }
  511. /**-----------------------------------------------------
  512.  * Fieldクラスです。画像のURLと、そのフィールドが障害物か否かを保存します。
  513.  * ----------------------------------------------------- */
  514. class Field {
  515.     public function Field(s:String, b:Boolean = false):void {
  516.         url = s;
  517.         isObstacle = b;
  518.     }
  519.     public var isObstacle:Boolean; //障害物か否か （true:障害物　　false:障害物じゃない（歩ける））
  520.     public var url:String; //画像のURL
  521. }
  524. class BasicTemplate extends Sprite {
  526.     /**
  527.      * 新しい BasicTemplate インスタンスを作成します。
  528.      * @param    viewWidth
  529.      * @param    viewHeight
  530.      * @param    scaleToStage
  531.      */
  532.     public function BasicTemplate(viewWidth:int = 640, viewHeight:int = 480, scaleToStage:Boolean = true) {
  533.         _viewWidth = viewWidth;
  534.         _viewHeight = viewHeight;
  535.         _scaleToStage = scaleToStage;
  537.         // Creating scene
  538.         scene = new Scene3D();
  539.         scene.splitAnalysis = false; // not analysis for performance
  540.         scene.root = new Object3D();
  542.         // Adding camera
  543.         camera = new Camera3D();
  544.         camera.z = -1000;
  545.         scene.root.addChild(camera);
  547.         // camera contoller
  548.         cameraContoller = new CameraController(this);
  549.         cameraContoller.camera = camera;
  551.         // set view
  552.         view = new View();
  553.         view.camera = camera;
  554.         addChild(view);
  556.         // stage
  557.         if (stage)
  558.             init();
  559.         else
  560.             addEventListener(Event.ADDED_TO_STAGE, init);
  561.     }
  562.     /**
  563.      * カメラインスタンスです。
  564.      */
  565.     public var camera:Camera3D;
  566.     /**
  567.      * カメラコントローラーです。
  568.      */
  569.     public var cameraContoller:CameraController;
  570.     /**
  571.      * シーンインスタンスです。
  572.      */
  573.     public var scene:Scene3D;
  574.     /**
  575.      * ビューインスタンスです。
  576.      */
  577.     public var view:View;
  579.     /**
  580.      * Event.ENTER_FRAME 時に実行されるレンダリングのイベントです。
  581.      * レンダリング後に実行したい処理を記述します。
  582.      */
  583.     protected var _onPostRender:Function = function():void {};
  585.     /**
  586.      * 初期化されたときに実行されるイベントです。
  587.      * 初期化時に実行したい処理を記述します。
  588.      */
  589.     private var _onInit:Function = function():void {};
  591.     /**
  592.      * Event.ENTER_FRAME 時に実行されるレンダリングのイベントです。
  593.      * レンダリング前に実行したい処理を記述します。
  594.      */
  595.     private var _onPreRender:Function = function():void {};
  596.     private var _scaleToStage:Boolean;
  597.     private var _viewHeight:int;
  599.     private var _viewWidth:int;
  601.     public function get onInit():Function {
  602.         return _onInit;
  603.     }
  605.     public function set onInit(value:Function):void {
  606.         _onInit = value;
  607.     }
  609.     public function get onPostRender():Function {
  610.         return _onPostRender;
  611.     }
  613.     public function set onPostRender(value:Function):void {
  614.         _onPostRender = value;
  615.     }
  617.     public function get onPreRender():Function {
  618.         return _onPreRender;
  619.     }
  621.     public function set onPreRender(value:Function):void {
  622.         _onPreRender = value;
  623.     }
  625.     /**
  626.      * シングルレンダリング(レンダリングを一回だけ)を実行します。
  627.      */
  628.     public function singleRender():void {
  629.         onRenderTick();
  630.     }
  632.     /**
  633.      * レンダリングを開始します。
  634.      */
  635.     public function startRendering():void {
  636.         addEventListener(Event.ENTER_FRAME, onRenderTick);
  637.     }
  639.     /**
  640.      * レンダリングを停止します。
  641.      */
  642.     public function stopRendering():void {
  643.         removeEventListener(Event.ENTER_FRAME, onRenderTick);
  644.     }
  646.     /**
  647.      * 初期化されたときに実行されるイベントです。
  648.      * 初期化時に実行したい処理をオーバーライドして記述します。
  649.      */
  650.     protected function atInit():void {
  651.     }
  653.     /**
  654.      * Event.ENTER_FRAME 時に実行されるレンダリングのイベントです。
  655.      * レンダリング後に実行したい処理をオーバーライドして記述します。
  656.      */
  657.     protected function atPostRender():void {
  658.     }
  660.     /**
  661.      * Event.ENTER_FRAME 時に実行されるレンダリングのイベントです。
  662.      * レンダリング前に実行したい処理をオーバーライドして記述します。
  663.      */
  664.     protected function atPreRender():void {
  665.     }
  667.     /**
  668.      * @private
  669.      */
  670.     private function init(e:Event = null):void {
  671.         // resize
  672.         stage.addEventListener(Event.RESIZE, onResize);
  673.         onResize(null);
  675.         // render
  676.         startRendering();
  678.         atInit();
  679.         _onInit();
  681.     }
  683.     /**
  684.      * @private
  685.      */
  686.     private function onRenderTick(e:Event = null):void {
  687.         atPreRender();
  688.         _onPreRender();
  689.         scene.calculate();
  690.         atPostRender();
  691.         _onPostRender();
  692.     }
  694.     /**
  695.      * @private
  696.      */
  697.     private function onResize(event:Event = null):void {
  698.         if (_scaleToStage) {
  699.             view.width = stage.stageWidth;
  700.             view.height = stage.stageHeight;
  701.         } else {
  702.             view.width = _viewWidth;
  703.             view.height = _viewHeight;
  704.         }
  705.     }
  706. }
  708. /**
  709.  * クロスドメイン問題を無視してロードするLoadBitmapData
  710.  * @see http://wonderfl.net/code/5c164cb968b9883d1eee01b236c5206956e57545
  711.  */
  712. class IllegalLoadBitmapData extends LoadCommand {
  713.     public function IllegalLoadBitmapData(request:URLRequest, initObject:Object = null) {
  714.         // 引数を設定する
  715.         _request = request;
  717.         // 親クラスを初期化する
  718.         super(request, initObject);
  719.     }
  720.     private var _context:LoaderContext;
  721.     private var _request:URLRequest;
  722.     private var loaderA:Loader;
  723.     private var loaderB:Loader;
  725.     public function get context():LoaderContext {
  726.         return _context;
  727.     }
  729.     public function set context(value:LoaderContext):void {
  730.         _context = value;
  731.     }
  733.     override protected function executeFunction():void {
  734.         // Loader を作成する
  735.         loaderA = new Loader();
  737.         // イベントリスナーを登録する
  738.         loaderA.contentLoaderInfo.addEventListener(Event.COMPLETE, _complete1);
  739.         loaderA.contentLoaderInfo.addEventListener(IOErrorEvent.IO_ERROR, _ioError2);
  740.         loaderA.contentLoaderInfo.addEventListener(ProgressEvent.PROGRESS, super.dispatchEvent);
  742.         // ファイルを読み込む
  743.         loaderA.load(_request, context);
  744.     }
  746.     /**
  747.      * データが正常にロードされたときに送出されます。
  748.      */
  749.     private function _complete1(e:Event):void {
  750.         loaderB = new Loader();
  751.         loaderB.contentLoaderInfo.addEventListener(Event.INIT, _complete2);
  752.         loaderB.loadBytes(loaderA.contentLoaderInfo.bytes);
  753.     }
  755.     private function _complete2(e:Event):void {
  756.         var loader:Loader = e.currentTarget.loader;
  758.         var bmd:BitmapData = new BitmapData(loader.width, loader.height, true, 0x00000000);
  759.         bmd.draw(loader);
  761.         // データを保持する
  762.         super.data = bmd;
  764.         // 処理を終了する
  765.         super.executeComplete();
  766.     }
  768.     private function _ioError2(e:IOErrorEvent):void {
  769.         super.throwError(this, new IOError(e.text));
  770.     }
  771. }
noswf

[Alternativa3D] Wonderfl Quest 3D forked from: [Alternativa3D] Wonderfl Quest 3D+TAGOX [diff(15)]

  1. // forked from clockmaker's [Alternativa3D] Wonderfl Quest 3D
  2. // forked from osamX's ワンダフルクエスト
  3. // forked from nengafl's nengafl
  4. /**=====================================================
  5.  * clockmakerさんのWonderfl Quest 3D をfolkして勇者を俺のキャラに改造しました。
  6.  * clockさん、勝手な事をやってしまい、本当に申し訳御座いませんでした。
  7.  * [How to Play]
  8.  * up, w    : move up
  9.  * down, s  : move down
  10.  * left, a  : move left
  11.  * right, d : move right
  12.  *
  13.  * [Hint]
  14.  * You can change map with edit MAP_DATA
  15.  * ===================================================== */
  16. package {
  17.     import com.bit101.components.ProgressBar;
  18.     import flash.display.*;
  19.     import flash.events.*;
  20.     import flash.geom.Point;
  21.     import flash.net.URLRequest;
  22.     import flash.system.LoaderContext;
  23.     import flash.ui.Keyboard;
  24.     import alternativa.engine3d.materials.MovieClipMaterial;
  25.     import alternativa.engine3d.materials.TextureMaterial;
  26.     import alternativa.engine3d.primitives.Plane;
  27.     import alternativa.types.Texture;
  28.     import alternativa.utils.MathUtils;
  29.     import jp.progression.commands.lists.SerialList;
  30.     import jp.progression.data.Resource;
  31.     import jp.progression.data.getResourceById;
  33.     [SWF(width="465", height="465", frameRate="60", backgroundColor="0x000000")]
  34.     public class WonderflQuest extends Sprite {
  35.         private static const FLDSIZE:uint = 48; //フィールド（マップ上の1マス）の横・縦のドット数
  36.         private static const MAPSIZE:uint = 32; //マップの横・縦のマスの個数
  38.         /**-----------------------------------------------------
  39.          * マップのデータ（ここが木で、あそこが芝生で．．．ってやつ）が入ってます。
  40.          * ここをいじると、マップが変わります。上のfieldListのコメント参照。
  41.          * ----------------------------------------------------- */
  42.         private static const MAP_DATA:Array =
  43.             [
  44.             [9, 9, 9, 9, 9, 9, 9, 1, 1, 1, 2, 1, 1, 1, 1, 1, 0, 6, 1, 1, 1, 1, 1, 1, 1, 1, 2, 1, 1, 1, 1, 9],
  45.             [9, 9, 9, 9, 0, 0, 0, 0, 0, 1, 0, 1, 3, 3, 1, 1, 0, 0, 1, 1, 0, 0, 0, 0, 0, 1, 0, 1, 3, 3, 1, 9],
  46.             [9, 9, 9, 9, 0, 0, 0, 0, 0, 1, 0, 1, 3, 8, 3, 3, 0, 0, 1, 1, 0, 0, 0, 0, 0, 1, 0, 1, 3, 8, 3, 9],
  47.             [9, 9, 9, 9, 0, 0, 0, 0, 0, 1, 0, 1, 3, 3, 3, 3, 7, 0, 1, 1, 0, 0, 0, 0, 0, 1, 0, 1, 3, 3, 3, 9],
  48.             [9, 9, 9, 1, 1, 1, 1, 1, 0, 1, 0, 1, 3, 1, 1, 1, 0, 0, 1, 1, 1, 1, 1, 1, 0, 1, 0, 1, 3, 1, 1, 9],
  49.             [9, 9, 1, 1, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 1, 1, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 9],
  50.             [9, 9, 1, 1, 0, 0, 0, 7, 0, 0, 0, 1, 1, 1, 1, 1, 0, 0, 1, 1, 0, 0, 0, 7, 0, 0, 0, 1, 1, 1, 1, 9],
  51.             [9, 9, 1, 1, 0, 0, 0, 0, 0, 0, 6, 0, 0, 0, 0, 1, 0, 0, 1, 1, 0, 0, 0, 0, 0, 0, 6, 0, 0, 0, 0, 9],
  52.             [9, 9, 1, 1, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 1, 1, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 9],
  53.             [9, 9, 1, 1, 1, 1, 0, 1, 0, 0, 0, 1, 0, 0, 0, 0, 1, 0, 1, 1, 1, 1, 0, 1, 0, 0, 0, 1, 0, 0, 0, 9],
  54.             [9, 9, 1, 1, 1, 1, 1, 1, 0, 0, 0, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 0, 0, 0, 1, 1, 1, 1, 9],
  55.             [9, 9, 9, 9, 9, 9, 9, 9, 4, 4, 9, 9, 9, 9, 9, 9, 1, 1, 9, 9, 9, 9, 9, 9, 4, 4, 9, 9, 9, 9, 9, 9],
  56.             [9, 9, 0, 0, 0, 9, 9, 0, 0, 0, 0, 6, 0, 6, 6, 7, 1, 1, 0, 0, 0, 9, 9, 0, 0, 0, 0, 6, 0, 0, 0, 9],
  57.             [9, 9, 1, 0, 0, 5, 5, 0, 0, 0, 0, 0, 0, 0, 7, 0, 1, 1, 1, 0, 0, 5, 5, 0, 0, 0, 0, 0, 0, 0, 0, 9],
  58.             [9, 9, 1, 1, 9, 9, 9, 9, 0, 0, 1, 1, 0, 0, 6, 0, 1, 8, 1, 1, 9, 9, 9, 9, 0, 0, 1, 1, 0, 0, 6, 9],
  59.             [9, 9, 1, 9, 9, 9, 9, 9, 9, 9, 9, 9, 1, 1, 1, 0, 1, 1, 1, 9, 9, 9, 9, 9, 9, 9, 9, 9, 1, 1, 1, 9],
  60.             [9, 9, 1, 1, 1, 1, 1, 1, 1, 1, 2, 1, 1, 1, 1, 1, 0, 6, 1, 1, 1, 1, 1, 1, 1, 1, 2, 1, 1, 1, 1, 9],
  61.             [9, 9, 1, 1, 0, 0, 0, 0, 0, 1, 0, 1, 3, 3, 1, 1, 0, 0, 1, 1, 0, 0, 0, 0, 0, 1, 0, 1, 3, 3, 1, 9],
  62.             [9, 9, 1, 1, 0, 0, 0, 0, 0, 1, 0, 1, 3, 8, 3, 3, 0, 0, 1, 1, 0, 0, 0, 0, 0, 1, 0, 1, 3, 8, 3, 9],
  63.             [9, 9, 1, 1, 0, 0, 0, 0, 0, 1, 0, 1, 3, 3, 3, 3, 7, 0, 1, 1, 0, 0, 0, 0, 0, 1, 0, 1, 3, 3, 3, 9],
  64.             [9, 9, 1, 1, 1, 1, 1, 1, 0, 1, 0, 1, 3, 1, 1, 1, 0, 0, 1, 1, 1, 1, 1, 1, 0, 1, 0, 1, 3, 1, 1, 9],
  65.             [9, 9, 1, 1, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 1, 1, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 9],
  66.             [9, 9, 1, 1, 0, 0, 0, 7, 0, 0, 0, 1, 1, 1, 1, 1, 0, 0, 1, 1, 0, 0, 0, 7, 0, 0, 0, 1, 1, 1, 1, 9],
  67.             [9, 9, 1, 1, 0, 0, 0, 0, 0, 0, 6, 0, 0, 0, 0, 1, 0, 0, 1, 1, 0, 0, 0, 0, 0, 0, 6, 0, 0, 0, 0, 9],
  68.             [9, 9, 1, 1, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 1, 1, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 9],
  69.             [9, 9, 1, 1, 1, 1, 0, 1, 0, 0, 0, 1, 0, 0, 0, 0, 1, 0, 1, 1, 1, 1, 0, 1, 0, 0, 0, 1, 0, 0, 0, 9],
  70.             [9, 9, 1, 1, 1, 1, 1, 1, 0, 0, 0, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 0, 0, 0, 1, 1, 1, 1, 9],
  71.             [9, 9, 9, 9, 9, 9, 9, 9, 4, 4, 9, 9, 9, 9, 9, 9, 9, 9, 9, 9, 9, 9, 9, 9, 9, 9, 9, 9, 9, 9, 9, 9],
  72.             [9, 9, 0, 0, 0, 9, 9, 0, 0, 0, 0, 6, 0, 6, 0, 7, 1, 1, 0, 0, 9, 9, 9, 0, 0, 0, 0, 6, 0, 0, 0, 9],
  73.             [9, 9, 1, 0, 0, 5, 5, 0, 0, 0, 0, 0, 0, 0, 0, 0, 1, 1, 1, 0, 5, 5, 5, 0, 0, 0, 0, 0, 0, 0, 0, 9],
  74.             [9, 9, 9, 9, 9, 9, 9, 9, 9, 9, 9, 9, 9, 9, 9, 9, 9, 9, 9, 9, 9, 9, 9, 9, 9, 9, 9, 9, 9, 9, 9, 9],
  75.             [9, 9, 9, 9, 9, 9, 9, 9, 9, 9, 9, 9, 9, 9, 9, 9, 9, 9, 9, 9, 9, 9, 9, 9, 9, 9, 9, 9, 9, 9, 9, 9],
  77.             ];
  78.         private static const SCALE:Number = 3; //勇者やフィールドの拡大率
  79.         private static const SIZE:Number = 465; //ステージの大きさ
  80.         // 空の画像
  81.         private static const SKY_URL:String = "http://clockmaker.jp/labs/100109_wonderfl_quest/imgs/sky.png";
  82.         private static const SPEED:Number = 3; //勇者が歩くスピード FLDSIZEの約数にしてください
  84.         /**-----------------------------------------------------
  85.          * コンストラクタ。　ここが最初に処理されます。
  86.          * ----------------------------------------------------- */
  87.         public function WonderflQuest():void {
  88.             stage.quality = StageQuality.LOW;
  90.             _progress = new ProgressBar();
  91.             addChild(_progress);
  92.             _progress.x = (stage.stageWidth - _progress.width) / 2 >> 0
  93.             _progress.y = (stage.stageHeight - _progress.height) / 2 >> 0
  95.             createMap(); //マップを作る
  97.             yuusha = new Yuusha(); //勇者を作る
  98.             yuusha.scaleX = yuusha.scaleY = SCALE; //勇者を拡大表示
  99.             yuusha.x = yuusha.y = (SIZE - FLDSIZE) / 2; //中央に配置
  101.             yuushaPos = new Point(16 * FLDSIZE, 26 * FLDSIZE); //勇者初期位置
  102.             moveMap(yuushaPos); //マップ移動
  103.         }
  105.         /**-----------------------------------------------------
  106.          * マップの1マス（フィールド）のリストです。
  107.          * ここをいじると好きな画像をマップ上に貼ることができます。
  108.          * 画像のサイズは、基本的に16*16ピクセルです。
  109.          * 形式はjpeg,gif,pngのどれかにしてください。
  110.          * Twitterのアイコン画像取得は、こちらのAPIを使わせてもらってます。
  111.          * http://usericons.relucks.org/
  112.          * ----------------------------------------------------- */
  113.         private const FIELD_IMG_URLS:Array = [
  114.             new Field("http://flash-scope.com/wonderfl/WonderflQuest/map/map0.png", false), //[ 0]: 芝生
  115.             new Field("http://flash-scope.com/wonderfl/WonderflQuest/map/map1.png", false), //[ 1]: 砂
  116.             new Field("http://flash-scope.com/wonderfl/WonderflQuest/map/map2.png", false), //[ 2]: 石畳
  117.             new Field("http://flash-scope.com/wonderfl/WonderflQuest/map/map3.png", false), //[ 3]: フローリング
  118.             new Field("http://flash-scope.com/wonderfl/WonderflQuest/map/map4.png", false), //[ 4]: 橋（縦）
  119.             new Field("http://flash-scope.com/wonderfl/WonderflQuest/map/map5.png", false), //[ 5]: 橋（横）
  120.             new Field("http://clockmaker.jp/labs/100109_wonderfl_quest/imgs/map6.png", true), //[ 6]: 木（小）
  121.             new Field("http://clockmaker.jp/labs/100109_wonderfl_quest/imgs/map7.png", true), //[ 7]: 木（大）
  122.             new Field("http://clockmaker.jp/labs/100109_wonderfl_quest/imgs/ton.png", true), //[ 8]: サボテン
  123.             new Field("http://flash-scope.com/wonderfl/WonderflQuest/map/map9.png", true), //[ 9]: 水
  124.             ];
  125.         /**-----------------------------------------------------
  126.          * 勇者の画像のURLリスト
  127.          * ----------------------------------------------------- */
  128.         private const YUUSHA_IMG_URLS:Array = [
  129.             "http://img.f.hatena.ne.jp/images/fotolife/t/tagox_image/20100110/20100110163247.png", //前向き1
  130.             "http://img.f.hatena.ne.jp/images/fotolife/t/tagox_image/20100110/20100110163705.png", //前向き2
  131.             "http://img.f.hatena.ne.jp/images/fotolife/t/tagox_image/20100110/20100110163705.png", //後ろ向き1
  132.             "http://img.f.hatena.ne.jp/images/fotolife/t/tagox_image/20100110/20100110163247.png", //後ろ向き2
  133.             "http://img.f.hatena.ne.jp/images/fotolife/t/tagox_image/20100110/20100110164532.png", //左向き1
  134.             "http://img.f.hatena.ne.jp/images/fotolife/t/tagox_image/20100110/20100110164531.png", //左向き2
  135.             "http://img.f.hatena.ne.jp/images/fotolife/t/tagox_image/20100110/20100110164531.png", //右向き1
  136.             "http://img.f.hatena.ne.jp/images/fotolife/t/tagox_image/20100110/20100110164532.png" //右向き2
  137.             ];
  139.         private var _progress:ProgressBar;
  140.         private var _world:BasicTemplate; // Alternativa3Dのテンプレート
  142.         private var _yuusha3D:Plane;
  143.         private var bMapData:Array = []; //フィールドが障害物か否かを記憶
  144.         private var frameCount:Number = 0; //onEnterFrameで使用
  145.         private var keyFlags:Array = [false, false, false, false]; //下上左右のキーが押されているか
  146.         private var map:MovieClip; //マップ本体　これを動かして勇者が移動しているように見せる
  147.         private var walkDirection:int = 4; //歩いていく方向 （0～3：下上左右  4:止）
  149.         private var yuusha:Yuusha; //勇者
  150.         private var yuushaPos:Point; //勇者のマップ上の座標
  152.         /**-----------------------------------------------------
  153.          * マップを作ります。
  154.          * この実装方法は良くないです。遅いし、何回も同じ画像をロードしてます。
  155.          * 画像が別ドメインにある時に、crossdomain.xmlがなくても大丈夫なようにしています。
  156.          * ----------------------------------------------------- */
  157.         private function createMap():void {
  158.             var i:int;
  159.             var cmd:IllegalLoadBitmapData;
  161.             map = new MovieClip();
  162.             bMapData = [];
  164.             var list:SerialList = new SerialList();
  166.             // update progress bar
  167.             list.onPosition = function():void {
  168.                 _progress.value = list.position / list.numCommands;
  169.             };
  171.             // Load Field Images
  172.             for (i = 0; i < FIELD_IMG_URLS.length; i++) {
  173.                 cmd = new IllegalLoadBitmapData(new URLRequest(FIELD_IMG_URLS[i].url));
  174.                 cmd.context = new LoaderContext(true);
  175.                 cmd.catchError = function(target:Object, error:Error):void {
  176.                     target.executeComplete();
  177.                 };
  178.                 list.addCommand(cmd);
  179.             }
  181.             // Load Yuusha Images
  182.             for (i = 0; i < YUUSHA_IMG_URLS.length; i++) {
  183.                 cmd = new IllegalLoadBitmapData(new URLRequest(YUUSHA_IMG_URLS[i]));
  184.                 cmd.context = new LoaderContext(true);
  185.                 cmd.catchError = function(target:Object, error:Error):void {
  186.                     target.executeComplete();
  187.                 };
  188.                 list.addCommand(cmd);
  189.             }
  191.             // SKY IMAGE
  192.             list.addCommand(new IllegalLoadBitmapData(new URLRequest(SKY_URL), {context: new LoaderContext(true)}));
  194.             // init
  195.             list.addCommand(
  196.                 function():void {
  197.                     for (var i:uint = 0; i < MAPSIZE; i++) {
  198.                         bMapData[i] = [];
  199.                         for (var j:uint = 0; j < MAPSIZE; j++) {
  200.                             var field:Field = FIELD_IMG_URLS[MAP_DATA[j][i]];
  201.                             bMapData[i][j] = field.isObstacle;
  202.                             switch (MAP_DATA[j][i]) {
  203.                                 case 6:
  204.                                 case 7:
  205.                                     field = FIELD_IMG_URLS[0];
  206.                                     break;
  207.                                 case 8:
  208.                                     field = FIELD_IMG_URLS[1];
  209.                                     break;
  210.                             }
  212.                             var res:Resource = getResourceById(field.url);
  213.                             if (res) {
  214.                                 var bmp:Bitmap = new Bitmap(res.toBitmapData());
  215.                                 bmp.x = FLDSIZE * i;
  216.                                 bmp.y = FLDSIZE * j;
  217.                                 bmp.scaleX = bmp.scaleY = SCALE;
  218.                                 map.addChild(bmp);
  219.                             }
  220.                         }
  221.                     }
  223.                     // build bitmap object from images
  224.                     yuusha.build(YUUSHA_IMG_URLS);
  226.                     // 3Dの初期化
  227.                     init3D();
  229.                     //イベントリスナーの登録
  230.                     addEventListener(Event.ENTER_FRAME, loop);
  231.                 }
  232.                 );
  233.             list.execute();
  234.         }
  236.         /**
  237.          * Init Alternativa3D
  238.          *
  239.          */
  240.         private function init3D():void {
  241.             removeChild(_progress); //ロード画面非表示
  242.             stage.addEventListener(KeyboardEvent.KEY_DOWN, onKeyDown); //イベントリスナーの登録
  243.             stage.addEventListener(KeyboardEvent.KEY_UP, onKeyUp); //イベントリスナーの登録
  245.             var res:Resource = getResourceById(SKY_URL);
  246.             addChild(new Bitmap(res.toBitmapData()));
  248.             // Alternativa3Dを初期化
  249.             _world = new BasicTemplate(465, 465, true);
  250.             addChild(_world);
  252.             var bmd:BitmapData = new BitmapData(map.width, map.height);
  253.             bmd.draw(map);
  255.             var tex:Texture = new Texture(bmd);
  256.             var mat:TextureMaterial = new TextureMaterial(tex);
  258.             var fieldPlane:Plane = new Plane(map.width, map.height, 1, 1);
  259.             fieldPlane.cloneMaterialToAllSurfaces(mat);
  260.             _world.scene.root.addChild(fieldPlane);
  261.             fieldPlane.x = +map.width / 2 >> 0;
  262.             fieldPlane.y = +map.height / 2 >> 0;
  264.             var mcMat:MovieClipMaterial = new MovieClipMaterial(yuusha, FLDSIZE / SCALE, FLDSIZE / SCALE);
  265.             _yuusha3D = new Plane(FLDSIZE, FLDSIZE, 1, 1);
  266.             _yuusha3D.cloneMaterialToAllSurfaces(mcMat);
  268.             _yuusha3D.z = -yuusha.height / 2;
  269.             _yuusha3D.rotationX = MathUtils.toRadian(90);
  271.             _world.scene.root.addChild(_yuusha3D);
  272.             _world.camera.z = -40;
  274.             _world.camera.rotationY = MathUtils.toRadian(180);
  275.             _world.camera.rotationX = MathUtils.toRadian(-100);
  276.             _world.camera.rotationZ = MathUtils.toRadian(180);
  278.             var field:Field;
  279.             var mat2:TextureMaterial;
  280.             var tree:Plane;
  282.             // 木とさぼ㌧だけ立体にする
  283.             for (var i:uint = 0; i < MAPSIZE; i++) {
  284.                 for (var j:uint = 0; j < MAPSIZE; j++) {
  285.                     switch (MAP_DATA[i][j]) {
  286.                         case 6:
  287.                         case 7:
  288.                         case 8:
  289.                             field = FIELD_IMG_URLS[MAP_DATA[i][j]];
  290.                             res = getResourceById(field.url);
  291.                             if (res) {
  292.                                 mat2 = new TextureMaterial(new Texture(res.toBitmapData()));
  293.                                 tree = new Plane(FLDSIZE, FLDSIZE, 1, 1, true);
  294.                                 tree.cloneMaterialToAllSurfaces(mat2);
  295.                                 _world.scene.root.addChild(tree);
  296.                                 tree.x = FLDSIZE * j + FLDSIZE / 2;
  297.                                 tree.y = FLDSIZE * i + FLDSIZE / 2;
  298.                                 tree.z = -FLDSIZE / 2;
  299.                                 tree.rotationX = MathUtils.toRadian(90);
  300.                             }
  301.                             break;
  302.                     }
  303.                 }
  304.             }
  305.         }
  307.         /**-----------------------------------------------------
  308.          * 毎フレームの処理。
  309.          * ----------------------------------------------------- */
  310.         private function loop(event:Event):void {
  311.             _yuusha3D.x = yuushaPos.x + FLDSIZE / 2;
  312.             _yuusha3D.y = yuushaPos.y + FLDSIZE / 2;
  314.             _world.camera.x = yuushaPos.x + FLDSIZE / 2;
  315.             _world.camera.y = yuushaPos.y + FLDSIZE + 100;
  317.             //20フレーム毎に処理する
  318.             if (frameCount++ > 20) {
  319.                 frameCount = 0;
  320.                 yuusha.walk();
  321.             }
  323.             //マップ（勇者）をどの方向に動かすか判定
  324.             if (yuushaPos.x % FLDSIZE == 0 && yuushaPos.y % FLDSIZE == 0) {
  325.                 var mapPosX:int = int(yuushaPos.x / FLDSIZE), mapPosY:int = int(yuushaPos.y / FLDSIZE);
  326.                 walkDirection = 4; //止まる
  327.                 switch (true) {
  328.                     case keyFlags[0]: //下
  329.                         if (yuushaPos.y < (MAPSIZE - 1) * FLDSIZE && !bMapData[mapPosX][mapPosY + 1])
  330.                             walkDirection = 0;
  331.                         yuusha.changeDirection(0);
  332.                         break;
  333.                     case keyFlags[1]: //上
  334.                         if (yuushaPos.y > 0 && !bMapData[mapPosX][mapPosY - 1])
  335.                             walkDirection = 1;
  336.                         yuusha.changeDirection(1);
  337.                         break;
  338.                     case keyFlags[2]: //左
  339.                         if (yuushaPos.x > 0 && !bMapData[mapPosX - 1][mapPosY])
  340.                             walkDirection = 2;
  341.                         yuusha.changeDirection(2);
  342.                         break;
  343.                     case keyFlags[3]: //右
  344.                         if (yuushaPos.x < (MAPSIZE - 1) * FLDSIZE && !bMapData[mapPosX + 1][mapPosY])
  345.                             walkDirection = 3;
  346.                         yuusha.changeDirection(3);
  347.                         break;
  348.                 }
  349.             }
  351.             //次のマスまで自動的に勇者を歩かせる
  352.             switch (walkDirection) {
  353.                 case 0:
  354.                     yuushaPos.y += SPEED;
  355.                     break;
  356.                 case 1:
  357.                     yuushaPos.y -= SPEED;
  358.                     break;
  359.                 case 2:
  360.                     yuushaPos.x -= SPEED;
  361.                     break;
  362.                 case 3:
  363.                     yuushaPos.x += SPEED;
  364.                     break;
  365.             }
  366.             if (walkDirection < 4)
  367.                 moveMap(yuushaPos);
  368.         }
  370.         /**-----------------------------------------------------
  371.          * マップの座標計算。
  372.          * ----------------------------------------------------- */
  373.         private function moveMap(pos:Point):void {
  374.             map.x = (SIZE - FLDSIZE) / 2 - yuushaPos.x;
  375.             map.y = (SIZE - FLDSIZE) / 2 - yuushaPos.y;
  376.         }
  378.         /**-----------------------------------------------------
  379.          * キーボードのキーが押された時の処理。
  380.          * ----------------------------------------------------- */
  381.         private function onKeyDown(event:KeyboardEvent):void {
  382.             switch (event.keyCode) {
  383.                 case Keyboard.DOWN:
  384.                 case "s".charAt(0): //↓ s
  385.                     keyFlags[0] = true;
  386.             }
  387.             switch (event.keyCode) {
  388.                 case Keyboard.UP:
  389.                 case "w".charAt(0): //↑ w
  390.                     keyFlags[1] = true;
  391.             }
  392.             switch (event.keyCode) {
  393.                 case Keyboard.LEFT:
  394.                 case "a".charAt(0): //← a
  395.                     keyFlags[2] = true;
  396.             }
  397.             switch (event.keyCode) {
  398.                 case Keyboard.RIGHT:
  399.                 case "d".charAt(0): //→ d
  400.                     keyFlags[3] = true;
  401.             }
  402.         }
  404.         /**-----------------------------------------------------
  405.          * キーボードのキーが離された時の処理。
  406.          * ----------------------------------------------------- */
  407.         private function onKeyUp(event:KeyboardEvent):void {
  408.             switch (event.keyCode) {
  409.                 case Keyboard.DOWN:
  410.                 case "s".charAt(0): //↓ s
  411.                     keyFlags[0] = false;
  412.             }
  413.             switch (event.keyCode) {
  414.                 case Keyboard.UP:
  415.                 case "w".charAt(0): //↑ w
  416.                     keyFlags[1] = false;
  417.             }
  418.             switch (event.keyCode) {
  419.                 case Keyboard.LEFT:
  420.                 case "a".charAt(0): //← a
  421.                     keyFlags[2] = false;
  422.             }
  423.             switch (event.keyCode) {
  424.                 case Keyboard.RIGHT:
  425.                 case "d".charAt(0): //→ d
  426.                     keyFlags[3] = false;
  427.             }
  428.         }
  429.     }
  430. }
  432. import flash.display.*;
  433. import flash.errors.*;
  434. import flash.events.*;
  435. import flash.net.URLRequest;
  436. import flash.system.LoaderContext;
  437. import alternativa.engine3d.controllers.CameraController;
  438. import alternativa.engine3d.core.Camera3D;
  439. import alternativa.engine3d.core.Object3D;
  440. import alternativa.engine3d.core.Scene3D;
  441. import alternativa.engine3d.display.View;
  442. import jp.progression.commands.lists.SerialList;
  443. import jp.progression.commands.net.LoadCommand;
  444. import jp.progression.data.Resource;
  445. import jp.progression.data.getResourceById;
  447. /**-----------------------------------------------------
  448.  * 勇者クラスです。勇者を作ったり、足踏させたり、向きを変えたりします。
  449.  * ----------------------------------------------------- */
  450. class Yuusha extends MovieClip {
  451.     /**-----------------------------------------------------
  452.      * コンストラクタ。
  453.      * ----------------------------------------------------- */
  454.     public function Yuusha():void {
  455.     }
  457.     public var direction:int = 0; //向き　（0:前　1：後　2：左　3：右）
  458.     private var walkFlag:Boolean = true; //足踏み用
  459.     private var yuushaImages:Array = []; //勇者の画像集
  461.     public function build(ImageURL:Array):void {
  462.         for (var i:uint = 0; i < 8; i++) {
  463.             var res:Resource = getResourceById(ImageURL[i]);
  464.             if (res) {
  465.                 var bmp:Bitmap = new Bitmap(res.toBitmapData());
  466.                 yuushaImages.push(bmp);
  467.                 if (i)
  468.                     yuushaImages[i].visible = false;
  469.                 addChild(yuushaImages[i]);
  470.             }
  471.         }
  472.     }
  474.     /**-----------------------------------------------------
  475.      * 向きを変更します。
  476.      * numは勇者の向きを表します。（0～3）
  477.      * ----------------------------------------------------- */
  478.     public function changeDirection(num:int):void {
  479.         direction = num;
  480.         for (var i:uint = 0; i < 8; i++) {
  481.             yuushaImages[i].visible = i == 2 * direction + int(walkFlag);
  482.         }
  483.     }
  485.     /**-----------------------------------------------------
  486.      * 足踏みさせます。
  487.      * ----------------------------------------------------- */
  488.     public function walk():void {
  489.         walkFlag = !walkFlag;
  490.         for (var i:uint = 0; i < 8; i++) {
  491.             yuushaImages[i].visible = i == 2 * direction + int(walkFlag);
  492.         }
  493.     }
  494. }
  496. /**-----------------------------------------------------
  497.  * Fieldクラスです。画像のURLと、そのフィールドが障害物か否かを保存します。
  498.  * ----------------------------------------------------- */
  499. class Field {
  500.     public function Field(s:String, b:Boolean = false):void {
  501.         url = s;
  502.         isObstacle = b;
  503.     }
  504.     public var isObstacle:Boolean; //障害物か否か （true:障害物　　false:障害物じゃない（歩ける））
  505.     public var url:String; //画像のURL
  506. }
  509. class BasicTemplate extends Sprite {
  511.     /**
  512.      * 新しい BasicTemplate インスタンスを作成します。
  513.      * @param    viewWidth
  514.      * @param    viewHeight
  515.      * @param    scaleToStage
  516.      */
  517.     public function BasicTemplate(viewWidth:int = 640, viewHeight:int = 480, scaleToStage:Boolean = true) {
  518.         _viewWidth = viewWidth;
  519.         _viewHeight = viewHeight;
  520.         _scaleToStage = scaleToStage;
  522.         // Creating scene
  523.         scene = new Scene3D();
  524.         scene.splitAnalysis = false; // not analysis for performance
  525.         scene.root = new Object3D();
  527.         // Adding camera
  528.         camera = new Camera3D();
  529.         camera.z = -1000;
  530.         scene.root.addChild(camera);
  532.         // camera contoller
  533.         cameraContoller = new CameraController(this);
  534.         cameraContoller.camera = camera;
  536.         // set view
  537.         view = new View();
  538.         view.camera = camera;
  539.         addChild(view);
  541.         // stage
  542.         if (stage)
  543.             init();
  544.         else
  545.             addEventListener(Event.ADDED_TO_STAGE, init);
  546.     }
  547.     /**
  548.      * カメラインスタンスです。
  549.      */
  550.     public var camera:Camera3D;
  551.     /**
  552.      * カメラコントローラーです。
  553.      */
  554.     public var cameraContoller:CameraController;
  555.     /**
  556.      * シーンインスタンスです。
  557.      */
  558.     public var scene:Scene3D;
  559.     /**
  560.      * ビューインスタンスです。
  561.      */
  562.     public var view:View;
  564.     /**
  565.      * Event.ENTER_FRAME 時に実行されるレンダリングのイベントです。
  566.      * レンダリング後に実行したい処理を記述します。
  567.      */
  568.     protected var _onPostRender:Function = function():void {};
  570.     /**
  571.      * 初期化されたときに実行されるイベントです。
  572.      * 初期化時に実行したい処理を記述します。
  573.      */
  574.     private var _onInit:Function = function():void {};
  576.     /**
  577.      * Event.ENTER_FRAME 時に実行されるレンダリングのイベントです。
  578.      * レンダリング前に実行したい処理を記述します。
  579.      */
  580.     private var _onPreRender:Function = function():void {};
  581.     private var _scaleToStage:Boolean;
  582.     private var _viewHeight:int;
  584.     private var _viewWidth:int;
  586.     public function get onInit():Function {
  587.         return _onInit;
  588.     }
  590.     public function set onInit(value:Function):void {
  591.         _onInit = value;
  592.     }
  594.     public function get onPostRender():Function {
  595.         return _onPostRender;
  596.     }
  598.     public function set onPostRender(value:Function):void {
  599.         _onPostRender = value;
  600.     }
  602.     public function get onPreRender():Function {
  603.         return _onPreRender;
  604.     }
  606.     public function set onPreRender(value:Function):void {
  607.         _onPreRender = value;
  608.     }
  610.     /**
  611.      * シングルレンダリング(レンダリングを一回だけ)を実行します。
  612.      */
  613.     public function singleRender():void {
  614.         onRenderTick();
  615.     }
  617.     /**
  618.      * レンダリングを開始します。
  619.      */
  620.     public function startRendering():void {
  621.         addEventListener(Event.ENTER_FRAME, onRenderTick);
  622.     }
  624.     /**
  625.      * レンダリングを停止します。
  626.      */
  627.     public function stopRendering():void {
  628.         removeEventListener(Event.ENTER_FRAME, onRenderTick);
  629.     }
  631.     /**
  632.      * 初期化されたときに実行されるイベントです。
  633.      * 初期化時に実行したい処理をオーバーライドして記述します。
  634.      */
  635.     protected function atInit():void {
  636.     }
  638.     /**
  639.      * Event.ENTER_FRAME 時に実行されるレンダリングのイベントです。
  640.      * レンダリング後に実行したい処理をオーバーライドして記述します。
  641.      */
  642.     protected function atPostRender():void {
  643.     }
  645.     /**
  646.      * Event.ENTER_FRAME 時に実行されるレンダリングのイベントです。
  647.      * レンダリング前に実行したい処理をオーバーライドして記述します。
  648.      */
  649.     protected function atPreRender():void {
  650.     }
  652.     /**
  653.      * @private
  654.      */
  655.     private function init(e:Event = null):void {
  656.         // resize
  657.         stage.addEventListener(Event.RESIZE, onResize);
  658.         onResize(null);
  660.         // render
  661.         startRendering();
  663.         atInit();
  664.         _onInit();
  666.     }
  668.     /**
  669.      * @private
  670.      */
  671.     private function onRenderTick(e:Event = null):void {
  672.         atPreRender();
  673.         _onPreRender();
  674.         scene.calculate();
  675.         atPostRender();
  676.         _onPostRender();
  677.     }
  679.     /**
  680.      * @private
  681.      */
  682.     private function onResize(event:Event = null):void {
  683.         if (_scaleToStage) {
  684.             view.width = stage.stageWidth;
  685.             view.height = stage.stageHeight;
  686.         } else {
  687.             view.width = _viewWidth;
  688.             view.height = _viewHeight;
  689.         }
  690.     }
  691. }
  693. /**
  694.  * クロスドメイン問題を無視してロードするLoadBitmapData
  695.  * @see http://wonderfl.net/code/5c164cb968b9883d1eee01b236c5206956e57545
  696.  */
  697. class IllegalLoadBitmapData extends LoadCommand {
  698.     public function IllegalLoadBitmapData(request:URLRequest, initObject:Object = null) {
  699.         // 引数を設定する
  700.         _request = request;
  702.         // 親クラスを初期化する
  703.         super(request, initObject);
  704.     }
  705.     private var _context:LoaderContext;
  706.     private var _request:URLRequest;
  707.     private var loaderA:Loader;
  708.     private var loaderB:Loader;
  710.     public function get context():LoaderContext {
  711.         return _context;
  712.     }
  714.     public function set context(value:LoaderContext):void {
  715.         _context = value;
  716.     }
  718.     override protected function executeFunction():void {
  719.         // Loader を作成する
  720.         loaderA = new Loader();
  722.         // イベントリスナーを登録する
  723.         loaderA.contentLoaderInfo.addEventListener(Event.COMPLETE, _complete1);
  724.         loaderA.contentLoaderInfo.addEventListener(IOErrorEvent.IO_ERROR, _ioError2);
  725.         loaderA.contentLoaderInfo.addEventListener(ProgressEvent.PROGRESS, super.dispatchEvent);
  727.         // ファイルを読み込む
  728.         loaderA.load(_request, context);
  729.     }
  731.     /**
  732.      * データが正常にロードされたときに送出されます。
  733.      */
  734.     private function _complete1(e:Event):void {
  735.         loaderB = new Loader();
  736.         loaderB.contentLoaderInfo.addEventListener(Event.INIT, _complete2);
  737.         loaderB.loadBytes(loaderA.contentLoaderInfo.bytes);
  738.     }
  740.     private function _complete2(e:Event):void {
  741.         var loader:Loader = e.currentTarget.loader;
  743.         var bmd:BitmapData = new BitmapData(loader.width, loader.height, true, 0x00000000);
  744.         bmd.draw(loader);
  746.         // データを保持する
  747.         super.data = bmd;
  749.         // 処理を終了する
  750.         super.executeComplete();
  751.     }
  753.     private function _ioError2(e:IOErrorEvent):void {
  754.         super.throwError(this, new IOError(e.text));
  755.     }
  756. }
noswf
Get Adobe Flash Player