※現在、「wonderfl build flash online」求人コンテンツ制作に関してのアンケートを実施中です！みなさまのお力添えを頂いて、続々とアンケート結果が集まっていますが、まだまだ募集しております。ご協力のほど、どうぞよろしくお願いいたします！

wonderfl運営事務局
→アンケートページ（※ログインしてからお答えいただけるようになっています。）

 notice: Flash editor updated! Join the development! Thanks to MiniBuilder


forked from : keno42's ちょっと変えたけどそんなに速くならなかった [diff(11)]

embed

noswf download fullscreen
flash swf thumbnail play
reload download fullscreen

FORKED
>sort

画像をトリミングしてみた（中心点未調整） forked from: 画像をトリミングしてみた（中心点未調整） [diff(2)]

  1. // forked from nemu90kWw's 画像をトリミングしてみた（中心点未調整）
  2. // forked from keno42's ちょっと変えたけどそんなに速くならなかった
  3. // forked from keno42's forked from: forked from: 速度比較したら一個前の方法が速かったっぽい
  4. // forked from keno42's forked from: 速度比較したら一個前の方法が速かったっぽい
  5. // forked from keno42's 速度比較したら一個前の方法が速かったっぽい
  6. // forked from bkzen's forked from: 色と透明度もいれてみた。こんなのどうだろバージョン
  7. // forked from bkzen's 色と透明度もいれてみた。速度向上したらいいなばーじょん
  8. // forked from keno42's 角度計算修正、色と透明度もいれてみた。重ね順ソートが重い。
  9. // forked from bkzen's forked from: BitmapDataで配列に格納すると高速化するよ(角度修正)
  10. // forked from clockmaker's BitmapDataで配列に格納すると高速化するよ
  11. // forked from clockmaker's 3D Flow Simulation with Field of Blur
  12. // forked from clockmaker's 3D Flow Simulation
  13. // forked from clockmaker's Interactive Liquid 10000
  14. // forked from clockmaker's Liquid110000 By Vector
  15. // forked from munegon's forked from: forked from: forked from: forked from: Liquid10000
  16. // forked from Saqoosha's forked from: forked from: forked from: Liquid10000
  17. // forked from nutsu's forked from: forked from: Liquid10000
  18. // forked from nutsu's forked from: Liquid10000
  19. // forked from zin0086's Liquid10000
  20. package 
  21. {
  22.     /**
  23.      * 矢印がいっぱいなんだけど、高速なデモ
  24.      * 画質はディフォルトの StageQuality.HIGH で
  25.      * 矢印 1000個
  26.      * @author Yasu
  27.      */
  28.     import flash.display.*;
  29.     import flash.geom.*;
  30.     import flash.events.*;
  31.     import flash.filters.*;
  32.     import flash.utils.*;
  33.     import flash.geom.*;
  34.     import net.hires.debug.Stats;
  35.     
  36.     [SWF(width="465", height="465", backgroundColor="0xFFFFFF")]
  37.     public class Main extends Sprite {
  38.         private const NUM_PARTICLE:uint = 10;        
  39.         private const ROT_STEPS:int = 128;
  40.         private const ALPHA_STEPS:int = 10;
  41.         
  42.         private var forceMap:BitmapData = new BitmapData( 233, 233, false, 0x000000 );
  43.         private var randomSeed:uint = Math.floor( Math.random() * 0xFFFF );
  44.         private var particleList:Vector.<Arrow> = new Vector.<Arrow>(NUM_PARTICLE, true);
  45.         private var seed:Number = Math.floor( Math.random() * 0xFFFF );
  46.         private var offset:Array = [new Point(), new Point()];
  47.         private var timer:Timer;
  48.         private var world:Sprite = new Sprite();
  49.         private var childrenArr:Vector.<Sprite> = new Vector.<Sprite>(ALPHA_STEPS, true);
  50.         private var rotArr:Vector.<BitmapData> = new Vector.<BitmapData>(ROT_STEPS * ALPHA_STEPS, true);
  51.         private var multiplyConst:Number = 64 / Math.PI;
  53.         public function Main() {
  54.             
  55.             stage.align = StageAlign.TOP_LEFT;
  56.             stage.scaleMode = StageScaleMode.NO_SCALE;
  57.             stage.frameRate = 60;
  58.             
  59.             addChild(world);
  60.             
  61.             // フォースマップの初期化をおこないます
  62.             resetFunc();
  63.             
  64.             // ループ処理
  65.             addEventListener( Event.ENTER_FRAME, loop );
  66.             
  67.             // 時間差でフォースマップと色変化の具合を変更しています
  68.             var timer:Timer = new Timer(1000)
  69.             timer.addEventListener(TimerEvent.TIMER, resetFunc);
  70.             timer.start();
  71.             
  72.             // 矢印をプレレンダリング
  73.             var dummy:Sprite = new Sprite();
  74.             dummy.graphics.beginFill(0xFF4444, 1);
  75.             dummy.graphics.lineStyle(1, 0x0, 1);
  76.             dummy.graphics.moveTo(2, 4);
  77.             dummy.graphics.lineTo(8, 4);
  78.             dummy.graphics.lineTo(8, 0);
  79.             dummy.graphics.lineTo(20, 7);
  80.             dummy.graphics.lineTo(8, 14);
  81.             dummy.graphics.lineTo(8, 10);
  82.             dummy.graphics.lineTo(2, 10);
  83.             dummy.graphics.lineTo(2, 4);
  84.             var dummyBg:Sprite = new Sprite();
  85.             dummyBg.graphics.beginFill(0x4444FF, 0.5);
  86.             dummyBg.graphics.lineStyle(1, 0x0, 1);
  87.             dummyBg.graphics.moveTo(2, 4);
  88.             dummyBg.graphics.lineTo(8, 4);
  89.             dummyBg.graphics.lineTo(8, 0);
  90.             dummyBg.graphics.lineTo(20, 7);
  91.             dummyBg.graphics.lineTo(8, 14);
  92.             dummyBg.graphics.lineTo(8, 10);
  93.             dummyBg.graphics.lineTo(2, 10);
  94.             dummyBg.graphics.lineTo(2, 4);
  95.             var dummyHolder:Sprite = new Sprite();
  96.             dummyHolder.addChild(dummyBg);
  97.             dummyHolder.addChild(dummy);
  98.             var matrix:Matrix;
  99.             var j:int = ALPHA_STEPS;
  100.             var temp:BitmapData;
  101.             var rect:Rectangle;
  102.             while(j--){
  103.                 var i:int = ROT_STEPS;
  104.                 var k:int = j * ROT_STEPS;
  105.                 var sp: Sprite = new Sprite();
  106.                 world.addChild(sp);
  107.                 // 忘れがちだけどこれ入れるだけでマウスが乗った時の重さが違う
  108.                 sp.mouseChildren = sp.mouseEnabled = false;
  109.                 childrenArr[ALPHA_STEPS-1-j] = sp;
  110.                 dummy.alpha = j / (ALPHA_STEPS-1);
  111.                 dummyBg.filters = [new BlurFilter(4.0*(1.0 - j / (ALPHA_STEPS-1)),4.0*(1.0 - j / (ALPHA_STEPS-1)))];
  112.                 dummy.filters = [new BlurFilter(4.0*(1.0 - j / (ALPHA_STEPS-1)),4.0*(1.0 - j / (ALPHA_STEPS-1)))];
  113.                 while (i--)
  114.                 {
  115.                     matrix = new Matrix();
  116.                     matrix.translate( -11, -11);
  117.                     matrix.rotate( ( 360 / ROT_STEPS * i )* Math.PI / 180);
  118.                     matrix.translate( 11, 11);
  119.                     temp = new BitmapData(22, 22, true, 0x0);
  120.                     temp.draw(dummyHolder, matrix);
  121.                     
  122.                     // トリミング処理（中心点の調整はしてない）
  123.                     rect = temp.getColorBoundsRect(0xFF000000, 0x00000000);
  124.                     rotArr[i+k] = new BitmapData(rect.width, rect.height, true, 0x0);
  125.                     rotArr[i+k].copyPixels(temp, rect, new Point(0, 0));
  126.                 }
  127.             }
  128.             
  129.             // パーティクルを生成します
  130.             for (i = 0; i < NUM_PARTICLE; i++) {
  131.                 var px:Number = Math.random() * 465;
  132.                 var py:Number = Math.random() * 465;
  133.                 particleList[i] = new Arrow(px, py);
  134.                 world.addChild(particleList[i]);
  135.             }
  136.             
  137.             // デバッグ用のスタッツを表示しています
  138.             addChild(new Stats);
  139.         }
  140.         private function loop( e:Event ):void {
  141.             
  142.             var len:uint = particleList.length;
  143.             var col:Number;
  144. //            var changedCount:int = 0;
  145.             for (var i:uint = 0; i < len; i++) {
  146.                 
  147.                 var arrow:Arrow = particleList[i];
  148.                 
  149.                 var oldX:Number = arrow.x;
  150.                 var oldY:Number = arrow.y;
  151.                 
  152.                 col = forceMap.getPixel( arrow.x >> 1, arrow.y >> 1);
  153.                 arrow.ax += ( (col      & 0xff) - 0x80 ) * .0005;
  154.                 arrow.ay += ( (col >> 8 & 0xff) - 0x80 ) * .0005;
  155.                 arrow.vx += arrow.ax;
  156.                 arrow.vy += arrow.ay;
  157.                 arrow.x += arrow.vx;
  158.                 arrow.y += arrow.vy;
  159.                 
  160.                 var _posX:Number = arrow.x;
  161.                 var _posY:Number = arrow.y;
  162.                 
  163.                 // rot成分
  164.                 // var rot:Number = - Math.atan2((_posX - oldX), (_posY - oldY)) * 180 / Math.PI + 90;
  165.                 // var angle:int = rot / 360 * ROT_STEPS | 0;
  166.                 // Math.absの高速化ね
  167.                 // angle = (angle ^ (angle >> 31)) - (angle >> 31);
  168.                 // angle = (angle + 130) & 119; // (angle + 130) % 120 の高速化
  169.                 // ↑これ & 2^n-1 になるときでないと使えないと思う
  170.                 // angle = (angle + 130) % 120;
  171.                 // arrow.rot += (angle - arrow.rot) * 0.2;
  172.                 
  173.                 // 計算式を簡単にしてみたのとビット演算使えるようにかえてみた
  174.         var rot:Number = Math.atan2( arrow.vy, arrow.vx );
  175.         arrow.rot = (128 + rot * multiplyConst) & 127;
  176.                 
  177.                 // alpha成分
  178.                 var speed:int = (arrow.vx*arrow.vx + arrow.vy*arrow.vy) >> 1; // *0.5
  179.                 speed = Math.min(ALPHA_STEPS-1, speed);
  180.                 arrow.bitmapData = rotArr[arrow.rot + ROT_STEPS * speed];
  182.                 // speedに応じてソート。これが重い
  183.                 // こんなのはどうだろう？
  184.                 // fps 29-31
  185.                 // Sprite(world.getChildAt(speed)).addChild(arrow);
  187.                 // fps 30-33
  188.                 // childrenArr[speed].addChild(arrow);
  189.                 
  190.                 // fps 35-38
  191.                 //if( arrow.parent != world.getChildAt(speed) )
  192.                 //    Sprite(world.getChildAt(speed)).addChild(arrow);
  193.                     
  194.                 // fps 37-39
  195.                 if( arrow.parent != childrenArr[speed] )
  196.                     childrenArr[speed].addChild(arrow);
  197. //                    changedCount++;
  198.                 
  199.                 arrow.ax *= .96;
  200.                 arrow.ay *= .96;
  201.                 arrow.vx *= .92;
  202.                 arrow.vy *= .92;
  203.                 
  204.                 // あと配置座標を整数化しておきます
  205.                 arrow.x = arrow.x | 0;
  206.                 arrow.y = arrow.y | 0;
  207.                 
  208.                 ( _posX > 465 ) ? arrow.x = 0 :
  209.                     ( _posX < 0 ) ? arrow.x = 465 : 0;
  210.                 ( _posY > 465 ) ? arrow.y = 0 :
  211.                     ( _posY < 0 ) ? arrow.y = 465 : 0;
  212.             }
  213. //            trace( changedCount ); // 大体100-150, 多いときで250程度
  214.         }
  215.         
  216.         private function resetFunc(e:Event = null):void{
  217.             forceMap.perlinNoise(117, 117, 3, seed, false, true, 6, false, offset);
  218.             
  219.             offset[0].x += 1.5;
  220.             offset[1].y += 1;
  221.             seed = Math.floor( Math.random() * 0xFFFFFF );
  222.         }
  223.     }
  224. }
  226. import flash.display.*;
  228. class Arrow extends Bitmap
  229. {
  230.     public var rot:int = 0;
  231.     public var vx:Number = 0;
  232.     public var vy:Number = 0;
  233.     public var ax:Number = 0;
  234.     public var ay:Number = 0;
  236.     function Arrow( x:Number, y:Number) {
  237.         this.x = x;
  238.         this.y = y;
  239.     }
  240. }
noswf

画像をトリミングしてみた（中心点未調整） BitmapData直描きにすれば残像付きでも超軽いよ [diff(303)]

  1. // forked from nemu90kWw's 画像をトリミングしてみた（中心点未調整）
  2. // forked from keno42's ちょっと変えたけどそんなに速くならなかった
  3. // forked from keno42's forked from: forked from: 速度比較したら一個前の方法が速かったっぽい
  4. // forked from keno42's forked from: 速度比較したら一個前の方法が速かったっぽい
  5. // forked from keno42's 速度比較したら一個前の方法が速かったっぽい
  6. // forked from bkzen's forked from: 色と透明度もいれてみた。こんなのどうだろバージョン
  7. // forked from bkzen's 色と透明度もいれてみた。速度向上したらいいなばーじょん
  8. // forked from keno42's 角度計算修正、色と透明度もいれてみた。重ね順ソートが重い。
  9. // forked from bkzen's forked from: BitmapDataで配列に格納すると高速化するよ(角度修正)
  10. // forked from clockmaker's BitmapDataで配列に格納すると高速化するよ
  11. // forked from clockmaker's 3D Flow Simulation with Field of Blur
  12. // forked from clockmaker's 3D Flow Simulation
  13. // forked from clockmaker's Interactive Liquid 10000
  14. // forked from clockmaker's Liquid110000 By Vector
  15. // forked from munegon's forked from: forked from: forked from: forked from: Liquid10000
  16. // forked from Saqoosha's forked from: forked from: forked from: Liquid10000
  17. // forked from nutsu's forked from: forked from: Liquid10000
  18. // forked from nutsu's forked from: Liquid10000
  19. // forked from zin0086's Liquid10000
  20. package {
  21.         
  22.     // 本末転倒？
  23.     import flash.display.*;
  24.     import flash.geom.*;
  25.     import flash.events.*;
  26.     import flash.filters.*;
  27.     import flash.utils.*;
  28.     import flash.geom.*;
  29.     import net.hires.debug.Stats;
  30.     
  31.     [SWF(width="465", height="465", backgroundColor="0xFFFFFF", frameRate="60")]
  32.     public class Main extends Sprite {
  33.         
  34.         private var forceMap:BitmapData = new BitmapData( 233, 233, false, 0x000000 );
  35.         private var randomSeed:uint = Math.floor( Math.random() * 0xFFFF );
  36.         private var seed:Number = Math.floor( Math.random() * 0xFFFF );
  37.         private var offset:Array = [new Point(), new Point()];
  38.         private var timer:Timer;
  39.         private var buffer:BitmapData = new BitmapData(465, 465, false, 0);
  40.         private var screen:Bitmap = new Bitmap(buffer);
  41.         private var particleList:Array = new Array();
  42.         
  43.         function Main() {
  44.             
  45.             // フォースマップの初期化をおこないます
  46.             resetFunc();
  47.             
  48.             // ループ処理
  49.             addEventListener( Event.ENTER_FRAME, loop );
  50.             
  51.             // 時間差でフォースマップと色変化の具合を変更しています
  52.             var timer:Timer = new Timer(1000);
  53.             timer.addEventListener(TimerEvent.TIMER, resetFunc);
  54.             timer.start();
  55.             
  56.             // 矢印をプレレンダリング
  57.             var dummy:Sprite = new Sprite();
  58.             var dummyBg:Sprite = new Sprite();
  59.             var dummyHolder:Sprite = new Sprite();
  60.             dummy.graphics.beginFill(0xFF3060, 1);
  61.             dummy.graphics.lineStyle(1, 0x002060, 1);
  62.             dummy.graphics.drawPath(Vector.<int>([1,2,2,2,2,2,2,2]), Vector.<Number>([-9,-7,-3,-7,-3,-11,9,-4,-3,3,-3,-1,-9,-1,-9,-7]));
  63.             dummyBg.graphics.beginFill(0x40A0FF, 0.25);
  64.             dummyBg.graphics.lineStyle(1, 0x103080, 0.5);
  65.             dummyBg.graphics.drawPath(Vector.<int>([1,2,2,2,2,2,2,2]), Vector.<Number>([-9,-7,-3,-7,-3,-11,9,-4,-3,3,-3,-1,-9,-1,-9,-7]));
  66.             dummyHolder.addChild(dummyBg);
  67.             dummyHolder.addChild(dummy);
  68.             
  69.             var temp:BitmapData;
  70.             var rect:Rectangle;
  71.             var matrix:Matrix = new Matrix();
  72.             var j:int = ALPHA_STEPS;
  73.             while(j--) {
  74.                 var i:int = ROT_STEPS;
  75.                 var k:int = j * ROT_STEPS;
  76.                 dummy.alpha = j / (ALPHA_STEPS-1);
  77.                 dummy.filters = dummyBg.filters = [new BlurFilter(4.0*(1.0 - j / (ALPHA_STEPS-1)),4.0*(1.0 - j / (ALPHA_STEPS-1)))];
  78.                 while (i--) {
  79.                     matrix.identity();
  80.                     matrix.rotate( ( 360 / ROT_STEPS * i )* Math.PI / 180);
  81.                     matrix.translate(11, 11);
  82.                     temp = new BitmapData(22, 22, true, 0x0);
  83.                     temp.draw(dummyHolder, matrix);
  84.                     rotArr[i+k] = new DisplayImage(temp, 11, 11);
  85.                 }
  86.             }
  87.             
  88.             // パーティクルを生成します
  89.             for (i = 0; i < NUM_PARTICLE; i++) {particleList[i] = new Arrow(Math.random() * 465, Math.random() * 465);}
  90.             addChild(screen);
  91.             stage.quality = StageQuality.LOW;
  92.             
  93.             // デバッグ用のスタッツを表示しています
  94.             addChild(new Stats);
  95.         }
  96.         
  97.         private function loop( e:Event ):void {
  98.             var len:int = particleList.length;
  99.             var arrow:Arrow;
  100.             
  101.             buffer.colorTransform(buffer.rect, new ColorTransform(1, 1, 1, 1, 12, 16, 20, 0));
  102.             particleList.sortOn("speed", Array.NUMERIC);
  103.             for (var i:int = 0; i < len; i++) {
  104.                 arrow = particleList[i];
  105.                 arrow.step(forceMap.getPixel( arrow.x >> 1, arrow.y >> 1));
  106.                 buffer.copyPixels(arrow.img.bmp, arrow.img.bmp.rect, new Point(arrow.x-arrow.img.cx, arrow.y-arrow.img.cy));
  107.             }
  108.         }
  109.         
  110.         private function resetFunc(e:Event = null):void {
  111.             forceMap.perlinNoise(117, 117, 3, seed, false, true, 6, false, offset);
  112.             
  113.             offset[0].x += 1.5;
  114.             offset[1].y += 1;
  115.             seed = Math.floor( Math.random() * 0xFFFFFF );
  116.         }
  117.     }
  118. }
  120. import flash.display.*;
  121. import flash.geom.*;
  123. const NUM_PARTICLE:uint = 1000;
  124. const ROT_STEPS:int = 128;
  125. const ALPHA_STEPS:int = 10;
  126. var rotArr:Vector.<DisplayImage> = new Vector.<DisplayImage>(ROT_STEPS * ALPHA_STEPS, true);
  127. var multiplyConst:Number = 64 / Math.PI;
  129. class DisplayImage {
  130.     
  131.     public var bmp:BitmapData;
  132.     public var rect:Rectangle;
  133.     public var cx:int, cy:int;
  134.     
  135.     function DisplayImage(bmp:BitmapData, cx:int, cy:int) {
  136.         this.bmp = bmp;
  137.         this.rect = bmp.rect;
  138.         this.cx = cx;
  139.         this.cy = cy;
  140.         trimming();
  141.     }
  142.     
  143.     private function trimming():void {
  144.         var rect:Rectangle = bmp.getColorBoundsRect(0xFF000000, 0x00000000);
  145.         var temp:BitmapData = new BitmapData(rect.width, rect.height, true, 0x00000000);
  146.         cx -= rect.x;
  147.         cy -= rect.y;
  148.         temp.copyPixels(bmp, rect, new Point(0, 0));
  149.         bmp = temp;
  150.     }
  151. }
  153. class Arrow {
  154.     
  155.     public var img:DisplayImage;
  156.     public var x:int, y:int;
  157.     public var vx:Number = 0, vy:Number = 0, ax:Number = 0, ay:Number = 0;
  158.     public var rot:int = 0, speed:int = 0;
  159.     
  160.     function Arrow(x:int, y:int) {
  161.         this.x = x;
  162.         this.y = y;
  163.     }
  164.     
  165.     public function step(col:uint):void {
  166.         ax += ( (col      & 0xff) - 0x80 ) * .0005;
  167.         ay += ( (col >> 8 & 0xff) - 0x80 ) * .0005;
  168.         vx += ax;
  169.         vy += ay;
  170.         x += vx;
  171.         y += vy;
  172.         
  173.         var dir:Number = Math.atan2( vy, vx );
  174.         rot = (128 + dir * multiplyConst) & 127;
  175.         speed = Math.min(ALPHA_STEPS-1, (vx*vx + vy*vy) >> 1); // *0.5
  176.         img = rotArr[rot + ROT_STEPS * speed];
  177.         
  178.         ax *= .96;
  179.         ay *= .96;
  180.         vx *= .92;
  181.         vy *= .92;
  182.         
  183.         ( x > 465 ) ? x = 0 : ( x < 0 ) ? x = 465 : 0;
  184.         ( y > 465 ) ? y = 0 : ( y < 0 ) ? y = 465 : 0;
  185.     }
  186. }
noswf
Get Adobe Flash Player