※現在、「wonderfl build flash online」求人コンテンツ制作に関してのアンケートを実施中です！みなさまのお力添えを頂いて、続々とアンケート結果が集まっていますが、まだまだ募集しております。ご協力のほど、どうぞよろしくお願いいたします！

wonderfl運営事務局
→アンケートページ（※ログインしてからお答えいただけるようになっています。）

 notice: Flash editor updated! Join the development! Thanks to MiniBuilder


forked from : bkzen's forked from: BitmapDataで配列に格納すると高速化するよ(角度修正) [diff(51)]

embed

noswf download fullscreen
flash swf thumbnail play
reload download fullscreen

TALK
hi
 i am a student learning flash. whnever i try to compile this code it gives me error saying  error 1120: undefined variable timer (line(60)) . can you help me out.
at 2009/08/16 10:45:09 by
FORKED
>sort

角度計算修正、色と透明度もいれてみた。重ね順ソートが重い。 色と透明度もいれてみた。速度向上したらいいなばーじょん [diff(9)]

  1. // forked from keno42's 角度計算修正、色と透明度もいれてみた。重ね順ソートが重い。
  2. // forked from bkzen's forked from: BitmapDataで配列に格納すると高速化するよ(角度修正)
  3. // forked from clockmaker's BitmapDataで配列に格納すると高速化するよ
  4. // forked from clockmaker's 3D Flow Simulation with Field of Blur
  5. // forked from clockmaker's 3D Flow Simulation
  6. // forked from clockmaker's Interactive Liquid 10000
  7. // forked from clockmaker's Liquid110000 By Vector
  8. // forked from munegon's forked from: forked from: forked from: forked from: Liquid10000
  9. // forked from Saqoosha's forked from: forked from: forked from: Liquid10000
  10. // forked from nutsu's forked from: forked from: Liquid10000
  11. // forked from nutsu's forked from: Liquid10000
  12. // forked from zin0086's Liquid10000
  13. package 
  14. {
  15.     /**
  16.      * 矢印がいっぱいなんだけど、高速なデモ
  17.      * 画質はディフォルトの StageQuality.HIGH で
  18.      * 矢印 1000個
  19.      * @author Yasu
  20.      */
  21.     import flash.display.*;
  22.     import flash.geom.*;
  23.     import flash.events.*;
  24.     import flash.filters.*;
  25.     import flash.utils.*;
  26.     import flash.geom.*;
  27.     import net.hires.debug.Stats;
  28.     
  29.     [SWF(width="465", height="465", backgroundColor="0xFFFFFF")]
  30.     public class Main extends Sprite {
  31.         private const NUM_PARTICLE:uint = 1000;
  32.         private const ROT_STEPS:int = 120;
  33.         private const ALPHA_STEPS:int = 10;
  34.         
  35.         private var forceMap:BitmapData = new BitmapData( 233, 233, false, 0x000000 );
  36.         private var randomSeed:uint = Math.floor( Math.random() * 0xFFFF );
  37.         private var particleList:Vector.<Arrow> = new Vector.<Arrow>(NUM_PARTICLE, true);
  38.         private var rect:Rectangle = new Rectangle( 0, 0, 465, 465 );
  39.         private var seed:Number = Math.floor( Math.random() * 0xFFFF );
  40.         private var offset:Array = [new Point(), new Point()];
  41.         private var timer:Timer;
  42.         private var world:Sprite = new Sprite();
  43.         private var worldAlphaChildren:Vector.<Sprite> = new Vector.<Sprite>(ALPHA_STEPS,true);
  44.         private var rotArr:Vector.<BitmapData> = new Vector.<BitmapData>(ROT_STEPS * ALPHA_STEPS, true);
  46.         public function Main() {
  47.             
  48.             stage.align = StageAlign.TOP_LEFT;
  49.             stage.scaleMode = StageScaleMode.NO_SCALE;
  50.             stage.frameRate = 60;
  51.             
  52.             addChild(world);
  53.             
  54.             // フォースマップの初期化をおこないます
  55.             resetFunc();
  56.             
  57.             // ループ処理
  58.             addEventListener( Event.ENTER_FRAME, loop );
  59.             
  60.             // 時間差でフォースマップと色変化の具合を変更しています
  61.             var timer:Timer = new Timer(1000)
  62.             timer.addEventListener(TimerEvent.TIMER, resetFunc);
  63.             timer.start();
  64.             
  65.             // 矢印をプレレンダリング
  66.             var dummy:Sprite = new Sprite();
  67.             dummy.graphics.beginFill(0xFF4444, 1);
  68.             dummy.graphics.lineStyle(1, 0x0, 1);
  69.             dummy.graphics.moveTo(2, 4);
  70.             dummy.graphics.lineTo(8, 4);
  71.             dummy.graphics.lineTo(8, 0);
  72.             dummy.graphics.lineTo(20, 7);
  73.             dummy.graphics.lineTo(8, 14);
  74.             dummy.graphics.lineTo(8, 10);
  75.             dummy.graphics.lineTo(2, 10);
  76.             dummy.graphics.lineTo(2, 4);
  77.             var dummyBg:Sprite = new Sprite();
  78.             dummyBg.graphics.beginFill(0x4444FF, 0.5);
  79.             dummyBg.graphics.lineStyle(1, 0x0, 1);
  80.             dummyBg.graphics.moveTo(2, 4);
  81.             dummyBg.graphics.lineTo(8, 4);
  82.             dummyBg.graphics.lineTo(8, 0);
  83.             dummyBg.graphics.lineTo(20, 7);
  84.             dummyBg.graphics.lineTo(8, 14);
  85.             dummyBg.graphics.lineTo(8, 10);
  86.             dummyBg.graphics.lineTo(2, 10);
  87.             dummyBg.graphics.lineTo(2, 4);
  88.             var dummyHolder:Sprite = new Sprite();
  89.             dummyHolder.addChild(dummyBg);
  90.             dummyHolder.addChild(dummy);
  91.             
  92.             var matrix:Matrix;
  93.             var j:int = ALPHA_STEPS;
  94.             while(j--){
  95.                 var i:int = ROT_STEPS;
  96.                 var k:int = j * ROT_STEPS;
  97.                 worldAlphaChildren[ALPHA_STEPS-1-j] = new Sprite();
  98.                 // 忘れがちだけどこれ入れるだけでマウスが乗った時の重さが違う
  99.                 worldAlphaChildren[ALPHA_STEPS - 1 - j].mouseChildren = worldAlphaChildren[ALPHA_STEPS - 1 - j].mouseEnabled = false;
  100.                 world.addChild( worldAlphaChildren[ALPHA_STEPS-1-j] );
  101.                 dummy.alpha = j / (ALPHA_STEPS-1);
  102.                 dummyBg.filters = [new BlurFilter(4.0*(1.0 - j / (ALPHA_STEPS-1)),4.0*(1.0 - j / (ALPHA_STEPS-1)))];
  103.                 dummy.filters = [new BlurFilter(4.0*(1.0 - j / (ALPHA_STEPS-1)),4.0*(1.0 - j / (ALPHA_STEPS-1)))];
  104.                 while (i--)
  105.                 {
  106.                     matrix = new Matrix();
  107.                     matrix.translate( -11, -11);
  108.                     matrix.rotate( ( 360 / ROT_STEPS * i )* Math.PI / 180);
  109.                     matrix.translate( 11, 11);
  110.                     rotArr[i+k] = new BitmapData(22, 22, true, 0x0);
  111.                     rotArr[i+k].draw(dummyHolder, matrix);
  112.                 }
  113.             }
  114.             
  115.             // パーティクルを生成します
  116.             for (i = 0; i < NUM_PARTICLE; i++) {
  117.                 var px:Number = Math.random() * 465;
  118.                 var py:Number = Math.random() * 465;
  119.                 particleList[i] = new Arrow(px, py);
  120.                 world.addChild(particleList[i]);
  121.             }
  122.             
  123.             // デバッグ用のスタッツを表示しています
  124.             addChild(new Stats);
  125.         }
  126.         
  127.         private function loop( e:Event ):void {
  128.             
  129.             var len:uint = particleList.length;
  130.             var col:Number;
  131.             
  132.             for (var i:uint = 0; i < len; i++) {
  133.                 
  134.                 var arrow:Arrow = particleList[i];
  135.                 
  136.                 var oldX:Number = arrow.x;
  137.                 var oldY:Number = arrow.y;
  138.                 
  139.                 col = forceMap.getPixel( arrow.x >> 1, arrow.y >> 1);
  140.                 arrow.ax += ( (col      & 0xff) - 0x80 ) * .0005;
  141.                 arrow.ay += ( (col >> 8 & 0xff) - 0x80 ) * .0005;
  142.                 arrow.vx += arrow.ax;
  143.                 arrow.vy += arrow.ay;
  144.                 arrow.x += arrow.vx;
  145.                 arrow.y += arrow.vy;
  146.                 
  147.                 var _posX:Number = arrow.x;
  148.                 var _posY:Number = arrow.y;
  149.                 
  150.                 // rot成分
  151.                 var rot:Number = - Math.atan2((_posX - oldX), (_posY - oldY)) * 180 / Math.PI + 90;
  152.                 var angle:int = rot / 360 * ROT_STEPS | 0;
  153.                 // Math.absの高速化ね
  154.                 // angle = (angle ^ (angle >> 31)) - (angle >> 31);
  155.                 // angle = (angle + 130) & 119; // (angle + 130) % 120 の高速化
  156.                 // ↑これ & 2^n-1 になるときでないと使えないと思う
  157.                 angle = (angle + 130) % 120;
  158.                 arrow.rot += (angle - arrow.rot) * 0.2;
  159.                 
  160.                 // alpha成分
  161.                 var speed:int = (arrow.vx*arrow.vx + arrow.vy*arrow.vy) >> 1; // *0.5
  162.                 speed = Math.min(ALPHA_STEPS-1, speed);
  163.                 arrow.bitmapData = rotArr[arrow.rot + ROT_STEPS * speed];
  165.                 // speedに応じてソート。これが重い
  166.                 if (arrow.parent != world.getChildAt(speed)) 
  167.                 {
  168.                     // speed が違う場合のみ変更する。ってことにすれば少し違うかも
  169.                     arrow.parent.removeChild(arrow);
  170.                     Sprite(world.getChildAt(speed)).addChild(arrow);
  171.                 }
  172.                     
  173.                 arrow.ax *= .96;
  174.                 arrow.ay *= .96;
  175.                 arrow.vx *= .92;
  176.                 arrow.vy *= .92;
  177.                 
  178.                 // あと配置座標を整数化しておきます
  179.                 arrow.x = arrow.x | 0;
  180.                 arrow.y = arrow.y | 0;
  181.                 
  182.                 ( _posX > 465 ) ? arrow.x = 0 :
  183.                     ( _posX < 0 ) ? arrow.x = 465 : 0;
  184.                 ( _posY > 465 ) ? arrow.y = 0 :
  185.                     ( _posY < 0 ) ? arrow.y = 465 : 0;
  186.             }
  187.         }
  188.         
  189.         private function resetFunc(e:Event = null):void{
  190.             forceMap.perlinNoise(117, 117, 3, seed, false, true, 6, false, offset);
  191.             
  192.             offset[0].x += 1.5;
  193.             offset[1].y += 1;
  194.             seed = Math.floor( Math.random() * 0xFFFFFF );
  195.         }
  196.     }
  197. }
  199. import flash.display.*;
  201. class Arrow extends Bitmap
  202. {
  203.     public var rot:int = 0;
  204.     public var vx:Number = 0;
  205.     public var vy:Number = 0;
  206.     public var ax:Number = 0;
  207.     public var ay:Number = 0;
  209.     function Arrow( x:Number, y:Number) {
  210.         this.x = x;
  211.         this.y = y;
  212.     }
  213. }
noswf
Get Adobe Flash Player