※現在、「wonderfl build flash online」求人コンテンツ制作に関してのアンケートを実施中です！みなさまのお力添えを頂いて、続々とアンケート結果が集まっていますが、まだまだ募集しております。ご協力のほど、どうぞよろしくお願いいたします！

wonderfl運営事務局
→アンケートページ（※ログインしてからお答えいただけるようになっています。）

 notice: Flash editor updated! Join the development! Thanks to MiniBuilder


embed

noswf download fullscreen
flash swf thumbnail play
reload download fullscreen

FORKED
>sort

[1日1Wonderfl]8日目: Reflection やってみたよ [1日1Wonderfl]10日目: Camera でも Reflection [diff(117)]

  1. // forked from soundkitchen's [1日1Wonderfl]8日目: Reflection やってみたよ
  2. // 1日1Wonderfl 10/30日目
  3. package
  4. {
  5.     import flash.display.Bitmap;
  6.     import flash.display.BitmapData;
  7.     import flash.display.Graphics;
  8.     import flash.display.GradientType;
  9.     import flash.display.Shape;
  10.     import flash.display.Sprite;
  11.     import flash.events.Event;
  12.     import flash.geom.Matrix;
  13.     import flash.media.Camera;
  14.     import flash.media.Video;
  16.     import com.flashdynamix.utils.SWFProfiler;
  18.     [SWF(width=465, height=465, frameRate=30, backgroundColor=0x000000)]
  20.     /**
  21.      *
  22.      */
  23.     public class Main extends Sprite
  24.     {
  25.         public static const CAMERA_WIDTH:Number = 240;
  26.         public static const CAMERA_HEIGHT:Number = 180;
  27.         public static const REFLECT_SCALE:Number = .5;
  28.         public static const REFLECT_MARGIN:Number = 0;
  30.         private var video:Video;
  31.         private var container:Sprite;
  32.         private var film:BitmapData;
  34.         /**
  35.          *
  36.          */
  37.         public function Main()
  38.         {
  39.             addEventListener(Event.ADDED_TO_STAGE, initialize);
  40.         }
  42.         /**
  43.          *
  44.          */
  45.         private function initialize(evt:Event):void
  46.         {
  47.             removeEventListener(Event.ADDED_TO_STAGE, initialize);
  49.             SWFProfiler.init(this);
  51.             container = new Sprite();
  53.             var webCam:Camera,
  54.                 original:Bitmap,
  55.                 reflect:Bitmap,
  56.                 msk:Shape,
  57.                 mtx:Matrix,
  58.                 g:Graphics;
  60.             //  get default web camera.
  61.             webCam = Camera.getCamera();
  63.             //  stop process if couldn't found any camera.
  64.             if (!webCam) return;
  66.             //  setup camera.
  67.             webCam.setMode(CAMERA_WIDTH, CAMERA_HEIGHT, stage.frameRate >> 1);
  69.             //  create and setup video.
  70.             video = new Video(CAMERA_WIDTH, CAMERA_HEIGHT);
  71.             //  reverse and fix position.
  72.             video.scaleX *= -1;
  73.             video.x += CAMERA_WIDTH;
  74.             //  bind camera.
  75.             video.attachCamera(webCam);
  77.             //  create bitmapdata as a snapshot film.
  78.             film = new BitmapData(CAMERA_WIDTH, CAMERA_HEIGHT, true, 0);
  80.             //  create original bitmap.
  81.             original = new Bitmap(film);
  82.             container.addChild(original);
  84.             //  create reflection bitmap.
  85.             reflect = new Bitmap(film);
  86.             //  reverse and fix position.
  87.             reflect.scaleY *= -1;
  88.             reflect.y = REFLECT_MARGIN + (CAMERA_HEIGHT << 1);
  89.             //  cache for mask and fade.
  90.             reflect.cacheAsBitmap = true;
  91.             container.addChild(reflect);
  93.             //  create mask shape.
  94.             msk = new Shape();
  95.             //  fix position.
  96.             msk.y = CAMERA_HEIGHT + REFLECT_MARGIN;
  97.             //  cache for mask and fade.
  98.             msk.cacheAsBitmap = true;
  100.             //  create matrix.
  101.             mtx = new Matrix();
  102.             mtx.createGradientBox(CAMERA_WIDTH, CAMERA_HEIGHT, Math.PI/2);
  104.             //  draw gradient box.
  105.             g = msk.graphics;
  106.             g.beginGradientFill(
  107.                 GradientType.LINEAR,
  108.                 [0x00, 0x00],
  109.                 [REFLECT_SCALE, 0],
  110.                 [0, 255 * REFLECT_SCALE],
  111.                 mtx
  112.             );
  113.             g.drawRect(0, 0, CAMERA_WIDTH, CAMERA_HEIGHT);
  114.             g.endFill();
  116.             container.addChild(msk);
  117.             reflect.mask = msk;
  119.             //  fix position.
  120.             container.x = (stage.stageWidth - original.width) >> 1;
  121.             container.y = (stage.stageHeight - original.height) >> 1;
  122.             addChild(container);
  124.             addEventListener(Event.ENTER_FRAME, step);
  125.         }
  127.         private function step(evt:Event):void
  128.         {
  129.             film.lock();
  130.             film.fillRect(film.rect, 0);
  131.             film.draw(video, video.transform.matrix);
  132.             film.unlock();
  133.         }
  134.     }
  135. }
noswf
Get Adobe Flash Player