毛文字 | wonderfl build flash online

※現在、「wonderfl build flash online」求人コンテンツ制作に関してのアンケートを実施中です！みなさまのお力添えを頂いて、続々とアンケート結果が集まっていますが、まだまだ募集しております。ご協力のほど、どうぞよろしくお願いいたします！

wonderfl運営事務局
→アンケートページ（※ログインしてからお答えいただけるようになっています。）

毛文字

add to favorites

borealkiss

notice: Flash editor updated! Join the development! Thanks to MiniBuilder

forked : 1
favorite : 21
lines : 171
license : All rights reserved
modified : 2008-12-25 03:29:29

embed

Twitterでつぶやく

package {
	import flash.display.Sprite;
	import flash.text.TextField;
	import flash.text.TextFieldType;
	import flash.events.MouseEvent;

[SWF(width="400",height="200",backgroundColor="0x0")]
	public class main extends Sprite{
		private const STAGE_WIDTH:int = 400;
		private const STAGE_HEIGHT:int = 200;
		private const LIMIT:int = 100000;
		private const INITIAL_LETTERS:String = "Type something.";
		private const PADDING:int = 5;
		private var _textField:TextField;
		private var _controller:Controller;
		
		public function main(){
			var canvas:Sprite = new Sprite();
			this.addChild(canvas);
			_controller = new Controller(canvas,STAGE_WIDTH,STAGE_HEIGHT,LIMIT);
			_controller.draw(INITIAL_LETTERS);
			this.createStageObjects();
		}
		
		//Button and TextField.
		private function createStageObjects():void{
			_textField = new TextField;
			_textField.background = true;
			_textField.backgroundColor = 0xFFFFFF;
            _textField.border = true;
            _textField.text = INITIAL_LETTERS;
            _textField.type = TextFieldType.INPUT;
            _textField.width = STAGE_WIDTH*0.8;
            _textField.height = 20;
            _textField.x = PADDING;
            _textField.y = STAGE_HEIGHT - _textField.height - PADDING;
            addChild(_textField);

var button:Sprite = new Sprite();
            button.buttonMode = true;
            button.graphics.beginFill(0xcccccc);
            button.graphics.drawRect(0,0,STAGE_WIDTH*0.15,20);
            button.graphics.endFill();
            button.mouseChildren = false;
            var label:TextField = new TextField();
            label.width = STAGE_WIDTH*0.15;
            label.height = 20;
            label.htmlText = "<p align='center'>Create</p>";
            button.addChild(label);
            button.x = 2*PADDING + _textField.width;
            button.y = STAGE_HEIGHT - button.height - PADDING;
            addChild(button);
            
            button.addEventListener(MouseEvent.CLICK,onClick);
		}
		
		private function onClick(e:MouseEvent):void{
			_controller.textInput = _textField.text;
		}
	}
}

/*************************/

import flash.display.DisplayObjectContainer;
class Controller{
	protected var _target:DisplayObjectContainer;
	protected var _imageWidth:int;
	protected var _imageHeight:int;
	protected var _limitNum:int;
	protected const HAIR_LENGTH:int = 10;
	protected const FONT_SIZE:Number = 50;
	
	protected var _textInput:String;
	public function set textInput(value:String):void{
		_textInput = value;
		this.draw(_textInput);
	}
	
	public function Controller(target:DisplayObjectContainer,width:int=465,height:int=465,limit:int=1000){
		_target = target;
		_imageWidth = width;
		_imageHeight = height;
		_limitNum = limit;
	}
	
	public function draw(textInput:String=null):void{
		this.remove();
		var bitmapData:FontBitmapData = new FontBitmapData(textInput,_imageWidth,_imageHeight,"Times New Roman",FONT_SIZE,0xFFFFFF);							
		var font:HairyFont = new HairyFont(bitmapData,_limitNum,HAIR_LENGTH,0xFFFFFF);
		_target.addChild(font);
		font.y = _imageHeight/2 - font.height/2;
	}
	
	/**
	 * @private (protected)
	 */ 
	protected function remove():void{
		while (_target.numChildren > 0){
			_target.removeChildAt(0);
		}
	}
}

/*************************/

import flash.display.Sprite;
import flash.display.Graphics;
import flash.display.BitmapData;
class HairyFont extends Sprite{
	protected var _sourceBitmapData:FontBitmapData;
	protected var _random:uint;
	protected var _stroke:uint;
	protected var _limit:uint;
	protected var _alpha:Number;

public function HairyFont(sourceBitmapData:FontBitmapData,limit:uint,random:uint,stroke:uint=0x0,alpha:Number=0.1){		
		_sourceBitmapData = sourceBitmapData;
		_limit = limit;
		_random = random;
		_stroke = stroke;
		_alpha = alpha;
		this.init();
	}
	
	protected function init():void{
		this.update();
	}
	
	protected function update():void{
		var rectWidth:int = _sourceBitmapData.width;
		var rectHeight:int = _sourceBitmapData.height;
		
		var g:Graphics = this.graphics;
		g.clear();
		g.lineStyle(0,_stroke,_alpha);
		
		for (var i:int=0; i<_limit; i++){
			var x:int = int(Math.random()*rectWidth);
			var y:int = int(Math.random()*rectHeight);
			var color32:uint = _sourceBitmapData.getPixel32(x,y);
			
			if (this.isInObject(color32)){
				//Start point
				var startX:Number = x;
				var startY:Number = y;
				
				//Anchor point so that the hair goes outer.
				var hairRad:Number = _random*Math.random();
				var hairTheta:Number = Math.random()*2*Math.PI;
				var anchorX:Number = startX + hairRad*Math.cos(hairTheta);
				var anchorY:Number = startY + hairRad*Math.sin(hairTheta);
				
				//Control point for the Bezier curve.
				var controlRad:Number = _random*Math.random();
				var controlTheta:Number = Math.random()*2*Math.PI;
				var controlX:Number = startX + controlRad*Math.cos(controlTheta);
				var controlY:Number = startY + controlRad*Math.sin(controlTheta);
				
				g.moveTo(startX,startY);
				g.curveTo(controlX,controlY,anchorX,anchorY);
			}
		}
	}
	
	protected function isInObject(color32:uint):Boolean{
		if (color32 == 0x0){
			return false;
		}
		return true;
	}
	
	protected function randomGen(random:uint):Number{
		return 2*random*(Math.random() - 1/2);
	}
}

/*************************/

import flash.display.BitmapData;
import flash.text.TextField;
import flash.text.TextFormat;
import flash.text.TextFormatAlign;
class FontBitmapData extends BitmapData{
	protected var _textField:TextField;
	protected var _textFormat:TextFormat;
	protected var _fontColor:uint;
	
	public function FontBitmapData(text:String,width:int,height:int,
									font:String="Times New Roman",
									size:Object=12,
									color:Object=0x0,
									bold:Object=null,
									italic:Object=null){
								
		super(width,height,true,0x00FFFFFF);
		
		_textField = new TextField();
		_textField.text = text;
		_textField.width = width;
		_textField.height = height;
		_fontColor = uint(color);
		_textFormat = new TextFormat(font,size,color,bold,italic);
		_textFormat.align = TextFormatAlign.CENTER;
		_textField.setTextFormat(_textFormat);
		this.init();						
	}
	
	protected function init():void{
		this.draw(_textField);
	}
}

HairyFont fun text

imajuk

yuuganisakase

FlashFit

yabuchany

mogera

plankton

fallen

t_matsuda

dizgid

assen_nissen

tkinjo

nki2

tatsuhisa

Kay

Laqu

hacker_d066k1r7

seyself

juvial

tenchiwang2 :

fun text

Akineton :

HairyFontHairyFont

szktkhr :

KEMOJI

>sort

毛文字 forked from: 毛文字 [diff(207)]

tkinjo

// forked from borealkiss's 毛文字
package {
/**
* どんな仕組みになっているか気になったので勉強をかねて、使いやすくリファクタリング
*/
import flash.display.BitmapData;
import flash.display.DisplayObject;
import flash.display.Sprite;
import flash.text.TextFormat;
[SWF(width = "465", height = "465", frameRate = "60", backgroundColor = "#ffffff")]
public class Main extends Sprite {
private const TEXT:String = "毛文字";
public function Main() {
var hairyText:DisplayObject = createHairyText( TEXT, new TextFormat( null, 100 ), 0.5 );
hairyText.x = ( stage.stageWidth - hairyText.width ) / 2;
hairyText.y = ( stage.stageHeight - hairyText.height ) / 2;
addChild( hairyText );
}
}
}
import flash.display.Bitmap;
import flash.display.DisplayObject;
import flash.display.Sprite;
import flash.display.Graphics;
import flash.display.BitmapData;
import flash.geom.Matrix;
import flash.geom.Rectangle;
import flash.text.TextFormat;
function createHairyText( text:String, textFormat:TextFormat = null, limit:Number = 1, longHairLength:Number = 0, alpha:Number = 0.5 ):DisplayObject {
if ( !textFormat )
textFormat = new TextFormat();
if ( !longHairLength )
longHairLength = ( ( textFormat.size ) ? Number( textFormat.size ) : 12 ) / 10; // 12 は Flash Player 固有のフォーマットのフォントサイズ
var bitmapData:BitmapData = textToBitmapData( text, textFormat );
var sprite:Sprite = new Sprite();
var graphics:Graphics = sprite.graphics;
graphics.clear();
graphics.lineStyle( 0, uint( textFormat.color ), alpha );
for ( var i:uint = 0; i < ( bitmapData.width * bitmapData.height ) * limit; i++ ) {
var x:uint = ( limit != 1 ) ? Math.random() * bitmapData.width : i % bitmapData.width;
var y:uint = ( limit != 1 ) ? Math.random() * bitmapData.height : uint( i / bitmapData.width );
var color32:uint = bitmapData.getPixel32( x, y );
if ( color32 != 0 ) {
//Anchor point so that the hair goes outer.
var hairLength:Number = longHairLength * Math.random();
var hairRadian:Number = Math.random() * 2 * Math.PI;
var anchorX:Number = x + hairLength * Math.cos( hairRadian );
var anchorY:Number = y + hairLength * Math.sin( hairRadian );
//Control point for the Bezier curve.
var controlDistance:Number = longHairLength * Math.random();
var controlRadian:Number = Math.random() * 2 * Math.PI;
var controlX:Number = x + controlDistance * Math.cos( controlRadian );
var controlY:Number = y + controlDistance * Math.sin( controlRadian );
graphics.moveTo( x, y );
graphics.curveTo( controlX, controlY, anchorX, anchorY );
}
}
return sprite;
}
import flash.display.BitmapData;
import flash.geom.Matrix;
import flash.text.TextField;
import flash.text.TextFormat;
/**
* テキストをビットマップデータに変換する関数
*/
function textToBitmapData( text:String, textFormat:TextFormat = null ):BitmapData {
// テキストフィールドの作成
var textField:TextField = new TextField();
textField.text = text;
// テキストフォーマットの適用
if( textFormat )
textField.setTextFormat( textFormat );
// テキストフィールドの幅、高さを調節。2 * 2 の意味は参考リンク参照。
textField.width = textField.textWidth + 2 * 2;
textField.height = textField.textHeight + 2 * 2;
// ビットマップデータの作成
var bitmapData:BitmapData = new BitmapData( textField.width - 2 * 2, textField.height - 2 * 2, true, 0 );
// テキストフィールドをビットマップデータ上に描画。
bitmapData.draw( textField, new Matrix(1, 0, 0, 1, -2, -2) );
return bitmapData;
}