※現在、「wonderfl build flash online」求人コンテンツ制作に関してのアンケートを実施中です！みなさまのお力添えを頂いて、続々とアンケート結果が集まっていますが、まだまだ募集しております。ご協力のほど、どうぞよろしくお願いいたします！

wonderfl運営事務局
→アンケートページ（※ログインしてからお答えいただけるようになっています。）

 notice: Flash editor updated! Join the development! Thanks to MiniBuilder


embed

noswf download fullscreen
flash swf thumbnail play
reload download fullscreen

FAVORITE BY
:
some japanese sidescrolling tunnel
FORKED
>sort

なんとかディウスっぽい背景 なんとかディウスっぽい蟹さん forked from: なんとかディウスっぽい背景 [diff(552)]

  1. // forked from gyuque's なんとかディウスっぽい背景
  3. // 左右キーとスペースで操作できます
  4. package
  5. {
  6.     import flash.display.*;
  7.     import flash.geom.*;
  8.     import flash.events.*;
  9.     import flash.ui.*;
  11.     [SWF(width="320", height="240", backgroundColor="0x000000", frameRate="30")]
  12.     public class Nemesis extends Sprite
  13.     {
  14.         public static const W:int = 320;
  15.         public static const H:int = 240;
  17.         private var mBGen:MountainGen = new MountainGen(80);
  18.         private var mTGen:MountainGen = new MountainGen(80, 1);
  19.         
  20.         private var mScreenBmp:Bitmap;
  21.         private var mScreen:BitmapData = new BitmapData(W, H, false, 0);
  22.         private var mBGScreen:BitmapData = new BitmapData(W, H, true, 0);
  23.         
  24.         private var mStarbg:StarBG = new StarBG(W, H, 50);
  25.         private var mKani:Kani;
  26.         private var legs:Array = new Array();
  27.         
  28.         private var count:int = 0;
  29.         
  30.         function Nemesis()
  31.         {
  32.             mScreenBmp = new Bitmap(mScreen);
  33.             addChild(mScreenBmp);
  34.             
  35.             mBGen.step();
  36.             mTGen.step();
  37.             for(var i:int = 0; i < W; i++)
  38.             {
  39.                 mBGen.step();
  40.                 mTGen.step();
  41.                 mBGen.draw(mBGScreen, i, 160);
  42.                 mTGen.draw(mBGScreen, i, 0, false);
  43.             }
  44.             
  45.             legs.push(new Leg(-80, 1));
  46.             legs.push(new Leg(  0, 1));
  47.             legs.push(new Leg( 80, 1));
  48.             legs.push(new Leg(-80, -1));
  49.             legs.push(new Leg(  0, -1));
  50.             legs.push(new Leg( 80, -1));
  51.             
  52.             mKani = new Kani(legs);
  53.             
  54.             addEventListener(Event.ENTER_FRAME, tick);
  55.             stage.addEventListener(KeyboardEvent.KEY_DOWN, Key.onKeyDownHandler);
  56.             stage.addEventListener(KeyboardEvent.KEY_UP, Key.onKeyUpHandler);
  57.         }
  58.         
  59.         private function tick(e:Event):void
  60.         {
  61.             var leg:Leg;
  62.             
  63.             mStarbg.main();
  64.             mKani.main();
  65.             
  66.             if(count % 2 == 0) {scroll(1);}
  67.             count++;
  68.             
  69.             //描画
  70.             mScreen.fillRect(mScreen.rect, 0);
  71.             mStarbg.draw(mScreen);
  72.             
  73.             var matrix:Matrix = new Matrix();
  74.             for each(leg in legs)
  75.             {
  76.                 matrix.translate(leg.x, leg.y);
  77.                 mScreen.draw(leg.sprite, matrix);
  78.                 matrix.identity();
  79.             }
  80.             matrix.translate(mKani.x, mKani.y);
  81.             mScreen.draw(mKani, matrix);
  82.             
  83.             mScreen.copyPixels(mBGScreen, mScreen.rect, new Point(0, 0));
  84.             
  85.             //当たり判定
  86.             for each(leg in legs) {
  87.                 leg.hitflag = mBGScreen.getPixel32(leg.x, leg.y) != 0x00000000;
  88.             }
  89.         }
  90.         
  91.         public function scroll(vx:int):void
  92.         {
  93.             mBGScreen.scroll(-vx, 0);
  94.             mBGScreen.fillRect(new Rectangle(W-vx, 0, vx, H), 0);
  95.             
  96.             var i:int;
  97.             mBGen.step();
  98.             mTGen.step();
  99.             
  100.             for (i = 0; i < vx; i++)
  101.             {
  102.                 mBGen.step();
  103.                 mTGen.step();
  104.                 mBGen.draw(mBGScreen, W-vx+i, 160);
  105.                 mTGen.draw(mBGScreen, W-vx+i, 0, false);
  106.             }
  107.             
  108.             mKani.x -= vx;
  109.             for each(var leg:Leg in legs) {leg.x -= vx;}
  110.         }
  111.     }
  112. }
  114. import flash.display.*;
  115. import flash.events.*;
  116. import flash.geom.*;
  117. import flash.ui.*;
  119. class Kani extends Sprite
  120. {
  121.     public var body:Body = new Body();
  122.     public var legs:Array = new Array();
  123.     
  124.     public var auto:Boolean;
  125.     public var dir:String = "none";
  126.     public var timer:int;
  127.     public var dance:int;
  128.     
  129.     function Kani(legs:Array)
  130.     {
  131.         x = 200;
  132.         y = 120;
  133.         
  134.         auto = false;
  135.         timer = 100;
  136.         
  137.         this.legs = legs;
  138.         for each(var leg:Leg in legs)
  139.         {
  140.             leg.parent = this;
  141.             leg.x = x+leg.offset - 20+Math.random()*40;
  142.             leg.y = 120 + 100*leg.invert;
  143.         }
  144.         
  145.         addChild(body);
  146.     }
  147.     
  148.     public function main():void
  149.     {
  150.         var leg:Leg;
  151.         
  152.         if(auto == false)
  153.         {
  154.             if(Key.isLeft == true) {dir = "left"; timer = 90;}
  155.             else if(Key.isRight == true) {dir = "right"; timer = 90;}
  156.             else {dir = "none";}
  157.             
  158.             if(Key.isSpace == true && dance == 0) {dance = 20; timer = 90;}
  159.             
  160.             timer--;
  161.             if(timer == 0) {auto = true;}
  162.         }
  163.         if(auto == true)
  164.         {
  165.             if(timer == 0)
  166.             {
  167.                 if(dir == "none")
  168.                 {
  169.                     if(x < 160) {dir = "right";}
  170.                     else {dir = "left";}
  171.                 }
  172.                 else {
  173.                     if(x < 50 && dir != "right") {
  174.                         timer = 60;
  175.                     }
  176.                     if(x > 300 && dir != "left") {
  177.                         timer = 60;
  178.                     }
  179.                 }
  180.             }
  181.             else {
  182.                 dir = "none";
  183.                 if(timer == 40) {
  184.                     dance = 20;
  185.                 }
  186.                 timer--;
  187.             }
  188.             
  189.             if(Key.isLeft == true || Key.isRight == true)
  190.             {
  191.                 auto = false;
  192.                 timer = 90;
  193.             }
  194.         }
  195.         
  196.         if(dir == "left") {x -= 2;}
  197.         if(dir == "right") {x += 2;}
  198.         
  199.         if(dir != "none") {
  200.             for each(leg in legs) {
  201.                 leg.move(dir);
  202.             }
  203.         }
  204.         
  205.         if(dance > 0)
  206.         {
  207.             if(dance > 15) {body.x = 2;}
  208.             else if(dance > 10) {body.x = 0;}
  209.             else if(dance > 5) {body.x = -2;}
  210.             else {body.x = 0;}
  211.             dance--;
  212.         }
  213.         
  214.         graphics.clear();
  215.         for each(leg in legs)
  216.         {
  217.             graphics.lineStyle(6, 0xFF80FF);
  218.             graphics.moveTo(leg.offset/8, 10*leg.invert);
  219.             graphics.lineTo((leg.x-x), (leg.y-y)-70*leg.invert);
  220.             graphics.endFill();
  221.         }
  222.     }
  223. }
  225. class Body extends Sprite
  226. {
  227.     function Body()
  228.     {
  229.         graphics.beginFill(0xC060C0);
  230.         graphics.lineStyle(2, 0xFF80FF);
  231.         graphics.drawRect(-15, -15, 30, 30);
  232.         graphics.endFill();
  233.     }
  234. }
  236. class Leg
  237. {
  238.     public var parent:Kani;
  239.     public var sprite:Sprite;
  240.     
  241.     public var x:Number;
  242.     public var y:Number;
  243.     public var offset:Number;
  244.     public var invert:int;
  245.     public var hitflag:Boolean;
  246.     public var moveflag:Boolean;
  247.     public var gear:int;
  248.     
  249.     function Leg(offset:Number, invert:int)
  250.     {
  251.         this.offset = offset;
  252.         this.invert = invert;
  253.         
  254.         sprite = new Sprite();
  255.         
  256.         sprite.graphics.beginFill(0xC060C0);
  257.         sprite.graphics.lineStyle(0, 0xFF80FF);
  258.         sprite.graphics.lineTo(-5, -40*invert);
  259.         sprite.graphics.lineTo(-5, -60*invert);
  260.         sprite.graphics.lineTo(-2, -70*invert);
  261.         sprite.graphics.lineTo(2, -70*invert);
  262.         sprite.graphics.lineTo(5, -60*invert);
  263.         sprite.graphics.lineTo(5, -40*invert);
  264.         sprite.graphics.lineTo(0, 0);
  265.         sprite.graphics.endFill();
  266.     }
  267.     
  268.     public function move(dir:String):void
  269.     {
  270.         var threshold_l:Number = parent.x+offset + 30;
  271.         var threshold_r:Number = parent.x+offset - 30;
  272.         
  273.         if(moveflag == false) {
  274.             if(threshold_l < x || threshold_r > x)
  275.             {
  276.                 moveflag = true;
  277.                 gear = -12;
  278.             }
  279.             if(threshold_r > x)
  280.             {
  281.                 moveflag = true;
  282.                 gear = 12;
  283.             }
  284.         }
  285.         
  286.         if(moveflag == true)
  287.         {
  288.             if(dir == "left" && threshold_l-50 < x)
  289.             {
  290.                 x -= 4;
  291.                 
  292.                 if(gear < 0) {
  293.                     y -= 4 * invert;
  294.                 }
  295.                 else {
  296.                     y += 4 * invert;
  297.                     if(hitflag == true) {
  298.                         moveflag = false;
  299.                     }
  300.                     if(y < 0 || y > 240) {
  301.                         gear = -12;
  302.                     }
  303.                 }
  304.                 gear++;
  305.             }
  306.             else if(dir == "right" && threshold_r+50 > x)
  307.             {
  308.                 x += 4;
  309.                 
  310.                 if(gear > 0) {
  311.                     y -= 4 * invert;
  312.                 }
  313.                 else {
  314.                     y += 4 * invert;
  315.                     if(hitflag == true) {
  316.                         moveflag = false;
  317.                     }
  318.                     if(y < 0 || y > 240) {
  319.                         gear = 12;
  320.                     }
  321.                 }
  322.                 gear--;
  323.             }
  324.         }
  325.     }
  326. }
  328. class StarBG
  329. {
  330.     private var mWidth:int;
  331.     private var mHeight:int;
  333.     private var mStars:Array;
  334.     private var mN:int;
  335.     
  336.     private var mCount:int = 0;
  338.     function StarBG(w:int, h:int, n:int)
  339.     {
  340.         mWidth = w;
  341.         mHeight = h;
  342.         mN = n;
  344.         mStars  = new Array(n);
  345.         for (var i:int = 0;i < n;i++) {
  346.             mStars[i] = {
  347.                 x : Math.random()*w, y : Math.random()*h, speed : -Math.random()*1.5-0.5,
  348.                 color : ((Math.random()*0xC0+0x40)<<8)+((Math.random()*0xC0+0x40)<<16)+(Math.random()*0xC0+0x40),
  349.                 blink : Math.floor(Math.random())*40+20
  350.             };
  351.         }
  352.     }
  354.     public function main():void
  355.     {
  356.         var n:int = mN;
  358.         for each(var star:Object in mStars)
  359.         {
  360.             star.x += star.speed;
  361.             
  362.             if(star.x < 0)
  363.             {
  364.                 star.x += mWidth;
  365.                 star.y = Math.random()*mHeight;
  366.                 star.speed = -Math.random()*1.5-0.5;
  367.             }
  368.         }
  369.         mCount++;
  370.     }
  372.     public function draw(b:BitmapData):void
  373.     {
  374.         for each(var star:Object in mStars)
  375.         {
  376.             if((mCount % star.blink) == 1) {b.setPixel(star.x, star.y, 0xFFFFFF);}
  377.             else {b.setPixel(star.x, star.y, star.color);}
  378.         }
  379.     }
  380. }
  382. class Key
  383. {
  384.     public static var isLeft:Boolean = false;
  385.     public static var isRight:Boolean = false;
  386.     public static var isSpace:Boolean = false;
  387.     
  388.     public static function onKeyDownHandler(e:KeyboardEvent):void
  389.     {
  390.         switch(e.keyCode) {
  391.             case Keyboard.LEFT: Key.isLeft = true; break;
  392.             case Keyboard.RIGHT: Key.isRight = true; break;
  393.             case Keyboard.SPACE: Key.isSpace = true; break;
  394.         }
  395.     }
  396.     public static function onKeyUpHandler(e:KeyboardEvent):void
  397.     {
  398.         switch(e.keyCode) {
  399.             case Keyboard.LEFT: Key.isLeft = false; break;
  400.             case Keyboard.RIGHT: Key.isRight = false; break;
  401.             case Keyboard.SPACE: Key.isSpace = false; break;
  402.         }
  403.     }
  404. }
  406. class MountainGen
  407. {
  408.     private var mPrevBuffer:Array;
  409.     private var mHeight:int;
  410.     private var mCount:int = 100;
  412.     private var tmpBuffer:Array;
  413.     private var mGenFunc:Function;
  414.     function MountainGen(h:int, generator:int = 0)
  415.     {
  416.         mHeight = h;
  417.         mGenFunc = generator ? genWav2 : genWav;
  418.         mPrevBuffer = new Array(h);
  419.         tmpBuffer   = new Array(h);
  420.     }
  422.     public function draw(b:BitmapData, x:int, y:int, rev:Boolean = true):void
  423.     {
  424.         var i:int;
  425.         for (i = 0;i < mHeight;i++) {
  426.             if (tmpBuffer[i]) {
  427.                 var c:int = tmpBuffer[i];
  428.                 b.setPixel32(x, rev ? (y+mHeight-i) : (y+i), 0xff000000 | (c/3+11) | ((c/5 + 170)<<16) | ((c/2+60) << 8));
  429.             }
  430.         }
  431.     }
  433.     public function step():void
  434.     {
  435.         var t:Number = Number(mCount) * 0.02;
  436.         var h:int = mGenFunc(t) * mHeight;
  437.         var i:int, k:int, m:int;
  439.         for (i = 0;i < mHeight;i++) {
  440.             mPrevBuffer[i] = tmpBuffer[i];
  441.         }
  443.         for (i = 0;i < mHeight;i++) {
  444.             tmpBuffer[i] = (i < h) ? (Math.random()*80 + 80) : 0;
  446.             if (tmpBuffer[i]) {
  447.                 if (mPrevBuffer[i])
  448.                     tmpBuffer[i] = (tmpBuffer[i] + mPrevBuffer[i]*7)/8;
  450.                 if (mPrevBuffer[i] == 0 || i == (h-1)) {
  451.                     m = 50;
  452.                     for (k = i;k >= 0 && m > 0;k--, m-=4) {
  453.                         if (m > 33) m--;
  454.                         tmpBuffer[k] += m;
  456.                         m += Math.random()*7;
  457.                     }
  458.                 }
  460.                 if (mPrevBuffer[i+1] && i == (h-1)) {
  461.                     m = -48;
  462.                     for (k = i;k >= 0 && m < 0;k--, m++) {
  463.                         tmpBuffer[k] += m;
  464.                         if (tmpBuffer[k]<1) tmpBuffer[k] = 1;
  465.                     }
  466.                 }
  468.            }
  469.         }
  471.        for (i = 0;i < mHeight;i++)
  472.             tmpBuffer[i] = (tmpBuffer[i] < 0) ? 0 : (tmpBuffer[i] > 255) ? 255 : tmpBuffer[i];
  474.         mCount++;
  475.     }
  477.     private static function genWav(t:Number, nest:int = 0):Number
  478.     {
  479.         var v:Number = Math.sin(t);
  480.         v += Math.cos(t*3) * 0.1;
  481.         v += Math.cos(0.1 + t*10) * 0.02;
  482.         v *= Math.cos(t*0.1);
  484.         if (nest < 5)
  485.             v += genWav(t+1, ++nest);
  487.         v = v*0.2 + 0.3;
  489.         return (v<0) ? 0 : (v>1) ? 1 : v;
  490.     }
  492.     private static function genWav2(t:Number, nest:int = 0):Number
  493.     {
  494.         var v:Number = Math.sin(t);
  495.         v += Math.cos(t*3) * 0.1;
  496.         v += Math.cos(0.1 + t*9) * 0.02;
  497.         v *= Math.cos(0.2 + t*0.15);
  499.         if (nest < 5)
  500.             v += genWav2(t+1, ++nest);
  502.         v = v*0.2 + 0.2;
  504.         return (v<0) ? 0 : (v>1) ? 1 : v;
  505.     }
  506. }
noswf

なんとかディウスっぽい背景 ゲームっぽくしてみたforked from: なんとかディウスっぽい背景 [diff(117)]

  1. // forked from gyuque's なんとかディウスっぽい背景
  2. // ゲームっぽくしてみた
  3. // 十字キーで移動
  4. //　スペースキーで弾発射
  5. // だれか当たり判定つけて＞＜
  7. package
  8. {
  9.     import flash.display.*;
  10.     import flash.geom.*;
  11.     import flash.events.*;
  12.     import flash.ui.Keyboard;
  14.     [SWF(width="320", height="240", backgroundColor="0x000000", frameRate="30")]  
  15.     public class Nemesis extends Sprite
  16.     {
  17.         public static const W:int = 320;
  18.         public static const H:int = 240;
  20.         private var mScroll:int = 0;
  21.         private var mMyPos:Point;
  22.         private var mBGen:MountainGen = new MountainGen(160);
  23.         private var mTGen:MountainGen = new MountainGen(160, 1);
  25.         private var mBGScreen:BitmapData = new BitmapData(W, H, true, 0);
  26.         private var mBGScreenBmp:Bitmap;
  27.         private var mBGScreenBmp2:Bitmap;
  28.         private var mStarbg:StarBG = new StarBG(W, H, 30);
  29.         
  30.         private var ship:Ship = new Ship(0x00ffff);
  31.         private var speed:int = 4;
  32.         private var isUp:Boolean = false;
  33.         private var isDown:Boolean = false;
  34.         private var isLeft:Boolean = false;
  35.         private var isRight:Boolean = false;
  36.         private var isShot:Boolean = false;
  37.         
  38.         function Nemesis()
  39.         {
  40.             addChild(mStarbg);
  42.             mBGScreenBmp = new Bitmap(mBGScreen);
  43.             addChild(mBGScreenBmp);
  45.             mBGScreenBmp2 = new Bitmap(mBGScreen);
  46.             addChild(mBGScreenBmp2);
  48.             addChild(ship);
  49.             ship.x = 40;
  50.             ship.y = H / 2;
  51.             
  52.             var i:int;
  53.             mBGen.step();
  54.             mTGen.step();
  55.             for (i = 0;i < W;i++) {
  56.                 mBGen.step();
  57.                 mTGen.step();
  58.                 mBGen.draw(mBGScreen, i, 80);
  59.                 mTGen.draw(mBGScreen, i, 0, false);
  60.             }
  62.             addEventListener(Event.ENTER_FRAME, tick);
  63.             stage.addEventListener(KeyboardEvent.KEY_DOWN, onKeyDownHandler);
  64.             stage.addEventListener(KeyboardEvent.KEY_UP, onKeyUpHandler);
  65.         }
  66.         
  67.         private var _clrrc:Rectangle = new Rectangle(0, 0, 1, H);
  68.         private function tick(e:Event):void
  69.         {
  70.             
  71.             var ox:int = mScroll % W;
  72.             _clrrc.x = ox;
  73.             mBGScreen.fillRect(_clrrc, 0);
  75.             mStarbg.tick();
  76.             mBGen.step();
  77.             mTGen.step();
  79.             mStarbg.draw();
  80.             mBGen.draw(mBGScreen, ox, 80);
  81.             mTGen.draw(mBGScreen, ox, 0, false);
  83.             mBGScreenBmp.x = -ox;
  84.             mBGScreenBmp2.x = W-ox;
  86.             mScroll++;
  87.             
  88.             ship.y -= isUp? speed : 0;
  89.             ship.y += isDown? speed: 0;
  90.             ship.x -= isLeft? speed: 0;
  91.             ship.x += isRight? speed: 0;
  92.             if (isShot && !(mScroll%5)) {
  93.                 var bullet:Bullet = new Bullet(0xff00ff, 3, 20);
  94.                 bullet.x = ship.x;
  95.                 bullet.y = ship.y;
  96.                 addChild(bullet);
  97.             }
  98.             if (ship.x - ship.width< 0) ship.x = ship.width;
  99.             else if (ship.x > W) ship.x = W;
  101.                         if (ship.y - ship.height/2 < 0) ship.y = ship.height/2;
  102.                         else if (ship.y + ship.height/2 > H) ship.y = H - ship.height/2; 
  103.             
  104.         }
  105.         
  106.         private function onKeyDownHandler(e:KeyboardEvent):void {
  107.             switch(e.keyCode) {
  108.                 case Keyboard.UP: isUp = true; break;
  109.                 case Keyboard.DOWN: isDown = true; break;
  110.                 case Keyboard.LEFT: isLeft = true; break;
  111.                 case Keyboard.RIGHT: isRight = true; break;
  112.                 case Keyboard.SPACE: isShot = true; break;
  113.             }
  114.         }
  115.         private function onKeyUpHandler(e:KeyboardEvent):void 
  116.         {
  117.             switch(e.keyCode) {
  118.                 case Keyboard.UP: isUp = false; break;
  119.                 case Keyboard.DOWN: isDown = false; break;
  120.                 case Keyboard.LEFT: isLeft = false; break;
  121.                 case Keyboard.RIGHT: isRight = false; break;
  122.                 case Keyboard.SPACE: isShot = false; break;
  123.             }            
  124.         }        
  125.     }
  126. }
  128. import flash.display.*;
  129. import flash.events.Event;
  130. import flash.geom.Point;
  131.     
  132. class Ship extends Sprite
  133. {
  134.     public var color:uint;
  135.     function Ship(color:uint)
  136.     {
  137.         this.color = color;
  138.         this.graphics.lineStyle(0, color);
  139.         this.graphics.lineTo( -30, -10);
  140.         this.graphics.lineTo( -30, 10);
  141.         this.graphics.lineTo(0, 0);
  142.         this.graphics.endFill();
  143.     }
  144. }
  146. class Bullet extends Sprite
  147. {
  148.     public var color:uint;
  149.     public var size:uint;
  150.     public var speed:uint;
  151.     function Bullet(color:uint = 0x0000ff, size:uint = 3, speed:uint = 5)
  152.     {
  153.         this.color = color;
  154.         this.size = size;
  155.         this.speed = speed;
  156.         
  157.         this.graphics.lineStyle(0, color);
  158.         this.graphics.drawCircle(0, 0, size);
  159.         this.graphics.endFill();
  160.         
  161.         addEventListener(Event.ENTER_FRAME, updateHandler);
  162.     }
  163.     
  164.     private function updateHandler(e:Event):void 
  165.     {
  166.         this.x += speed;
  167.         
  168.         if (this.x + size / 2 > Nemesis.W) {
  169.             this.parent.removeChild(this);
  170.             removeEventListener(Event.ENTER_FRAME, updateHandler);
  171.         }
  172.     }
  173. }
  176. class MountainGen
  177. {
  178.     private var mPrevBuffer:Array;
  179.     private var mHeight:int;
  180.     private var mCount:int = 0;
  182.     private var tmpBuffer:Array;
  183.     private var mGenFunc:Function;
  184.     function MountainGen(h:int, generator:int = 0)
  185.     {
  186.         mHeight = h;
  187.         mGenFunc = generator ? genWav2 : genWav;
  188.         mPrevBuffer = new Array(h);
  189.         tmpBuffer   = new Array(h);
  190.     }
  192.     public function draw(b:BitmapData, x:int, y:int, rev:Boolean = true):void
  193.     {
  194.         var i:int;
  195.         for (i = 0;i < mHeight;i++) {
  196.             if (tmpBuffer[i]) {
  197.                 var c:int = tmpBuffer[i];
  198.                 b.setPixel32(x, rev ? (y+mHeight-i) : (y+i), 0xff000000 | (c/3+11) | ((c/5 + 170)<<16) | ((c/2+60) << 8));
  199.             }
  201.         }        
  202.     }
  204.     public function step():void
  205.     {
  206.         var t:Number = Number(mCount) * 0.02;
  207.         var h:int = mGenFunc(t) * mHeight;
  208.         var i:int, k:int, m:int;
  210.         for (i = 0;i < mHeight;i++) {
  211.             mPrevBuffer[i] = tmpBuffer[i];
  212.         }
  213.         
  214.         for (i = 0;i < mHeight;i++) {
  215.             tmpBuffer[i] = (i < h) ? (Math.random()*80 + 80) : 0;
  217.             if (tmpBuffer[i]) {
  218.                 if (mPrevBuffer[i])
  219.                     tmpBuffer[i] = (tmpBuffer[i] + mPrevBuffer[i]*7)/8;
  221.                 if (mPrevBuffer[i] == 0 || i == (h-1)) {
  222.                     m = 50;
  223.                     for (k = i;k >= 0 && m > 0;k--, m-=4) {
  224.                         if (m > 33) m--;
  225.                         tmpBuffer[k] += m;
  227.                         m += Math.random()*7;
  228.                     }
  229.                 }
  231.                 if (mPrevBuffer[i+1] && i == (h-1)) {
  232.                     m = -48;
  233.                     for (k = i;k >= 0 && m < 0;k--, m++) {
  234.                         tmpBuffer[k] += m;
  235.                         if (tmpBuffer[k]<1) tmpBuffer[k] = 1;
  236.                     }
  237.                 }
  239.            }
  240.         }
  242.        for (i = 0;i < mHeight;i++)
  243.             tmpBuffer[i] = (tmpBuffer[i] < 0) ? 0 : (tmpBuffer[i] > 255) ? 255 : tmpBuffer[i];
  245.         mCount++;
  246.     }
  248.     private static function genWav(t:Number, nest:int = 0):Number
  249.     {
  250.         var v:Number = Math.sin(t);
  251.         v += Math.cos(t*3) * 0.1;
  252.         v += Math.cos(0.1 + t*10) * 0.02;
  253.         v *= Math.cos(t*0.1);
  255.         if (nest < 5)
  256.             v += genWav(t+1, ++nest);
  258.         v = v*0.2 + 0.3;
  260.         return (v<0) ? 0 : (v>1) ? 1 : v;
  261.     }
  263.     private static function genWav2(t:Number, nest:int = 0):Number
  264.     {
  265.         var v:Number = Math.sin(t);
  266.         v += Math.cos(t*3) * 0.1;
  267.         v += Math.cos(0.1 + t*9) * 0.02;
  268.         v *= Math.cos(0.2 + t*0.15);
  270.         if (nest < 5)
  271.             v += genWav2(t+1, ++nest);
  273.         v = v*0.2 + 0.2;
  275.         return (v<0) ? 0 : (v>1) ? 1 : v;
  276.     }
  277. }
  279. class StarBG extends Sprite
  280. {
  281.     private var mWidth:int;
  282.     private var mHeight:int;
  284.     private var mStars:Array;
  285.     private var mStarVs:Array;
  286.     private var mN:int;
  288.     function StarBG(w:int, h:int, n:int)
  289.     {
  290.         mWidth = w;
  291.         mHeight = h;
  292.         mN = n;
  294.         mStars  = new Array(n);
  295.         mStarVs = new Array(n);
  296.         for (var i:int = 0;i < n;i++) {
  297.             mStars[i] = new Point(int( Math.random()*w ), int( Math.random()*h ));
  298.             mStarVs[i] = Math.random() + 0.2;
  299.         }
  300.     }
  302.     public function tick():void
  303.     {
  304.         var n:int = mN;
  306.         for (var i:int = 0;i < n;i++) {
  307.             mStars[i].x -= Number(mStarVs[i]);
  309.             if (mStars[i].x < 0) {
  310.                 mStars[i].x += mWidth;
  311.                 mStars[i].y = int( Math.random()*mHeight );
  312.             }
  313.         }
  314.     }
  316.     public function draw():void
  317.     {
  318.         var g:Graphics = graphics;
  319.         var n:int = mN;
  321.         g.clear();
  322.         for (var i:int = 0;i < n;i++) {
  323.             g.beginFill(0xffffff);
  324.             g.drawCircle( mStars[i].x, mStars[i].y , 0.4);
  325.         }   
  326.     }
  327. }
noswf
Get Adobe Flash Player