※現在、「wonderfl build flash online」求人コンテンツ制作に関してのアンケートを実施中です！みなさまのお力添えを頂いて、続々とアンケート結果が集まっていますが、まだまだ募集しております。ご協力のほど、どうぞよろしくお願いいたします！

wonderfl運営事務局
→アンケートページ（※ログインしてからお答えいただけるようになっています。）

 notice: Flash editor updated! Join the development! Thanks to MiniBuilder


forked from : keim_at_Si's ABC flyer [diff(296)]

embed

noswf download fullscreen
flash swf thumbnail play
reload download fullscreen

FAVORITE BY
:
best one yet needs the cloud mod though
:
3d
:
OUTRAGEOUS!
:
3D
:
Very Nice Sound and 3D
:
its a burner !
FORKED
>sort

wonderflで音楽♪Final TakeOff from:ABC flyer forked from: wonderflで音楽♪Final TakeOff from:ABC flyer [diff(1)]

  1. // forked from keim_at_Si's wonderflで音楽♪Final TakeOff from:ABC flyer
  2. // forked from keim_at_Si's ABC flyer
  3. // forked from keim_at_Si's ABC ground
  4. // The gradation colors are refered from psyrak's BumpyPlanet and nemu90kWw's 水平線.
  5. // arrows or [wasd] to move, [shift/x/m] to accel.
  6. //--------------------------------------------------------------------------------
  7. package {
  8.     import flash.display.*;
  9.     import flash.events.*;
  10.     import flash.media.*;
  12.     [SWF(width='465', height='465', backgroundColor='#103860', frameRate='30')]
  13.     public class main extends Sprite {
  14.         function main() {
  15.             // keyboard mapper
  16.             _key = new KeyMapper(stage);
  17.             _key.map(0,37,65).map(1,38,87).map(2,39,68).map(3,40,83).map(4,17,90,78).map(5,16,88,77);
  18.             
  19.             // rendering engine
  20.             _shape3d.visible = false;
  21.             addChild(_shape3d);
  22.             
  23.             // background
  24.             _base.x = 232.5;
  25.             _base.y = 232.5;
  26.             _landscape.rotationX = -85;
  27.             _landscape.scaleX = 10;
  28.             _landscape.scaleY = 8;
  29.             _landscape.x = -1024-_base.x;
  30.             _landscape.y = 280-_base.y;
  31.             _landscape.z = 1800;
  32.             _sky.scaleX = 5;
  33.             _sky.scaleY = 5;
  34.             _sky.x = -1520-_base.x;
  35.             _sky.y = -1400-_base.y;
  36.             _sky.z = 1800;
  37.             _base.addChild(_landscape);
  38.             _base.addChild(_sky);
  39.             addChild(_base);
  40.             
  41.             // rendering layer
  42.             addChild(new Bitmap(_screen));
  43.             
  44.             // initialize
  45.             _flyer = new Flyer(0, 0, 100);
  46.             _pitch = 0;
  47.             _roll = 0;
  48.             
  49.             // event listener
  50.             addEventListener("enterFrame", _onEnterFrame);
  51.             
  52.             _startMusic();
  53.         }
  55.         private function _onEnterFrame(e:Event) : void {
  56.             // move
  57.             var inkey:int = _key.flag;
  58.             _roll  += ((inkey & 1)      - ((inkey & 4)>>2))*5 - _roll*0.1;
  59.             _pitch += (((inkey & 2)>>1) - ((inkey & 8)>>3))*2 - _pitch*0.1;
  60.             _globalVel.z += 0.5 - _globalVel.z * ((inkey & 32) ? 0.03 : 0.06);
  61.             _globalVel.x = (_roll) * 0.1 - 0.5;
  62.             _base.rotationX = _pitch;
  63.             _base.rotationZ = _roll;
  64.             
  65.             // update
  66.             _landscape.update();
  67.             _flyer.update();
  68.             
  69.             // rendering
  70.             _screen.fillRect(_screen.rect, 0);
  71.             _flyer.render();
  72.         }
  73.         
  74.         // sound
  75.         private var _sound:Sound = new Sound();
  76.         private var _sequencer:Sequencer = new Sequencer();
  77.         private var _module:TinySiOPM = new TinySiOPM(2048, 1024, _sequencer.onSoundFrame);
  78.         
  79.         private function _startMusic() : void {
  80.             var mml:String = "";
  81.             mml += "#BS=l2<ef+abaf+>[2a8[2a4<a>araa12<gara>a4<a>araa6arr<ef+>a4a4<a>araa6<arrgara>a4<a>ara";
  82.             mml += "<ef+abaf+>a8a4<a>araa12<gara>a4<a>ara<<c+de4dc+>a4>a4a4<a>araa6<arrgara>a4f+4<f+r>g4<gr>g+4a8]|";
  83.             mml += "[2[2a4<a>araa6<arrga>g4g4<g>grgg16b4b4<b>brbb6<brrd8<dr6>e8<errrde>>|a4]";
  84.             mml += "l4g12g<g>gr<d8<dr>d<ef+r>>a8[11a]<gagd>g12g<g>gr<d8<dr>d<ef+r>>a8[23a]a16g8f+8";
  85.             mml += "[4l2[6a4<ar>]g4<gr>f+4<f+r>]|l4[2f8f2r2g8<g2r2d>gg8<g2r2>a8<age>f8f2r2g8<g2r2>ga8<e6g2a<c>bg8>]f8f2r2g48";
  86.             mml += "a8a<a2>a6a6a6a8aa2<a2>aa6a6g2a6[2aa8a6a6a8]l2]";
  87.             mml += "[2l4[4f8f2r2g8<g2r2d>gg8<g2r2>a8<age>f8f2r2g8<g2r2>ga8<e6g2a<c>bg8>]f8f2r2|g52]g48l2];";
  88.             mml += "@0@o1o4v6s16BS; @0@i3@o1o2s8BS; v7@0@i3o4s8BS;";
  89.             mml += "#BD=r16[2v10p4[3l4[3rcr2cc2crrc]|rcr2cc2l2v8<p1ggp5cc>l4p4gv10c]l3v8<p1ggg2p3eee2p5ccc2>l4v10p4rc[3rcr2cc2|crrc]c6c10v10crcr|v8<c6c10>v10";
  90.             mml += "[2l4[2[2ccr2cc2c[2r10c2c]r12]][2crrcrrcrrcrcr12crcrrcrrrcrrrcrcr]rcccl3v8<ggg2ccc2>l4v10cr12crcr";
  91.             mml += "[4cr12cr8crcr8c8c8]|[4cr8crcrccr8crcr8]cr8cr8[2cr12]cc[3rcr6c2crrc]r4l2v8<ggggeeeecccc>ggv10]";
  92.             mml += "[2[8cr8crcrccr8crcr8]cr8cr8[2cr12]cc]]rcrcr;";
  93.             mml += "#SN=r16[2v15p3[3l8[6rc]|rcl2p1ccp5ccp4c8]l3p1ccc2p3ccc2p5ccc2p3ccc2l8[4rc]rcc6c10|c4c4rc6c10";
  94.             mml += "[2[16rc][2l8rrcr4cr12crrcrcl4rccc|c2cc2c8]ccccccccl3ccc2ccc2l8c16cc";
  95.             mml += "[4rcrcrc4c2c2cc]|l8[7rc]l4cccrl8[6rc]rl2cc6ccccc4cc10l8c[3rc][6rc]r4l2[14c]l8]";
  96.             mml += "[2[2l8[7rc]l4cccrl8[6rc]rl2cc6ccccc4c|c2]c10l8c[3rc]]]c8l2[4c]c4c8c32;";
  97.             mml += "#CY=r12[2l2[2s4v15p3d16s99v4p5[56c+]][2[3s4v15p3d16s99v4p5[8c+]]|[16c+]]|[16c+]";
  98.             mml += "[2l4[2s4v15p3d16s32v5p5[28c+]]s4v15[2r4p3d28p6c+20p3d12|p6c+64]p6c+100p3d16s5[5p1c+8p6|d56]d8";
  99.             mml += "|[2s4v15p3c+16l2v6p5[14s99c+c+s8c+4]]s4v15p6c+12p2d16v6p4s8l8[3c+|r]";
  100.             mml += "l2[2s99[14v6c+v4c+]|s4v6d8]][2[4s4v15p3c+16l2v6p5[14s99c+c+s8c+4]]s4v15p6c+12p2d16v6p4s8l8[2c+r]|r4]]";
  101.             mml += "s6v15p3r24c+8p6d32;";
  102.             mml += "#CB=r16[2l8r256[32g]|[2r832|[32g][24g]][64g][8g][64g][8g]];";
  103.             mml += "#RD=r16l8r512[2r256[2r4l8[7e]r4r64]r64[4r4[6e]r12]|r4[31e]r4r192][2r4[31e]r4]r64[2r4[31e]r4]r64;";
  104.             mml += "@0s32w32o4BD; @3o0k6s12SN; @3o0CY; @2v8s99o6k120@o1CB;@0v8s64o6@i3p6CB; @2v10s4o6k123@o1RD;@0v5s20o5@i5p2RD;";
  105.             mml += "#GT=r12[2l32s1o4fga56<c8>fga20<c6c2r8>a8<c6c2r4d8> fga20<g+1a5g+1a5g+1a3a28>fga20g+1a5g+1a5g+1a3|w1a28";
  106.             mml += "w0[2[2a32g36b28<d16e16>][2g32<d32>d4r4|s8a4s1a52] s8a4s1a12s8a4s1a40g32a16g8f+8l4[4s4rarra8rs2a8a12g8f+8]";
  107.             mml += "|[2f8rg20g8ra8s4ages2f8rg12ra36]f8rg52s4aar8<s2c16>s4aar<drs2c12>s4aar8<s2c8rd32>]";
  108.             mml += "[4f8rg20g8ra8s4ages2f8rg12ra36]f8rg52 [4f8rg20g8ra8s4ages2|r8f8rgra36]f8rg12ra36f8rg48]a20l4grs7w2a32;";
  109.             mml += "@2@o1o6v6k1  GT; @0@i3@o1o4v12k112GT; p7@1@i4o3v6    GT;";
  110.             mml += "@2@o1o6v6k113GT; @0@i3@o1o4v12k224GT; p1@1@i4o3v6k112GT;";
  111.             mml += "@2@o1o7v5k1  GT; @0@i3@o1o5v10k112GT; p4@1@i4o4v6    GT;";
  112.             mml += "#S1=r16[2v8s5o6[2[2l2rrccrcrcc16rrddrdrdd16rreereree12|c+dc+6>a6e8c+6r6<]|l4arar24]rrarar|r20";
  113.             mml += "l4v6[2c+32d36d28d16e16c+24e8d36d28d16e16r20[2g12f+32f+ree56|r16]l2[5s64[6>a>a<a<a]s5g8f+8]";
  114.             mml += "|>l4[2a8rg16rg8ra16ra8rg16a36]a8rg52l2s64[16a>a<|a<a>]l4s5<] >l4[4a8rg16rg8ra16ra8rg16a36]a8rg52 l4[2a8rg16rg8ra16rr8a8rgra36]";
  115.             mml += "l2>gab<c>ab<cd>b<cdecdefdefgefgafgabgab<c>ab<cd>b<cdecdefdefgefgafgabgab<c>ab<cdl4d+1e11d12cdd+1e3dc>a8reab8rb16a20egar<c12>b52]";
  116.             mml += "r12gr6ar6v3ar6v2ar6v1ar6ar6;";
  117.             mml += "#S2=r16[2v8s5o5[2[2l2rraararaa16rrbbrbrbb16<rrc+c+rc+rc+c+12|r4>a6e6c+8>a6<r6]|l4ere>r24]rrerer|r20>";
  118.             mml += "l4v6[2[2a32b36b28a16b16]<d32[2d32drc+c+56|d28][5r48d8d8] |l4[2c8r>b16rb8r<c16rc8r>b16<c36]c8r>b52r124]";
  119.             mml += "l4[4c8r>b16rb8r<c16rc8r>b16<c36]c8r>b52 l4[4c8r>b16rb8r<c16r|r8c8r>br<c36]c8r>b16<c36>a8rg52]";
  120.             mml += "r12dr6er6v3er6v2er6v1er6er6;";
  121.             mml += "#S3=r16[2v8s5o5[2[2l2rrffrfrff16rrggrgrgg16rraararaa12|r4e6c+6>a8e6<r6]<|l4c+rc+>r24]rrc+rc+r|r20>";
  122.             mml += "l4v6[2[2e32g36f+28f+16g+16]b32[2a32araa56|b28][5r48b8a8] |l4[2f8rd16rd8re16rf8rd16e36]f8rd52r124]";
  123.             mml += "l4[4f8rd16rd8re16rf8rd16e36]f8rd52 l4[4f8rd16rd8re16r|r8f8rdre36]f8rd12re36f8rd52]";
  124.             mml += "r12>br6<c+r6v3c+r6v2c+r6v1c+r6c+r6;";
  125.             mml += "@1k1S1; @1k-1S2; @1S3; @1k-1S1;";
  126.             mml += "#MA=r16s4r508[2l4[2c1c+23dec+24de|d+1e15d12>a<c+1d11c+>arbr<]d+1e11dg+1a11g+arg+rf+rg+r";
  127.             mml += "g+1a51a+1b7<c+>brag+1a43c1c+3ea24c1c+3ea20a+1b7<c+>brag+1a91";
  128.             mml += "[2[3f+1g3]f+1g5f+5r1|e40]a40[3f+1g3]f+1g5f+5r1e40c+1d7c+d6er2c1c+3r>a44";
  129.             mml += "|ab<c2>b2a<d+1e11d16>gg<c>ba16g2f2e12d8ega20ab<c>a<c+1d7>a<d+1e7>a8<d+1e3gega8b<c>a8<cd+1e7dr2cr2>a36<d+1e11d128r48>]";
  130.             mml += "ab<c2>b2a<d+1e11d16>gg<c>ba16g2f2e12d8ega20ab<c>a<c+1d7>a<d+1e7>a8<d+1e3gega8b<c>a8<cd+1e7dr2cr2>a36";
  131.             mml += "<d+1e11d16>gg<c>ba16g2f2e12d8ega20ab<c>a<c+1d7>a<d+1e7>a8<d+1e3gega8b<c>a8<cd+1e3rdr2cr2>a36<d+1e11d52>>";
  132.             mml += ">b1<c3>b1<c3>a2g2a12l3geg2aga2bab2<c>b<c2dcd2l4r8d+1e13c6dc>ba<c20>l1ab<cdefgg+a8l4gfefge8d2c2d>a20cccc>b<cgc8>b1<c19";
  133.             mml += "l2>b<cdecdefdefgefgafgabgab<c>ab<cd>b<cdecdefdefgefgafgabgab<c>ab<cd>b<cdecdefl4f+1g11f12eff+1g3fec8r>a<cd8rd16c20>ab<cre12d52>;";
  134.             mml += "@1v12o6k-1MA; @6v12o5k1MA; @8v4p1o6r4MA;";
  135.             
  136.             _sequencer.mml = _expandMML(mml);
  137.             _sound.addEventListener("sampleData", function(e:SampleDataEvent) : void {
  138.                 var i:int, out:Vector.<Number> = _module.render();
  139.                 for (i=0; i<4096; i++) e.data.writeFloat(out[i]);
  140.             });
  141.             _sound.play();
  142.         }
  143.         
  144.         private function _expandMML(mml:String) : Array {
  145.             var split:Array = mml.replace(/\s+/g, "").split(/;/);
  146.             var list:Array = [], macro:* = {}, charA:int = "A".charCodeAt();
  147.             var defMacro:RegExp = /^#([_A-Z][_A-Z0-9]*)=?(.*)/m;
  148.             for each (var seq:String in split) {
  149.                 var res:* = defMacro.exec(seq);
  150.                 if (res) macro[res[1]] = res[2];
  151.                 else list.push(seq.replace(/[_A-Z][_A-Z0-9]*/g, function() : String {
  152.                     if (!arguments[0] in macro) return "";
  153.                     return macro[arguments[0]];
  154.                 }));
  155.             }
  156.             return list;
  157.         }
  158.     }
  159. }
  161. import flash.display.*;
  162. import flash.geom.*;
  163. import flash.events.*;
  164. import flash.filters.*;
  165. import mx.utils.Base64Decoder;
  167. // internal variables
  168. //----------------------------------------------------------------------------------------------------
  169. var _key:KeyMapper;
  170. var _models:ModelManager = new ModelManager();
  172. var _flyer:Flyer;
  173. var _landscape:Landscape = new Landscape(256, 256);
  174. var _sky:Sky = new Sky();
  175. var _base:Sprite = new Sprite();
  177. var _light:Light = new Light(-1,-1,-1);
  178. var _shape3d:Shape3D = new Shape3D();
  179. var _screen:BitmapData = new BitmapData(465, 465, true, 0);
  180. var _mat2d:Matrix = new Matrix(1,0,0,1,232,232);
  181. var _pitch:Number, _roll:Number, _globalVel:Vector3D = new Vector3D();
  182. var _homingAbility:Number = 0.1;
  184. // Key mapper
  185. //----------------------------------------------------------------------------------------------------
  186. class KeyMapper {
  187.     public  var flag:int = 0;
  188.     private var _mask:Vector.<int> = new Vector.<int>(256, true);
  189.     
  190.     function KeyMapper(stage:Stage) : void { 
  191.         stage.addEventListener("keyDown", function(e:KeyboardEvent):void { flag |= _mask[e.keyCode]; });
  192.         stage.addEventListener("keyUp",   function(e:KeyboardEvent):void { flag &= ~(_mask[e.keyCode]); });
  193.     }
  194.     
  195.     public function map(bit:int, ...args) : KeyMapper {
  196.         for (var i:int=0; i<args.length; i++) { _mask[args[i]] = 1<<bit; }
  197.         return this;
  198.     }
  199. }
  201. // Resource
  202. //----------------------------------------------------------------------------------------------------
  203. class ModelManager {
  204.     public var mdlFlyer:Model;
  205.     public var mdlFire:Model;
  206.     public var texFire:Vector.<BitmapData> = new Vector.<BitmapData>(8, true);
  207.     private var _dec:Base64Decoder = new Base64Decoder();
  208.     private const SCALE:Number = 0.1;
  209.     function ModelManager() {
  210.         var i:int, vdata:String="", idata:String="", shp:Shape=new Shape(), mtx:Matrix=new Matrix();
  211.         // Flyer model
  212.         vdata += "iN94Art14Ar5234tF43zutz4Au503zwR4HwxNz4Awt030zN34Ar524ItF44Mu504MwR4IQwt04LiN94Aft73Yft93AtF43znt53Q";
  213.         vdata += "mt93AwR4HwvR6nmtN6nQvSB3mmuD4AmuF3gmuB3AiOD4AfuF3gfuB3AzN34A0SEIA0uAHm1N73w1N54A4eDYA4uAHz4t+324t94A";
  214.         vdata += "7OB4AhN734at73Aat53Iat53Yat534at74AVt73AVt53IVt53YVt73gWR73rVt/3AVuB3IVuB3YVt/3gWR/3rat/3AauB3IauB3Y";
  215.         vdata += "at/3gat/4AfuD3oiN94AUt6nQUt7XZUt7XGUt93cUt93DUuAHGUuAHZUuA3QWt93QWt93QiN94Aft74oft95AtF44Mnt54wmt95A";
  216.         vdata += "wR4IQvR6oZtN6owvSB4ZmuD4AmuF4gmuB5AiOD4AfuF4gfuB5AzN34A0SEIA0uAIZ1N74Q1N54A4eDYA4uAIM4t+4J4t94A7OB4A";
  217.         vdata += "hN74Iat75Aat544at54oat54Iat74AVt75AVt544Vt54oVt74gWR74UVt/5AVuB44VuB4oVt/4gWR/4Uat/5AauB44auB4oat/4g";
  218.         vdata += "fuD4YiN94AUt6owUt7YmUt7Y5Ut94jUt948UuAI5UuAImUuA4wWt94wWt94wbN/3AbN/2QZt/0gdV93AdV92AgB93AgB92AcN/0I";
  219.         vdata += "mt93AgB/3AgB/2AdV/3AdV/2Amt93AbN/5AbN/5wZt/7gdV95AdV96AgB95AgB96AcN/74mt95AgB/5AgB/6AdV/5AdV/6Amt95A";
  220.         vdata += "UN/1wat93AWV92YX193ASt/2AUt92gVN93ATt/24VN93AWB/3AX193Aat93AUN/6Qat95AWV95oX195ASt/6AUt95gVN95ATt/5I";
  221.         vdata += "VN95AWB/5AX195Aat95AWtj3IUtj3IVt53IVt53Qat53Iat53QWtj44Utj44Vt544Vt54wat544at54w"
  222.         idata += "AAQIAAAgMABCQgHBCQYIBCAYFAAAoBAAAsKBBw4JBDg0JBDA0OAFRYTAEhUTADxITAEA8TAGBcWAFxsUAGRoYAJiglAJygmAJSgk";
  223.         idata += "AHyMiAFh8iAFhUfAFiIhAGBYhAHjo5AKywQALDEyALSwyAPh0cAPxApAOh4dAOzodAGBobAFxgbAIBkYAISAYAQEExAMEAxAQUMy";
  224.         idata += "AMUEyAQ0Y3AMkM3ARkc2AN0Y2AR0U1ANkc1ARUQ0ANUU0AREIvANEQvAQkAwAL0IwCSEZDCQUhDCRUdICSERFCSEJECSEBCCQUBI";
  225.         idata += "ATlFQATlBNATk1KATkpLAUVJTAT1ZSAU1VUAYGNhAYWNiAX2NgAXV5aAXVpRAWlBRAXF1RAXFFTAdHVZAS2dmAbWxnAbWdoAV1h4";
  226.         idata += "AZEt5AWFl1AWHV2AVlVTAVlNSAU1RbAU1tcAbHt6AbHprAbX17AbXtsAcoB9Acn1tAcYGAAcYByAcH+BAcIFxAb35/Ab39wAanx+";
  227.         idata += "Aan5vAa3p8Aa3xqCfYCCCfYJ7CgoF/Cf36CCfnyCCfHqCCgnp7AbmkzAPXM4AFhMXAFBMXAT05SAUU5SAiIaFAhYaQAi4qRAiomR";
  228.         idata += "Ai5GOAjI2OAk5SWAnpSTAn5iZAn5eYAnJ+ZAnJuaAp6WkAo6qhAqKmmAo6GiAqKepApKmnAqaSgAoKKrAq6mgAsLGzArbavAsrW0";
  229.         idata += "Arq2vAtbO0As7WwArLC1At66sArLW3Auru5AuL28Av8HAAwsO+BBAUCBAQQCBBQYDBAgUDBCAUEBBwgEBCgwEBAQoEBCw0MBCgsM";
  230.         idata += "BBAwOBBwQOAFBEQAExQQAFxQTAFhcTAHB0aAGRwaAHR4bAGh0bAFBseAERQeAIiYlAISIlAJyYiAIyciAJCAhAJSQhAKxARAKisR";
  231.         idata += "ALSkQALC0QALg8pALS4pALzArAKi8rAMDEsAKzAsAMy4tAMjMtANzgzAMjczAOTo1ANDk1AOjs2ANTo2AOzw3ANjs3APD04ANzw4";
  232.         idata += "AHT48AOx08APhw9APD49AOSoRAHjkRANC8qAOTQqCR0ZICSUdIAS0xPATktPATk9SAUU5SAVFVYAV1RYAVVZZAWFVZATFlWAT0xW";
  233.         idata += "AYGFdAXGBdAXWFiAXl1iAXFtfAYFxfATEtmAZUxmAS2RoAZ0toAZEppAaGRpAZWZrAamVrAZmdsAa2ZsAaGluAbWhuAbW5zAcm1z";
  234.         idata += "Ab3B1AdG91AcHF2AdXB2AcXJ3AdnF3AcnM9Ad3I9Adnd4AWHZ4APVd4Adz14AWUxlAdFllAdGVqAb3RqCg4KACgYOAAOHNuAMzhu";
  235.         idata += "Ah4iFAhIeFAiYqIAh4mIAi4aIAiouIAj5COAjY+OAkIaLAjpCLAhIWQAj4SQAkpOWAlZKWAlZaYAl5WYAlpSZAmJaZAm5yeAnZue";
  236.         idata += "AnJmUAnpyUAnZ6TAkp2TApaKgApKWgApaajAoqWjAp6imApaemArK6xAsKyxArq+yAsa6yAsbK0As7G0Aubu9AuLm9Aurm4AvLq4";
  237.         idata += "AvsPBAv77BAwr6/AwMK/"
  238.         mdlFlyer = _unpackModel(vdata, idata, [new Material(0xc0c0c0), new Material(0x203040), new Material(0xffc040)]);
  239.         // Fire billboard
  240.         mtx.createGradientBox(32,32,0,0);
  241.         for (i=0; i<8; i++) {
  242.             texFire[i] = new BitmapData(32, 32, true, 0);
  243.             shp.graphics.clear();
  244.             shp.graphics.beginGradientFill(GradientType.RADIAL, [0x80c0f0, 0x80c0f0], [0,0.5-i*0.05], [0,255], mtx);
  245.             shp.graphics.drawCircle(16,16,16);
  246.             shp.graphics.endFill();
  247.             texFire[i].draw(shp);
  248.         }
  249.         mdlFire = new Model(Vector.<Number>([-1,-1,0,-1,1,0,1,-1,0,1,1,0]), Vector.<Number>([0,0,0,0,1,0,1,0,0,1,1,0]));
  250.         mdlFire.face(0,1,2).face(3,2,1);
  251.     }
  252.     
  253.     private function _unpackModel(vdata:String, idata:String, materials:Array) : Model {
  254.         var i:int, ui:uint, model:Model = new Model(null, null, Vector.<Material>(materials));
  255.         for (i=0; i<vdata.length; i+=5) {
  256.             _dec.decode(vdata.substr(i, 5) + "A==");
  257.             ui = (_dec.toByteArray().readUnsignedInt())>>2;
  258.             model.vertices.push(((ui&1023)-512)*SCALE, (((ui>>10)&1023)-512)*SCALE, (((ui>>20)&1023)-512)*SCALE);
  259.         }
  260.         for (i=0; i<idata.length; i+=5) {
  261.             _dec.decode(idata.substr(i, 5) + "A==");
  262.             ui = (_dec.toByteArray().readUnsignedInt())>>2;
  263.             model.face(ui&255, (ui>>8)&255, (ui>>16)&255, (ui>>24)&63);
  264.         }
  265.         return model;
  266.     }
  267. }
  269. // Background
  270. //----------------------------------------------------------------------------------------------------
  271. class Sky extends Shape {
  272.     // This color gradation is refered from nemu90kWw's 水平線
  273.     // http://wonderfl.kayac.com/code/2b527a2efe155b7f69330822a3c7f7733ab6ea7e
  274.     public var gradation:* = {
  275.         color:[0x103860, 0x4070B8, 0x60B0E0, 0xD0F0F0, 0x0033c0, 0x0033c0], 
  276.         alpha:[100, 100, 100, 100, 100, 0], ratio:[0, 128, 192, 216, 224, 255]
  277.     };
  278.     function Sky() {
  279.         var mat:Matrix = new Matrix();
  280.         mat.createGradientBox(700, 380, Math.PI/2);
  281.         graphics.beginGradientFill("linear", gradation.color, gradation.alpha, gradation.ratio, mat);
  282.         graphics.drawRect(0, 0, 700, 380);
  283.         graphics.endFill();
  284.     }
  285. }
  287. class Landscape extends Bitmap {
  288.     // This color gradation is refered from psyrak's BumpyPlanet
  289.     // http://wonderfl.kayac.com/code/d79cd85845773958620f42cb3e6cb363c2020c73
  290.     public var gradation:* = {
  291.         color:[0x000080, 0x0066ff, 0xcc9933, 0x00cc00, 0x996600, 0xffffff], 
  292.         alpha:[100, 100, 100, 100, 100, 100], ratio:[0, 96, 96, 128, 168, 192]
  293.     };
  294.     public var pixels:BitmapData, texture:BitmapData, rect:Rectangle;
  295.     function Landscape(w:int, h:int) {
  296.         texture = new BitmapData(w*2, h*2, false, 0);
  297.         pixels = new BitmapData(w, h, false, 0);
  298.         rect = new Rectangle(0, 0, w, h);
  299.         super(pixels);
  300.         
  301.         // height map
  302.         var hmap:BitmapData = new BitmapData(w, h, false, 0);
  303.         hmap.perlinNoise(w*0.5, h*0.5, 10, Math.random()*0xffffffff, true, false, 0, true);
  304.         hmap.colorTransform(hmap.rect, new ColorTransform(1.5, 1.5, 1.5, 1, -64, -64, -64, 0));
  305.         
  306.         // texture
  307.         var mapR:Array=new Array(256), mapG:Array=new Array(256), mapB:Array=new Array(256);
  308.         var gmap:BitmapData = new BitmapData(256,1,false,0), render:Shape = new Shape(), mat:Matrix = new Matrix();
  309.         mat.createGradientBox(256,1,0,0,0);
  310.         render.graphics.clear();
  311.         render.graphics.beginGradientFill("linear", gradation.color, gradation.alpha, gradation.ratio, mat);
  312.         render.graphics.drawRect(0,0,256,1);
  313.         render.graphics.endFill();
  314.         gmap.draw(render);
  315.         for (var i:int=0; i<256; i++) {
  316.             var col:uint = gmap.getPixel(i, 0);
  317.             mapR[i] = col & 0xff0000;
  318.             mapG[i] = col & 0x00ff00;
  319.             mapB[i] = col & 0x0000ff;
  320.         }
  321.         gmap.dispose();
  322.         mat.identity();
  323.         texture.paletteMap(hmap, hmap.rect, hmap.rect.topLeft, mapR, mapG, mapB);
  325.         // shading
  326.         var smap:BitmapData = new BitmapData(w, h, false, 0);
  327.         smap.applyFilter(hmap, hmap.rect, hmap.rect.topLeft, new ConvolutionFilter(3,3,[-1,-1,0,-1,0,1,0,1,1],1,0,true,true));
  328.         texture.draw(smap, null, new ColorTransform(4, 4, 4, 1, 160, 160, 160, 0), "multiply");
  329.         
  330.         // copy 2x2
  331.         pt.x = w; pt.y = h; texture.copyPixels(texture, hmap.rect, pt);
  332.         pt.x = 0; pt.y = h; texture.copyPixels(texture, hmap.rect, pt);
  333.         pt.x = w; pt.y = 0; texture.copyPixels(texture, hmap.rect, pt);
  334.         pt.x = 0; pt.y = 0;
  335.     }
  336.     
  337.     private var pt:Point = new Point();
  338.     public function update() : void {
  339.         rect.x = (int(rect.x-_globalVel.x)) & (pixels.width-1);
  340.         rect.y = (int(rect.y-_globalVel.z)) & (pixels.height-1);
  341.         pixels.copyPixels(texture, rect, pt);
  342.     }
  343. }
  345. // Flyer
  346. //----------------------------------------------------------------------------------------------------
  347. class Flyer {
  348.     public var p:Vector3D, v:Vector3D, a:Vector3D, mdlFlyer:Model, mdlFire:Model;
  349.     private var _afterBurner:Boolean = false;
  350.     
  351.     function Flyer(x:Number, y:Number, z:Number) : void {
  352.         p = new Vector3D(x, y, z);
  353.         v = new Vector3D();
  354.         a = new Vector3D();
  355.         mdlFlyer = _models.mdlFlyer;
  356.         mdlFire  = _models.mdlFire;
  357.     }
  358.     
  359.     public function update() : void {
  360.         var inkey:int = _key.flag;
  361.         a.x = ((inkey & 1) - ((inkey & 4)>>2))*1.2;
  362.         a.y = (((inkey & 2)>>1) - ((inkey & 8)>>3))*0.8;
  363.         v.x = v.x * 0.8 - p.x*0.05;
  364.         v.y = v.y * 0.8 - p.y*0.05;
  365.         _afterBurner = Boolean(inkey & 32);
  366.         p.x += v.x + a.x * 0.5;
  367.         p.y += v.y + a.y * 0.5;
  368.         v.x += a.x;
  369.         v.y += a.y;
  370.     }
  371.     
  372.     public function render() : void {
  373.         _shape3d.pushMatrix()
  374.             .translate(p.x, p.y+10, p.z).rotateZ(v.x*6-_roll*0.5).rotateY(v.x*3).rotateX(v.y*-4)
  375.             .project(mdlFlyer).renderSolid(_light);
  376.         _screen.draw(_shape3d, _mat2d);
  377.         var scale:Number = (_afterBurner) ? 1.7 : 1.5,
  378.             length:Number = (_afterBurner) ? 1.5 : 1.0,
  379.             rand:Number;
  380.         for (var i:int=0; i<8; i++) {
  381.             rand = scale*(0.9+Math.random()*0.1);
  382.             _shape3d.pushMatrix()
  383.                 .translate(-4.8, -0.9, -18.1-i*length).scale(rand, rand, 1)
  384.                 .project(mdlFire).renderTexture(_models.texFire[i]);
  385.             _screen.draw(_shape3d, _mat2d, null, "add");
  386.             _shape3d.popMatrix().pushMatrix()
  387.                 .translate(4.8, -0.9, -18.1-i*length).scale(rand, rand, 1)
  388.                 .project(mdlFire).renderTexture(_models.texFire[i]);
  389.             _screen.draw(_shape3d, _mat2d, null, "add");
  390.             _shape3d.popMatrix();
  391.         }
  392.         _shape3d.popMatrix();
  393.     }
  394. }
  396. // MML Sequencer
  397. //   http://wonderfl.kayac.com/user/keim_at_Si
  398. //----------------------------------------------------------------------------------------------------
  399. class Sequencer {
  400.     private var _tracks:Array, _count:int=Track.speed+1;
  401.     function Sequencer(speed:int=2, mml:Array=null) {
  402.         this.speed = speed;
  403.         this.mml = mml;
  404.     }
  405.     public function onSoundFrame() : Boolean {
  406.         if (++_count == Track.speed) {
  407.             for each (var tr:Track in _tracks) tr.execute();
  408.             _count = 0;
  409.             return true;
  410.         }
  411.         return false;
  412.     }
  413.     public function set speed(spd:int) : void {
  414.         Track.speed = spd;
  415.         if (_count >= spd) _count=0;
  416.     }
  417.     public function set drSpeed(spd:int) : void {
  418.         if (spd<0 || spd>2) return;
  419.         Track.drs = spd;
  420.     }
  421.     public function set pos(p:int) : void {
  422.         for (var i:int=0; i<p; i++) {
  423.             for each (var tr:Track in _tracks) tr.execute();
  424.         }
  425.     }
  426.     public function set mml(list:Array) : void {
  427.         _tracks = [];
  428.         if (list) {
  429.             for each (var seq:String in list) _tracks.push(new Track(seq));
  430.         }
  431.         _count = 0;
  432.     }
  433. }
  435. class Track {
  436.     static public var codeA:int="a".charCodeAt(), nt:Array=[9,11,0,2,4,5,7], speed:int=3, drs:int=2;
  437.     public var oct:int, len:int, tl:int, dt:int, cnt:int, seq:String, sgn:int, stac:Array, osc:Osc;
  438.     private var _rex:RegExp=/(@i|@o|[a-gkloprsvw<>[|\]$@])([#+])?(-?\d+)?/g;
  439.     function Track(seq:String) {
  440.         osc = Osc.alloc().reset().activate(false);
  441.         reset(seq);
  442.     }
  443.     public function reset(seq_:String) : void {
  444.         seq=seq_; oct=5; len=4; tl=256; dt=0; cnt=0; sgn=0; _rex.lastIndex=0; stac=[];
  445.     }
  446.     public function execute() : void {
  447.         if (--cnt <= 0) {
  448.             for (var i:int=0; i<100; i++) {
  449.                 var res:* = _rex.exec(seq);
  450.                 if (!res) {
  451.                     if (sgn) { _rex.lastIndex = sgn; continue; }
  452.                     else     { cnt = int.MAX_VALUE; break; }
  453.                 }
  454.                 var cmd:int = res[1].charCodeAt();
  455.                 if (cmd>=codeA && cmd<=codeA+6) {
  456.                     cnt = (res[3]) ? int(res[3]) : len;
  457.                     osc.len = cnt * speed;
  458.                     osc.pt = ((nt[cmd-codeA]+oct*12+((res[2])?1:0))<<4) + dt;
  459.                     osc.tl = tl;
  460.                     break;
  461.                 } else if (res[1] == 'r') {
  462.                     cnt = (res[3]) ? int(res[3]) : len;
  463.                     break;
  464.                 } else {
  465.                     switch(res[1]){
  466.                     case 'k': dt  = int(res[3]); break;
  467.                     case 'l': len = int(res[3]); break;
  468.                     case 'o': oct = int(res[3]); break;
  469.                     case 'v': tl  = TinySiOPM.log(int(res[3])*0.0625); break;
  470.                     case '<': oct++; break;
  471.                     case '>': oct--; break;
  472.                     case '@':  osc.ws = int(res[3]);    break;
  473.                     case 's':  osc.dr = (int(res[3])<<drs)&~1; break;
  474.                     case 'w':  osc.sw = -(int(res[3])>>(2-drs));   break;
  475.                     case 'p':  osc.pan = (int(res[3])<<4)-64; break;
  476.                     case '@i': osc.mod = int(res[3]);   break;
  477.                     case '@o': osc.out = int(res[3]);   break;
  478.                     case '$': sgn = _rex.lastIndex; break;
  479.                     case '[': stac.unshift({p:_rex.lastIndex,c:((res[3])?int(res[3]):2),j:0}); break;
  480.                     case '|': if (stac[0].c == 1) { _rex.lastIndex = stac[0].j; stac.shift(); } break;
  481.                     case ']': 
  482.                         stac[0].j = _rex.lastIndex;
  483.                         if (--stac[0].c == 0) stac.shift();
  484.                         else _rex.lastIndex = stac[0].p;
  485.                         break;
  486.                     }
  487.                 }
  488.             }
  489.         }
  490.     }
  491. }
  493. class TinySiOPM {
  494.     private var _output:Vector.<Number>, _zero:Vector.<int>, _pipe:Vector.<int>;
  495.     private var _pitchTable:Vector.<int> = new Vector.<int>(2048, true);
  496.     private var _logTable:Vector.<int> = new Vector.<int>(6144, true);
  497.     private var _panTable:Vector.<Number> = new Vector.<Number>(129, true);
  498.     private var _bufferSize:int, _callbackFrams:int, _onSoundFrame:Function;
  499.     
  500.     // Pass the buffer size and the function calls in each frame.
  501.     function TinySiOPM(bufferSize:int=2048, callbackFrams:int=1024, onSoundFrame:Function=null) {
  502.         var i:int, j:int, p:Number, v:Number, t:Vector.<int>, ft:Array=[0,1,2,3,4,5,6,7,7,6,5,4,3,2,1,0];
  503.         for (i=0, p=0; i<192; i++, p+=0.00520833333)                            // create pitchTable[128*16]
  504.             for(v=Math.pow(2, p)*12441.464342886, j=i; j<2048; v*=2, j+=192) _pitchTable[j] = int(v);
  505.         for (i=0; i<32; i++) _pitchTable[i] = (i+1)<<6;                         // [0:31] for white noize
  506.         for (i=0, p=0.0078125; i<256; i+=2, p+=0.0078125)                       // create logTable[12*256*2]
  507.             for(v=Math.pow(2, 13-p), j=i; j<3328; v*=0.5, j+=256) _logTable[j+1] = -(_logTable[j]=int(v));
  508.         for (i=3328; i<6144; i++) _logTable[i] = 0;                             // [3328:6144] is 0-fill area
  509.         for (i=0, p=0; i<129; i++, p+=0.01217671571) _panTable[i]=Math.sin(p)*0.5;  // pan table;
  510.         for (t=Osc.createTable(10), i=0, p=0; i<1024; i++, p+=0.00613592315) t[i] = log(Math.sin(p)); // sin=0
  511.         for (t=Osc.createTable(10), i=0, p=0.75; i<1024; i++, p-=0.00146484375) t[i] = log(p);        // saw=1
  512.         for (t=Osc.createTable(5),  i=0; i<16; i++) t[i+16] = (t[i] = log(ft[i]*0.0625)) + 1;         // famtri=2
  513.         for (t=Osc.createTable(15), i=0; i<32768; i++) t[i] = log(Math.random()-0.5);                 // wnoize=3
  514.         for (i=0; i<8; i++) for (t=Osc.createTable(4), j=0; j<16; j++) t[j] = (j<=i) ? 192 : 193;     // pulse=4-11
  515.         _zero = new Vector.<int>(bufferSize, true);                             // allocate zero buffer
  516.         _pipe = new Vector.<int>(bufferSize, true);                             // allocate fm pipe buffer
  517.         _output = new Vector.<Number>(bufferSize*2, true);                      // allocate stereo out
  518.         _bufferSize = bufferSize;
  519.         _callbackFrams = callbackFrams; 
  520.         _onSoundFrame = onSoundFrame;                                           // set parameters
  521.         for (i=0; i<bufferSize; i++) { _pipe[i]=_zero[i]=0; }                   // clear buffers
  522.     }
  523.     
  524.     // calculate index of logTable
  525.     static public function log(n:Number) : int {
  526.         return (n<0) ? ((n<-0.00390625) ? (((int(Math.log(-n) * -184.66496523 + 0.5) + 1) << 1) + 1) : 2047)
  527.                      : ((n> 0.00390625) ? (( int(Math.log( n) * -184.66496523 + 0.5) + 1) << 1)      : 2046);
  528.     }
  530.     // reset all oscillators
  531.     public function reset() : void {
  532.         for (var o:Osc=Osc._tm.n; o!=Osc._tm; o=o.inactivate().n) { o.fl = Osc._fl; }
  533.     }
  535.     // Returns stereo output as Vector.<Number>(bufferSize*2).
  536.     public function render() : Vector.<Number> {
  537.         var i:int, j:int, ph:int, dph:int, mod:int, sh:int, tl:int, lout:int, v:int, imax:int, 
  538.             osc:Osc, tm:Osc, l:Number, r:Number, wv:Vector.<int>, fm:Vector.<int>, base:Vector.<int>, 
  539.             out:Vector.<int>=_pipe, lt:Vector.<int>=_logTable, stereoOut:Vector.<Number> = _output;
  540.         imax = _bufferSize<<1;
  541.         for (i=0; i<imax; i++) stereoOut[i] = 0;
  542.         for (imax=_callbackFrams; imax<=_bufferSize; imax+=_callbackFrams) {
  543.             if (_onSoundFrame!=null) _onSoundFrame();
  544.             tm = Osc._tm;
  545.             for (osc=tm.n; osc!=tm; osc=osc.update()) {
  546.                 dph=_pitchTable[osc.pt]; ph=osc.ph; mod=osc.mod+10; sh=osc.sh; tl=osc.tl; wv=osc.wv;
  547.                 fm=(osc.mod==0)?_zero:_pipe; base=(osc.out!=2)?_zero:_pipe;
  548.                 for (i = imax-_callbackFrams; i < imax; i++) {
  549.                     v = ((ph + (fm[i] << mod))& 0x3ffffff) >> sh;
  550.                     lout = wv[v] + tl;
  551.                     out[i] = lt[lout] + base[i];
  552.                     ph = (ph + dph) & 0x3ffffff;
  553.                 }
  554.                 osc.ph = ph;
  555.                 if (osc.out==0) {
  556.                     l = _panTable[64-osc.pan] * 0.0001220703125;
  557.                     r = _panTable[64+osc.pan] * 0.0001220703125;
  558.                     for (i=imax-_callbackFrams, j=i*2; i<imax; i++) {
  559.                         stereoOut[j] += out[i]*l; j++;
  560.                         stereoOut[j] += out[i]*r; j++;
  561.                     }
  562.                 }
  563.             }
  564.         }
  565.         return stereoOut;
  566.     }
  567.     
  568.     // note on
  569.     public function noteOn(pitch:int, length:int=0, vol:Number=0.5, wave:int=0, decay:int=6, sweep:int=0, pan:int=0) : Osc {
  570.         var osc:Osc = Osc.alloc().reset();
  571.         osc.pt = pitch;
  572.         osc.len = length;
  573.         osc.tl = log(vol);
  574.         osc.ws = wave;
  575.         osc.dr = decay<<2;
  576.         osc.sw = sweep; 
  577.         osc.pan = pan;
  578.         return osc.activate(true);
  579.     }
  580. }
  582. class Osc {
  583.     // create new wave table and you can refer the table by '@' command.
  584.     static public function createTable(b:int) : Vector.<int> {
  585.         _w.push(new Vector.<int>(1<<b,true)); _s.push(26-b);
  586.         return _w[_w.length-1];
  587.     }
  588.     static public var _w:Array=[], _s:Array=[], _fl:Osc=new Osc(), _tm:Osc=new Osc();
  589.     static public function alloc():Osc{ if(_fl.p==_fl)return new Osc();var r:Osc=_fl.p;_fl.p=r.p;r.p.n=_fl;return r; }
  590.     public function into(x:Osc):Osc{ p=x.p;n=x;p.n=this;n.p=this;return this; }
  591.     public var p:Osc, n:Osc, fl:Osc, pt:int, len:int, ph:int;
  592.     public var tl:int, sw:int, dr:int, wv:Vector.<int>, sh:int, mod:int, out:int, pan:int;
  593.     public function set ws(t:int) : void { wv=_w[t]; sh=_s[t]; }
  594.     public function Osc() { p = n = this; }
  595.     public function update() : Osc { tl+=dr; pt+=sw; pt&=2047; return (--len==0||tl>3328) ? (inactivate().n) : n; }
  596.     public function reset() : Osc { ph=0; pt=0; len=0; tl=3328; sw=0; dr=24; pan=0; ws=0; mod=0; out=0; return this; }
  597.     public function activate(autoFree:Boolean=false) : Osc { into(_tm); fl=(autoFree)?_fl:null; return this; }
  598.     public function inactivate() : Osc { tl=3328; if(!fl)return this; var r:Osc=p; p.n=n; n.p=p; into(fl); return r; }
  599.     public function isActive() : Boolean { return (tl<3328); }
  600. }
  602. // 3D Engine
  603. //   http://wonderfl.kayac.com/user/keim_at_Si
  604. //----------------------------------------------------------------------------------------------------
  605. /** 3D Shape */
  606. class Shape3D extends Shape {
  607.     /** model view matrix */
  608.     public var matrix:Matrix3D;
  609.     private var _modelProjected:Model = null;
  610.     private var _facesProjected:Vector.<Face> = new Vector.<Face>();
  611.     private var _vertexOnWorld:Vector.<Number> = new Vector.<Number>();
  612.     private var _vout:Vector.<Number> = new Vector.<Number>();
  613.     private var _projectionMatrix:Matrix3D;
  614.     private var _matrixStac:Vector.<Matrix3D> = new Vector.<Matrix3D>();
  615.     private var _cmdTriangle:Vector.<int> = Vector.<int>([1,2,2]);
  616.     private var _cmdQuadrangle:Vector.<int> = Vector.<int>([1,2,2,2]);
  617.     private var _data:Vector.<Number> = new Vector.<Number>(8, true);
  618.     
  619.     /** constructor */
  620.     function Shape3D(focus:Number=300) {
  621.         var projector:PerspectiveProjection = new PerspectiveProjection()
  622.         projector.focalLength = focus;
  623.         _projectionMatrix = projector.toMatrix3D();
  624.         matrix = new Matrix3D();
  625.         _matrixStac.length = 1;
  626.         _matrixStac[0] = matrix;
  627.     }
  628.     
  629.     /** push matrix */
  630.     public function pushMatrix() : Shape3D { _matrixStac.push(matrix.clone()); return this; }
  631.     
  632.     /** pop matrix */
  633.     public function popMatrix() : Shape3D { matrix = (_matrixStac.length == 1) ? matrix : _matrixStac.pop(); return this; }
  634.     
  635.     /** translate */
  636.     public function translate(x:Number, y:Number, z:Number) : Shape3D { matrix.prependTranslation(x, y, z); return this; }
  637.     
  638.     /** scale */
  639.     public function scale(x:Number, y:Number, z:Number) : Shape3D { matrix.prependScale(x, y, z); return this; }
  640.     
  641.     /** rotate */
  642.     public function rotate(angle:Number, axis:Vector3D) : Shape3D { matrix.prependRotation(angle, axis); return this; }
  643.     public function rotateX(angle:Number) : Shape3D { matrix.prependRotation(angle, Vector3D.X_AXIS); return this; }
  644.     public function rotateY(angle:Number) : Shape3D { matrix.prependRotation(angle, Vector3D.Y_AXIS); return this; }
  645.     public function rotateZ(angle:Number) : Shape3D { matrix.prependRotation(angle, Vector3D.Z_AXIS); return this; }
  646.     
  647.     /** project */
  648.     public function project(model:Model) : Shape3D {
  649.         var i0x3:int, i1x3:int, i2x3:int, x01:Number, x02:Number, y01:Number, y02:Number, z01:Number, z02:Number,
  650.             viewx:Number, viewy:Number, viewz:Number;
  651.         matrix.transformVectors(model.vertices, _vertexOnWorld);
  652.         _facesProjected.length = 0;
  653.         var vertices:Vector.<Number> = _vertexOnWorld;
  654.         for each (var face:Face in model.faces) {
  655.             i0x3 = (face.i0<<1) + face.i0;
  656.             i1x3 = (face.i1<<1) + face.i1;
  657.             i2x3 = (face.i2<<1) + face.i2;
  658.             face.x = (vertices[i0x3] + vertices[i1x3] + vertices[i2x3]) * 0.333333333333;
  659.             x01 = vertices[i1x3] - vertices[i0x3];
  660.             x02 = vertices[i2x3] - vertices[i0x3];
  661.             i0x3++; i1x3++; i2x3++;
  662.             face.y = (vertices[i0x3] + vertices[i1x3] + vertices[i2x3]) * 0.333333333333;
  663.             y01 = vertices[i1x3] - vertices[i0x3];
  664.             y02 = vertices[i2x3] - vertices[i0x3];
  665.             i0x3++; i1x3++; i2x3++;
  666.             face.z = (vertices[i0x3] + vertices[i1x3] + vertices[i2x3]) * 0.333333333333;
  667.             z01 = vertices[i1x3] - vertices[i0x3];
  668.             z02 = vertices[i2x3] - vertices[i0x3];
  669.             face.normal.z = x02*y01 - x01*y02;
  670.             face.normal.x = y02*z01 - y01*z02;
  671.             face.normal.y = z02*x01 - z01*x02;
  672.             if (face.x * face.normal.x + face.y * face.normal.y + face.z * face.normal.z <= 0) {
  673.                 face.normal.normalize();
  674.                 _facesProjected.push(face);
  675.             }
  676.         }
  677.         _facesProjected.sort(function(f1:Face, f2:Face) : Number { return f2.z - f1.z; });
  678.         _modelProjected = model;
  679.         return this;
  680.     }
  682.     /** render solid */
  683.     public function renderSolid(light:Light) : Shape3D {
  684.         var idx:int, mat:Material, materials:Vector.<Material> = _modelProjected.materials;
  685.         Utils3D.projectVectors(_projectionMatrix, _vertexOnWorld, _vout, _modelProjected.texCoord);
  686.         graphics.clear();
  687.         for each (var face:Face in _facesProjected) {
  688.             mat = materials[face.mat];
  689.             graphics.beginFill(mat.getColor(light, face.normal), mat.alpha);
  690.             idx = face.i0<<1;
  691.             _data[0] = _vout[idx]; idx++;
  692.             _data[1] = _vout[idx]; 
  693.             idx = face.i1<<1;
  694.             _data[2] = _vout[idx]; idx++;
  695.             _data[3] = _vout[idx]; 
  696.             idx = face.i2<<1;
  697.             _data[4] = _vout[idx]; idx++;
  698.             _data[5] = _vout[idx]; 
  699.             graphics.drawPath(_cmdTriangle, _data);
  700.             graphics.endFill();
  701.         }
  702.         return this;
  703.     }
  704.     
  705.     /** render with texture */
  706.     public function renderTexture(texture:BitmapData) : Shape3D {
  707.         var idx:int, mat:Material;
  708.         Utils3D.projectVectors(_projectionMatrix, _vertexOnWorld, _vout, _modelProjected.texCoord);
  709.         graphics.clear();
  710.         graphics.beginBitmapFill(texture, null, false, true);
  711.         graphics.drawTriangles(_vout, _modelProjected.indices, _modelProjected.texCoord);
  712.         graphics.endFill();
  713.         return this;
  714.     }
  715. }
  717. /** Face */
  718. class Face {
  719.     public var i0:int, i1:int, i2:int, i3:int, mat:int, x:Number, y:Number, z:Number, normal:Vector3D = new Vector3D();
  720.     static private var _freeList:Vector.<Face> = new Vector.<Face>();
  721.     static public function alloc() : Face { return _freeList.pop() || new Face(); }
  722.     static public function free(face:Face) : void { _freeList.push(face); }
  723. }
  725. /** Model */
  726. class Model {
  727.     public var materials:Vector.<Material>;                 // material list
  728.     public var vertices:Vector.<Number>;                    // vertex
  729.     public var texCoord:Vector.<Number>;                    // texture coordinate
  730.     public var faces:Vector.<Face> = new Vector.<Face>();   // face list
  731.     private var _indices:Vector.<int> = new Vector.<int>(); // temporary index list
  732.     
  733.     /** indices as Vector.<int> */
  734.     public function get indices() : Vector.<int> {
  735.         _indices.length = 0;
  736.         for each (var face:Face in faces) { _indices.push(face.i0, face.i1, face.i2); }
  737.         return _indices;
  738.     }
  740.     /** constructor */
  741.     function Model(vertices:Vector.<Number>=null, texCoord:Vector.<Number>=null, materials:Vector.<Material>=null) {
  742.         this.vertices = vertices || new Vector.<Number>();
  743.         this.texCoord = texCoord || new Vector.<Number>();
  744.         this.materials = materials || Vector.<Material>([new Material()]);
  745.     }
  746.     
  747.     /** clear */
  748.     public function clear() : Model {
  749.         for each (var face:Face in faces) Face.free(face);
  750.         faces.length = 0;
  751.         return this;
  752.     }
  753.     
  754.     /** register face */
  755.     public function face(i0:int, i1:int, i2:int, mat:int=0) : Model {
  756.         var face:Face = Face.alloc();
  757.         face.i0 = i0;
  758.         face.i1 = i1;
  759.         face.i2 = i2;
  760.         face.mat = mat;
  761.         faces.push(face);
  762.         return this;
  763.     }
  764. }
  766. /** Light */
  767. class Light {
  768.     private var _direction:Vector3D = new Vector3D();
  769.     private var _halfVector:Vector3D = new Vector3D();
  770.     public function get direction()  : Vector3D { return _direction; }
  771.     public function get halfVector() : Vector3D { return _halfVector; }
  772.     
  773.     /** constructor (set position) */
  774.     function Light(x:Number=1, y:Number=1, z:Number=1) { setPosition(x, y, z); }
  775.     
  776.     /** set position */
  777.     public function setPosition(x:Number, y:Number, z:Number) : void {
  778.         _direction.x = x;
  779.         _direction.y = y;
  780.         _direction.z = z; 
  781.         _direction.normalize();
  782.         _halfVector.x = _direction.x;
  783.         _halfVector.y = _direction.y;
  784.         _halfVector.z = _direction.z + 1; 
  785.         _halfVector.normalize();
  786.     }
  787. }
  789. /** Material */
  790. class Material {
  791.     public var colorTable:BitmapData = new BitmapData(256,256,false);
  792.     public var alpha:Number = 1;
  793.     private var _nega_filter:int = 0;
  794.     
  795.     /** constructor */
  796.     function Material(color:uint=0xc0c0c0, alpha:Number=1.0) { setColor(color, alpha); }
  797.     
  798.     /** set color. */
  799.     public function setColor(color:uint, alpha:Number= 1.0, 
  800.                              amb:int=64, dif:int=192, spc:int=0,  pow:Number=8, 
  801.                              emi:int=0,  doubleSided:Boolean=false) : Material 
  802.     {
  803.         var i:int, r:int, c:int, rc:Rectangle;
  804.         var lightTable:BitmapData = new BitmapData(256, 256, false);
  805.         
  806.         // color/alpha
  807.         colorTable.fillRect(colorTable.rect, color);
  808.         this.alpha = alpha;
  810.         // ambient/diffusion/emittance
  811.         var ea:Number = (256-emi)*0.00390625, eb:Number = emi*0.5;
  812.         r = dif - amb;
  813.         rc = new Rectangle(0, 0, 1, 256);
  814.         for (i=0; i<256; ++i) {
  815.             rc.x = i;
  816.             lightTable.fillRect(rc, (((i*r)>>8)+amb)*0x10101);
  817.         }
  818.         colorTable.draw(lightTable, null, new ColorTransform(ea,ea,ea,1,eb,eb,eb,0), BlendMode.HARDLIGHT);
  819.         
  820.         // specular/power
  821.         if (spc > 0) {
  822.             rc = new Rectangle(0, 0, 256, 1);
  823.             for (i=0; i<256; ++i) {
  824.                 rc.y = i;
  825.                 c = int(Math.pow(i*0.0039215686, pow)*spc);
  826.                 lightTable.fillRect(rc, ((c<255)?c:255)*0x10101);
  827.             }
  828.             colorTable.draw(lightTable, null, null, BlendMode.ADD);
  829.         }
  831.         // double side
  832.         _nega_filter = (doubleSided) ? -1 : 0;
  833.         
  834.         lightTable.dispose();
  836.         return this;
  837.     }
  838.     
  839.     /** calculate color by light and normal vector. */
  840.     public function getColor(light:Light, normal:Vector3D) : uint {
  841.         var dir:Vector3D = light.direction, hv:Vector3D = light.halfVector;
  842.         var ln:int = int((dir.x * normal.x + dir.y * normal.y + dir.z * normal.z)*255),
  843.             hn:int = int((hv.x  * normal.x + hv.y  * normal.y + hv.z  * normal.z)*255);
  844.         if (ln<0) ln = (-ln) & _nega_filter;
  845.         if (hn<0) hn = (-hn) & _nega_filter;
  846.         return colorTable.getPixel(ln, hn);
  847.     }
  848. }
noswf
Get Adobe Flash Player