notice: Flash editor updated! Join the development! Thanks to MiniBuilder


forked from : muta244's [最適化 Tips] Array, Vector 走査時に加算を行う際の処理速度の違い [diff(74)]

embed

noswf download fullscreen
flash swf thumbnail play
download fullscreen
FORKED
>sort

[最適化 Tips] 変数を参照する際の処理速度の違い [最適化 Tips] サイン・コサインの取得方法による処理速度の違い [diff(78)]

  1. package {
  3. import flash.display.*;
  4. import flash.geom.*;
  5. import flash.events.*;
  6. import flash.text.*;
  7. import flash.utils.*;
  9. public class Main extends Sprite
  10. {
  11.     static private const _NUM_TIMES:int = 1000000;
  12.     static private const _DEGREES:Number = 30;
  13.     
  14.     static private const _TABLE_SIZE:int = 0x10000;
  15.     static private const _PI:Number = Math.PI;
  16.     static private const _RADIANS:Number = _DEGREES * (_PI / 180);
  17.     static private const _TWO_PI:Number = 2 * _PI;
  18.     static private const _TWO_PI_SCALE:Number = _TABLE_SIZE / _TWO_PI;
  19.     static private const _HALF_PI:Number = _PI / 2;
  20.     
  21.     private var _table:Vector.<Number> = new function ():Vector.<Number>
  22.     {
  23.         var table:Vector.<Number> = new Vector.<Number>(_TABLE_SIZE, true);
  24.         
  25.         for (var i:uint = 0; i < _TABLE_SIZE; i++) {
  26.             table[i] = Math.sin(i / _TWO_PI_SCALE);
  27.         }
  28.         
  29.         return table;
  30.     };
  31.     
  32.     private function _init():void
  33.     {
  34.         _debug(
  35.             "各テスト " + _NUM_TIMES + " 回処理させた計算結果 [単位 ： ミリ秒]\n" +
  36.             "(誤差は多少生じます)\n"
  37.         );
  38.         
  39.         _debug("最初に計算の正当性を確認 (テーブルは " + _TABLE_SIZE + " 分割)\n");
  40.         _debug(_DEGREES + " 度の sin を Math.sin() で計算 -> " + Math.sin(_RADIANS));
  41.         _debug(_DEGREES + " 度の sin をテーブルから近似値を取得 -> " + _sin(_RADIANS));
  42.         _debug(_DEGREES + " 度の cos を Math.cos() で計算 -> " + Math.cos(_RADIANS));
  43.         _debug(_DEGREES + " 度の cos をテーブルから近似値を取得 -> " + _cos(_RADIANS) + "\n");
  44.         
  45.         _measure("ループのみ", function ():void
  46.         {
  47.             for (var i:uint = 0; i < _NUM_TIMES; i++) {
  48.                 
  49.             }
  50.         });
  51.         
  52.         _measure("Math.sin() で計算", function ():void
  53.         {
  54.             for (var i:uint = 0; i < _NUM_TIMES; i++) {
  55.                 Math.sin(_RADIANS);
  56.             }
  57.         });
  58.         
  59.         _measure("Math.cos() で計算", function ():void
  60.         {
  61.             for (var i:uint = 0; i < _NUM_TIMES; i++) {
  62.                 Math.cos(_RADIANS);
  63.             }
  64.         });
  65.         
  66.         _measure("関数を通したテーブルから sin の近似値を取得", function ():void
  67.         {
  68.             for (var i:uint = 0; i < _NUM_TIMES; i++) {
  69.                 _sin(_RADIANS);
  70.             }
  71.         });
  72.         
  73.         _measure("関数を通したテーブルから cos の近似値を取得", function ():void
  74.         {
  75.             for (var i:uint = 0; i < _NUM_TIMES; i++) {
  76.                 _cos(_RADIANS);
  77.             }
  78.         });
  79.         
  80.         _measure("テーブルから sin の近似値を直接取得", function ():void
  81.         {
  82.             for (var i:uint = 0; i < _NUM_TIMES; i++) {
  83.                 _table[(_RADIANS * _TWO_PI_SCALE) & (_TABLE_SIZE - 1)];
  84.             }
  85.         });
  86.         
  87.         _measure("テーブルから cos の近似値を直接取得", function ():void
  88.         {
  89.             for (var i:uint = 0; i < _NUM_TIMES; i++) {
  90.                 _table[((_RADIANS + _HALF_PI) * _TWO_PI_SCALE) & (_TABLE_SIZE - 1)];
  91.             }
  92.         });
  93.         
  94.         _debug("\n結果については言及しませんので, 各自ご判断ください.");
  95.     }
  96.     
  97.     private function _sin(radians:Number):Number
  98.     {
  99.         return _table[(radians * _TWO_PI_SCALE) & (_TABLE_SIZE - 1)];
  100.     }
  101.     
  102.     private function _cos(radians:Number):Number
  103.     {
  104.         return _table[((radians + _HALF_PI) * _TWO_PI_SCALE) & (_TABLE_SIZE - 1)];
  105.     }
  106.     
  107.     private var _field:TextField;
  108.     private var _time:uint;
  109.     
  110.     public function Main():void
  111.     {
  112.         _setup();
  113.         _init();
  114.     }
  115.     
  116.     private function _measure(title:String, func:Function, ...params):void
  117.     {
  118.         _time = getTimer();
  119.         func.apply(null, params);
  120.         _time = getTimer() - _time;
  121.         
  122.         _debug("[ " + title + " ] --> " + _time + " ms");
  123.     }
  124.     
  125.     private function _debug(log:String):void
  126.     {
  127.         _field.appendText(log + "\n");
  128.     }
  129.     
  130.     private function _setup():void
  131.     {
  132.         _field = new TextField();
  133.         _field.width = stage.stageWidth - 40;
  134.         _field.height = stage.stageHeight - 60;
  135.         _field.x = 20;
  136.         _field.y = 60;
  137.         _field.multiline = true;
  138.         _field.wordWrap = true;
  139.         
  140.         var format:TextFormat = _field.defaultTextFormat;
  141.         format.font = "_sans";
  142.         _field.defaultTextFormat = format;
  143.         
  144.         addChild(_field);
  145.         
  146.         var button:Sprite = new Sprite();
  147.         button.graphics.lineStyle(1, 0xBBBBBB);
  148.         button.graphics.beginFill(0xEEEEEE);
  149.         button.graphics.drawRoundRect(0, 0, 100, 20, 5, 5);
  150.         button.graphics.endFill();
  151.         
  152.         addChild(button);
  153.         
  154.         button.x = 20;
  155.         button.y = 20;
  156.         button.mouseChildren = false;
  157.         button.buttonMode = true;
  158.         
  159.         var field:TextField = new TextField();
  160.         field.width = 100;
  161.         field.height = 20;
  162.         field.htmlText = "<p align='center'><font face='_sans'>再計算</span></p>";
  163.         
  164.         button.addChild(field);
  165.         
  166.         button.addEventListener(MouseEvent.CLICK, function ():void
  167.         {
  168.             _field.text = "";
  169.             _init();
  170.         });
  171.     }
  172. }
  174. }
noswf
Get Adobe Flash Player