※現在、「wonderfl build flash online」求人コンテンツ制作に関してのアンケートを実施中です！みなさまのお力添えを頂いて、続々とアンケート結果が集まっていますが、まだまだ募集しております。ご協力のほど、どうぞよろしくお願いいたします！

wonderfl運営事務局
→アンケートページ（※ログインしてからお答えいただけるようになっています。）

 notice: Flash editor updated! Join the development! Thanks to MiniBuilder


embed

noswf download fullscreen
flash swf thumbnail play
reload download fullscreen

FORKED
>sort

Happy Birthday ;) forked from: Happy Birthday ;) [diff(1)]

  1. // forked from soundkitchen's Happy Birthday ;)
  2. /**
  3.  *  Spark 勉強会の Geoff Stearns 氏のハッピーバースデー企画
  4.  *  お誕生日おめでとーございまーす :-)
  5.  *
  6.  *  @see http://wiki.libspark.org/wiki/SparkStudy/09
  7.  */
  8. package
  9. {
  10.     import flash.display.Sprite;
  11.     import flash.display.StageAlign;
  12.     import flash.display.StageQuality;
  13.     import flash.display.StageScaleMode;
  14.     import flash.events.Event;
  16.     import com.flashdynamix.utils.SWFProfiler;
  17.     import org.libspark.thread.Thread;
  18.     import org.libspark.thread.EnterFrameThreadExecutor;
  19.     import org.papervision3d.cameras.Camera3D;
  20.     import org.papervision3d.objects.DisplayObject3D;
  21.     import org.papervision3d.render.LazyRenderEngine;
  22.     import org.papervision3d.scenes.Scene3D;
  23.     import org.papervision3d.view.Viewport3D;
  25.     [SWF(width=465, height=465, frameRate=60, backgroundColor=0x000000)]
  27.     /**
  28.      *  document class.
  29.      */
  30.     public class CodeBreak extends Sprite
  31.     {
  32.         /**
  33.          *  constructor.
  34.          */
  35.         public function CodeBreak()
  36.         {
  37.             addEventListener(Event.ADDED_TO_STAGE, initialize);
  38.         }
  40.         /**
  41.          *  initialize the object.
  42.          */
  43.         private function initialize(evt:Event):void
  44.         {
  45.             removeEventListener(Event.ADDED_TO_STAGE, initialize);
  47.             if (!Thread.isReady)
  48.             {
  49.                 stage.align = StageAlign.TOP_LEFT;
  50.                 stage.quality = StageQuality.HIGH;
  51.                 stage.scaleMode = StageScaleMode.NO_SCALE;
  53.                 SWFProfiler.init(this);
  55.                 Thread.initialize(new EnterFrameThreadExecutor());
  56.             }
  58.             var ctx:Context,
  59.                 camera:Camera3D,
  60.                 scene:Scene3D,
  61.                 viewport:Viewport3D,
  62.                 container:DisplayObject3D,
  63.                 renderer:LazyRenderEngine;
  65.             //  camera.
  66.             camera = new Camera3D();
  67.             camera.z = 1000;
  68.             //camera.focus = 20;
  69.             //camera.zoom = 40;
  70.             camera.lookAt(DisplayObject3D.ZERO);
  71.             //  scene.
  72.             scene = new Scene3D();
  73.             //  container.
  74.             container = new DisplayObject3D();
  75.             scene.addChild(container);
  76.             //  viewport.
  77.             viewport = new Viewport3D(stage.stageWidth, stage.stageHeight, true);
  78.             addChild(viewport);
  79.             //  render engine.
  80.             renderer = new LazyRenderEngine(scene, camera, viewport);
  82.             //  context.
  83.             ctx = new Context();
  84.             ctx.layer = this;
  85.             ctx.stage = stage;
  86.             ctx.camera = camera;
  87.             ctx.scene = scene;
  88.             ctx.container = container;
  89.             ctx.viewport = viewport;
  90.             ctx.renderer = renderer;
  92.             new MainThread(ctx).start();
  93.         }
  94.     }
  95. }
  97. import flash.display.Bitmap;
  98. import flash.display.BitmapData;
  99. import flash.display.BlendMode;
  100. import flash.display.DisplayObject;
  101. import flash.display.DisplayObjectContainer;
  102. import flash.display.Stage;
  103. import flash.display.StageDisplayState;
  104. import flash.events.Event;
  105. import flash.events.MouseEvent;
  106. import flash.filters.GlowFilter;
  107. import flash.net.URLRequest;
  108. import flash.text.TextField;
  109. import flash.text.TextFieldAutoSize;
  110. import flash.text.TextFormat;
  112. import frocessing.color.ColorHSV;
  113. import org.libspark.betweenas3.BetweenAS3;
  114. import org.libspark.betweenas3.tweens.ITween;
  115. import org.libspark.betweenas3.targets.single.ISingleTweenTarget;
  116. import org.libspark.betweenas3.easing.*;
  117. import org.libspark.betweenas3.events.BetweenEvent;
  118. import org.libspark.thread.Monitor;
  119. import org.libspark.thread.Thread;
  120. import org.libspark.thread.threads.net.URLLoaderThread;
  121. import org.papervision3d.cameras.Camera3D;
  122. import org.papervision3d.core.math.Matrix3D;
  123. import org.papervision3d.core.math.Number3D;
  124. import org.papervision3d.materials.special.Letter3DMaterial;
  125. import org.papervision3d.objects.DisplayObject3D;
  126. import org.papervision3d.render.LazyRenderEngine;
  127. import org.papervision3d.scenes.Scene3D;
  128. import org.papervision3d.typography.Font3D;
  129. import org.papervision3d.typography.Text3D;
  130. import org.papervision3d.typography.fonts.HelveticaBold;
  131. import org.papervision3d.view.Viewport3D;
  133. internal const SOURCE_URL:String = "http://ajax.googleapis.com/ajax/libs/swfobject/2.1/swfobject_src.js";
  134. internal const TARGET_WORDS:String = "Happy Birthday ;)";
  136. /**
  137.  *  context object.
  138.  */
  139. internal class Context
  140. {
  141.     /**
  142.      *  reference of document class object.
  143.      */
  144.     public var layer:DisplayObjectContainer;
  146.     /**
  147.      *  reference of stage object.
  148.      */
  149.     public var stage:Stage;
  151.     /**
  152.      *  reference of pv3d camera object.
  153.      */
  154.     public var camera:Camera3D;
  156.     /**
  157.      *  reference of pv3d container object.
  158.      */
  159.     public var container:DisplayObject3D;
  161.     /**
  162.      *  reference of pv3d scene object.
  163.      */
  164.     public var scene:Scene3D;
  166.     /**
  167.      *  reference of pv3d renderer object.
  168.      */
  169.     public var renderer:LazyRenderEngine;
  171.     /**
  172.      *  reference of pv3d viewport object.
  173.      */
  174.     public var viewport:Viewport3D;
  175. }
  177. /**
  178.  *  main task of this applicaiton.
  179.  */
  180. internal class MainThread extends Thread
  181. {
  182.     private var context:Context;
  183.     private var loader:URLLoaderThread;
  185.     /**
  186.      *  constructor.
  187.      */
  188.     public function MainThread(context:Context)
  189.     {
  190.         this.context = context;
  191.     }
  193.     /**
  194.      *  first executable.
  195.      */
  196.     override protected function run():void
  197.     {
  198.         var t:Thread;
  200.         t = new WaitAnimationThread(context);
  201.         t.start();
  202.         t.join();
  204.         new HandleScreenThread(context).start();
  206.         next(startAnimation);
  207.     }
  209.     private function startAnimation():void
  210.     {
  211.         var req:URLRequest;
  213.         req = new URLRequest(SOURCE_URL);
  215.         loader = new URLLoaderThread(req);
  216.         loader.start();
  217.         loader.join();
  219.         next(loadComplete);
  220.         error(Error, loadFailure);
  221.     }
  223.     private function loadComplete():void
  224.     {
  225.         var data:String;
  226.         
  227.         data = String(loader.loader.data);
  229.         new PV3DRenderThread(context).start();
  230.         new MainAnimationThread(context, data).start();
  231.     }
  233.     private function loadFailure(e:Error, t:Thread):void
  234.     {
  235.         trace(e.getStackTrace());
  236.     }
  238.     /**
  239.      *  finalize the object.
  240.      */
  241.     override protected function finalize():void
  242.     {
  243.         context = null;
  244.     }
  245. }
  247. /**
  248.  *  wait user's action.
  249.  */
  250. internal class WaitAnimationThread extends Thread
  251. {
  252.     private var context:Context;
  253.     private var message:Bitmap;
  255.     /**
  256.      *  constructor.
  257.      */
  258.     public function WaitAnimationThread(context:Context)
  259.     {
  260.         this.context = context;
  261.     }
  263.     /**
  264.      *  first executable.
  265.      */
  266.     override protected function run():void
  267.     {
  268.         var txt:TextField,
  269.             fmt:TextFormat,
  270.             bmd:BitmapData;
  272.         fmt = new TextFormat();
  273.         fmt.font = 'Lucida Grande';
  274.         fmt.size = 64;
  275.         fmt.color = 0x000000;
  277.         txt = new TextField();
  278.         txt.autoSize = TextFieldAutoSize.LEFT;
  279.         txt.defaultTextFormat = fmt;
  280.         txt.text = "click to start";
  282.         bmd = new BitmapData(txt.width, txt.height, true, 0);
  283.         bmd.draw(txt);
  284.         message = new Bitmap(bmd);
  285.         message.x = (context.stage.stageWidth - message.width) >> 1;
  286.         message.y = (context.stage.stageHeight - message.height) >> 1;
  287.         message.blendMode = BlendMode.INVERT;
  289.         context.layer.addChild(message);
  291.         event(context.stage, MouseEvent.CLICK, clicked);
  292.         event(context.stage, Event.RESIZE, resized);
  293.     }
  295.     /**
  296.      *  will execute when clicked stage.
  297.      */
  298.     private function clicked(evt:MouseEvent):void
  299.     {
  300.         message.x = (context.stage.stageWidth - message.width) >> 1;
  301.         message.y = (context.stage.stageHeight - message.height) >> 1;
  303.         new HideMessageThread(message).start();
  304.     }
  306.     /**
  307.      *  will execute when resized stage size.
  308.      */
  309.     private function resized(evt:Event):void
  310.     {
  311.         message.x = (context.stage.stageWidth - message.width) >> 1;
  312.         message.y = (context.stage.stageHeight - message.height) >> 1;
  314.         event(context.stage, MouseEvent.CLICK, clicked);
  315.         event(context.stage, Event.RESIZE, resized);
  316.     }
  318.     /**
  319.      *  finalize the object.
  320.      */
  321.     override protected function finalize():void
  322.     {
  323.         message = null;
  324.         context = null;
  325.     }
  326. }
  328. /**
  329.  *  hide splash message.
  330.  */
  331. internal class HideMessageThread extends Thread
  332. {
  333.     private var message:DisplayObject;
  334.     private var monitor:Monitor;
  336.     /**
  337.      *  constructor.
  338.      */
  339.     public function HideMessageThread(message:DisplayObject)
  340.     {
  341.         this.message = message;
  342.         this.monitor = new Monitor();
  343.     }
  345.     /**
  346.      *  first executable.
  347.      */
  348.     override protected function run():void
  349.     {
  350.         var b:ITween,
  351.             from:Object,
  352.             to:Object;
  354.         to = {
  355.             'alpha': 0,
  356.             //'y': message.stage.stageHeight,
  357.             '_blurFilter': {
  358.                 'blurX': 128,
  359.                 'blurY': 128
  360.             }
  361.         };
  362.         b = BetweenAS3.tween(message, to, from, 2, Quadratic.easeIn);
  363.         b.onComplete = monitor.notifyAll;
  364.         b.play();
  366.         monitor.wait();
  367.     }
  369.     /**
  370.      *  finalize the object.
  371.      */
  372.     override protected function finalize():void
  373.     {
  374.         message.parent.removeChild(message);
  375.         message = null;
  376.         monitor = null;
  377.     }
  378. }
  380. /**
  381.  *  handle full screen.
  382.  */
  383. internal class HandleScreenThread extends Thread
  384. {
  385.     private var context:Context;
  387.     /**
  388.      *  constructor.
  389.      */
  390.     public function HandleScreenThread(context:Context)
  391.     {
  392.         this.context = context;
  393.     }
  395.     /**
  396.      *  first executable.
  397.      */
  398.     override protected function run():void
  399.     {
  400.         event(context.stage, MouseEvent.CLICK, toggleDisplayState, false, int.MAX_VALUE);
  401.     }
  403.     /**
  404.      *  toggle full screen and normal.
  405.      */
  406.     private function toggleDisplayState(evt:MouseEvent):void
  407.     {
  408.         var s:Stage;
  410.         s = context.stage;
  412.         s.displayState = s.displayState == StageDisplayState.NORMAL
  413.                        ? StageDisplayState.FULL_SCREEN
  414.                        : StageDisplayState.NORMAL;
  416.         event(s, MouseEvent.CLICK, toggleDisplayState, false, int.MAX_VALUE);
  417.     }
  419.     /**
  420.      *  finalize the object.
  421.      */
  422.     override protected function finalize():void
  423.     {
  424.         context = null;
  425.     }
  426. }
  428. /**
  429.  *  main animation.
  430.  */
  431. internal class MainAnimationThread extends Thread
  432. {
  433.     private var context:Context;
  434.     private var monitor:Monitor;
  435.     private var data:String;
  436.     private var hsv:ColorHSV;
  437.     private var dataIndex:uint;
  438.     private var targetIndex:uint;
  440.     /**
  441.      *  constructor.
  442.      */
  443.     public function MainAnimationThread(context:Context, data:String)
  444.     {
  445.         this.context = context;
  446.         this.data = data.replace(/\r+|\n+|\s+/g, ' ');
  447.         hsv = new ColorHSV(0, 1, 1, 1);
  448.         dataIndex = 0;
  449.         targetIndex = 0;
  450.         monitor = new Monitor();
  451.     }
  453.     /**
  454.      *  first executable.
  455.      */
  456.     override protected function run():void
  457.     {
  458.         if (targetIndex >= TARGET_WORDS.length)
  459.         {
  460.             showFullMessage();
  461.         }
  462.         else if (dataIndex >= data.length)
  463.         {
  464.             //  todo: logic implement.
  465.         }
  466.         else
  467.         {
  468.             var t:String,
  469.                 c:String;
  471.             t = TARGET_WORDS.charAt(targetIndex);
  472.             c = data.charAt(dataIndex);
  473.             if (t == c)
  474.             {
  475.                 addTargetCharacter(t);
  476.             }
  477.             else
  478.             {
  479.                 addDefaultCharacter(c);
  480.             }
  481.             next(run);
  482.         }
  483.     }
  485.     /**
  486.      *  add target character.
  487.      */
  488.     private function addTargetCharacter(str:String):void
  489.     {
  490.         var b:ITween,
  491.             mat:Letter3DMaterial,
  492.             fnt:Font3D,
  493.             txt:Text3D,
  494.             rot:Number3D;
  496.         targetIndex++;
  497.         dataIndex++;
  499.         rot = Matrix3D.matrix2euler(context.camera.transform);
  500.         fnt = new HelveticaBold();
  501.         mat = new Letter3DMaterial(0xffffff);
  503.         try
  504.         {
  505.             txt = new Text3D(str, fnt, mat);
  506.         }
  507.         catch (e:Error)
  508.         {
  509.             return;
  510.         }
  511.         txt.z = 950;
  512.         txt.rotationX = rot.x;
  513.         txt.rotationY = rot.y;
  514.         txt.rotationZ = rot.z;
  515.         txt.filters = [
  516.             new GlowFilter(0xffffff, 1, 8, 8)
  517.         ];
  518.         txt.useOwnContainer = true;
  520.         context.container.addChild(txt);
  522.         b = BetweenAS3.tween(txt, {
  523.             'z': 0,
  524.             'alpha': 0,
  525.             'rotationX': 360 * Math.random(),
  526.             'rotationY': 360 * Math.random(),
  527.             'rotationZ': 360 * Math.random()
  528.         }, null, 1, Expo.easeIn);
  529.         b.addEventListener(BetweenEvent.COMPLETE, completeHandler);
  530.         if (targetIndex >= TARGET_WORDS.length)
  531.         {
  532.             b.onComplete = monitor.notifyAll;
  533.             monitor.wait();
  534.         }
  535.         else
  536.         {
  537.             sleep(200);
  538.         }
  539.         b.play();
  540.     }
  542.     /**
  543.      *  add character.
  544.      */
  545.     private function addDefaultCharacter(str:String):void
  546.     {
  547.         var b:ITween,
  548.             to:Object, from:Object,
  549.             mat:Letter3DMaterial,
  550.             fnt:Font3D,
  551.             txt:Text3D,
  552.             rot:Number3D;
  554.         dataIndex++;
  556.         hsv.h += 5;
  557.         rot = Matrix3D.matrix2euler(context.camera.transform);
  558.         fnt = new HelveticaBold();
  559.         mat = new Letter3DMaterial(hsv.value, .25);
  561.         try
  562.         {
  563.             txt = new Text3D(str, fnt, mat);
  564.         }
  565.         catch (e:Error)
  566.         {
  567.             return;
  568.         }
  569.         txt.z = 950;
  570.         txt.rotationX = rot.x;
  571.         txt.rotationY = rot.y;
  572.         txt.rotationZ = rot.z;
  573.         txt.filters = [
  574.             new GlowFilter(0xffffff, 1, 8, 8)
  575.         ];
  576.         txt.useOwnContainer = true;
  578.         context.container.addChild(txt);
  580.         b = BetweenAS3.tween(txt, {
  581.             'z': 0,
  582.             'alpha': 0,
  583.             'rotationX': 360 * Math.random(),
  584.             'rotationY': 360 * Math.random(),
  585.             'rotationZ': 360 * Math.random()
  586.         }, null, .75, Quadratic.easeIn);
  587.         b.addEventListener(BetweenEvent.COMPLETE, completeHandler);
  588.         if (dataIndex >= data.length)
  589.         {
  590.             b.onComplete = monitor.notifyAll;
  591.             monitor.wait();
  592.         }
  593.         else
  594.         {
  595.             sleep(50);
  596.         }
  597.         b.play();
  598.     }
  600.     /**
  601.      *  show complete message.
  602.      */
  603.     private function showFullMessage():void
  604.     {
  605.         var b:ITween,
  606.             mat:Letter3DMaterial,
  607.             fnt:Font3D,
  608.             txt:Text3D,
  609.             rot:Number3D;
  611.         rot = Matrix3D.matrix2euler(context.camera.transform);
  612.         mat = new Letter3DMaterial(0xffffff);
  613.         fnt = new HelveticaBold();
  614.         txt = new Text3D(TARGET_WORDS, fnt, mat);
  616.         txt.z = -1000;
  617.         txt.rotationX = Math.random() * 360;
  618.         txt.rotationY = Math.random() * 360;
  619.         txt.rotationZ = Math.random() * 360;
  620.         txt.alpha = 0;
  621.         txt.useOwnContainer = true;
  623.         context.container.addChild(txt);
  625.         b = BetweenAS3.tween(txt, {
  626.             'z': 500,
  627.             'alpha': 1,
  628.             'rotationX': rot.x,
  629.             'rotationY': rot.y,
  630.             'rotationZ': rot.z
  631.         }, null, 5, Elastic.easeOut);
  632.         b.play();
  633.     }
  635.     /**
  636.      *  will execute when tween complete betweenas3.
  637.      */
  638.     private function completeHandler(evt:BetweenEvent):void
  639.     {
  640.         var b:ITween,
  641.             t:ISingleTweenTarget,
  642.             obj:DisplayObject3D;
  644.         b = ITween(evt.target);
  645.         t = ISingleTweenTarget(b.tweenTarget);
  646.         obj = DisplayObject3D(t.target);
  647.         obj.parent.removeChild(obj);
  648.     }
  650.     /**
  651.      *  finalize the object.
  652.      */
  653.     override protected function finalize():void
  654.     {
  655.         context = null;
  656.         data = null;
  657.     }
  658. }
  660. /**
  661.  *  rendering pv3d.
  662.  */
  663. internal class PV3DRenderThread extends Thread
  664. {
  665.     private var context:Context;
  667.     /**
  668.      *  constructor.
  669.      */
  670.     public function PV3DRenderThread(context:Context)
  671.     {
  672.         this.context = context;
  673.     }
  675.     /**
  676.      *  first executable.
  677.      */
  678.     override protected function run():void
  679.     {
  680.         if (checkInterrupted()) return;
  682.         context.renderer.render();
  684.         next(run);
  685.     }
  687.     /**
  688.      *  finalize the object.
  689.      */
  690.     override protected function finalize():void
  691.     {
  692.         context = null;
  693.     }
  694. }
noswf
Get Adobe Flash Player