Forked from:: nme's basic bmp audio graph v0.1

basic bmp audio graph v0.1

written by Anthony R Pace

Just playing with the colour and making the line bigger this time round

forked:3
favorite:2
lines:39
license : MIT License
modified : 2012-05-16 06:12:07

Embed: Tweet

//Originally written by NME a.k.a Anthony R Pace
package {
    import flash.geom.Rectangle; 
    import flash.utils.ByteArray;
    import flash.events.SampleDataEvent;
    import flash.media.Microphone;
    import flash.display.BitmapData;
    import flash.display.Bitmap;
    import flash.display.Sprite;
    public class BMPAudioGraph extends Sprite {
        public var  bmpHeight:int = stage.stageHeight,//The height of the graph
                    smplHeight:int = 20,//The height of the Rect that will visually represent the position and height of the sample
                    bmp:Bitmap = new Bitmap(new BitmapData(512,bmpHeight,false,0x006600)), //the bitmap that will be used to represent the time domain
                    mic:Microphone = Microphone.getMicrophone(), //the default microphone if available
                    n:int, // the sample number
                    sn:Number,  //sample value at n, or s[n] 
                    bah:ByteArray, //Byte Array  that Holds the sample data
                    A:Number = ((bmpHeight-smplHeight)/2),//'A'  for amplitude factor.  
                    sampleRect:Rectangle = new Rectangle(0,0,1,smplHeight);
        public function sdeh(e:SampleDataEvent):void{ //sample data event handler
            bah = e.data;
            bah.position = 0;
            bmp.bitmapData.lock();
            bmp.bitmapData.fillRect(bmp.bitmapData.rect,0x3CD8FF);
            for (n = 0;n<512;++n){
               sn = bah.readFloat();//reads 4 bytes = 32 bit floating point sample value
               sampleRect.x = n;
               sampleRect.y = A-sn*A;//in this case I am using the Amplitude as not only a factor, but also the offset for the zero line.
               bmp.bitmapData.fillRect(sampleRect,0xd7f7ff);
            }
            bmp.bitmapData.unlock();
        }
        public function BMPAudioGraph() {
            stage.addChild(bmp);//make the bitmap visible on the display list
            mic.rate = 11;// sets the sample frequency to 11025hz
            mic.setSilenceLevel(0);//setting this to 0 makes it so you hear all activity... you should notice noise in the line.
            mic.addEventListener(SampleDataEvent.SAMPLE_DATA,sdeh); // call the sdeh function if the mic hears audio
        }
    }
}

Code Fullscreen

Preview Fullscreen