pv3d勉強100506

参考にしました。http://www.procreo.jp/tutorial01.html
Box2Dがいまだによくわからんので手計算。ハァ…。
@author atsu

forked:2
favorite:0
lines:142
license : All rights reserved
modified : 2010-05-06 18:44:42

Embed: Tweet

package  
{
	import flash.display.*;
	import flash.events.*;
	import org.papervision3d.lights.PointLight3D;
	import org.papervision3d.core.math.*;
	import org.papervision3d.view.*;
	import org.papervision3d.cameras.*;
	import org.papervision3d.objects.*;
	import org.papervision3d.objects.primitives.*;
	import org.papervision3d.materials.shadematerials.*;
	import org.papervision3d.materials.*;
	
	/**参考にしました。http://www.procreo.jp/tutorial01.html
	 * Box2Dがいまだによくわからんので手計算。ハァ…。
	 * @author atsu
	 */
	[SWF(frameRate = "50")]
	public class Main extends BasicView
	{
		private var sphere:Sphere;
		private var sw:Number;
		private var sh:Number;
		private var cx:Number;
		private var cy:Number;
		private var speedX:Number = 5;
		private var speedY:Number = 4;
		private var nowX:Number;
		private var prevX:Number;
		private var nowY:Number;
		private var prevY:Number;
		private var mouseFlag:Boolean = false;
		
		public function Main() 
		{
			super(0, 0, true, true, CameraType.FREE);
			addEventListener(Event.ADDED_TO_STAGE, addToStage);
		}
		
		private function addToStage(e:Event):void 
		{
			removeEventListener(Event.ADDED_TO_STAGE, addToStage);
			setStage();
			setDO3D();
		}
		
		private function setStage():void
		{
			stage.align = StageAlign.TOP_LEFT;
			stage.scaleMode = StageScaleMode.NO_SCALE;
			stage.quality = StageQuality.MEDIUM;
			stage.showDefaultContextMenu = false;
			stage.addEventListener(Event.RESIZE, resizeEvent);
			resizeEvent(null);
		}
		
		private function resizeEvent(e:Event):void
		{
			sw = stage.stageWidth;
			sh = stage.stageHeight;
			cx = sw / 2;
			cy = sh / 2;
		}
		
		private function setDO3D():void
		{
			var light:PointLight3D = new PointLight3D();
			light.x = -300;
			light.y = 200;
			light.z = -300;
			
			var material:FlatShadeMaterial = new FlatShadeMaterial(light, 0xEEEEEE);
			sphere = new Sphere(material, 100, 20, 20);
			scene.addChild(sphere);
			
			var material2:FlatShadeMaterial = new FlatShadeMaterial(light,0xEEEEEE);
			material2.doubleSided = true;
			var plane:Plane = new Plane(material2, 1000, 300, 4, 4);
			scene.addChild(plane);
			plane.rotationX = 90;
			plane.y = -300;
			var planeUe:Plane = new Plane(material2, 1000, 300, 4, 4);
			scene.addChild(planeUe);
			planeUe.rotationX = 90;
			planeUe.y = 300;
			
			var plane2:Plane = new Plane(material2, 600, 300, 4, 4);
			var plane3:Plane = new Plane(material2, 600, 300, 4, 4);
			scene.addChild(plane2);
			scene.addChild(plane3);
			plane2.rotationX = 90;
			plane2.rotationZ = -90;
			plane2.x = 500;
			plane3.rotationX = 90;
			plane3.rotationZ = -90;
			plane3.x = -500;
			
			camera.focus = 40;
			camera.z = -2000//-camera.zoom * camera.focus;
			
			startRendering();
			addEventListener(Event.ENTER_FRAME, loop);
			stage.addEventListener(MouseEvent.MOUSE_DOWN, downEvent);
			stage.addEventListener(MouseEvent.MOUSE_UP, upEvent);
			trace(camera.x, camera.y, camera.z);
		}
		
		private function downEvent(e:MouseEvent):void 
		{
			mouseFlag = true;
		}
		
		private function upEvent(e:MouseEvent):void 
		{
			mouseFlag = false;
		}
		
		private function loop(e:Event):void 
		{
			speedX *= 0.99;
			speedY = speedY * 0.99 + 0.98;
			if (mouseFlag == false) {
				camera.rotationY += (((stage.mouseX - cx) / 30) - camera.rotationY) / 20;
				if ((stage.mouseX - cx) / 30 >= 5) {
					camera.rotationY += (5 - camera.rotationY) / 20;
				}else if ((stage.mouseX - cx) / 30 <= -5) {
					camera.rotationY += (-5 - camera.rotationY) / 20;
				}
				sphere.x += speedX;
				if (sphere.x >= 400 || sphere.x <= -400) {
					speedX = speedX * -1 * 0.8;
				}
				sphere.y -= speedY;
				if (sphere.y >= 200 || sphere.y <= -200) {
					speedY = speedY * -1 * 0.8;
				}
			}else if (mouseFlag == true) {
				sphere.x = stage.mouseX - cx;
				sphere.y = -(stage.mouseY - cy);
				prevX = nowX;
				nowX = sphere.x;
				speedX = (nowX - prevX) / 2;
				prevY = nowY;
				nowY = sphere.y;
				speedY = -(nowY - prevY) / 2;
			}
			sphere.rotationZ = -sphere.x / (100 * Math.PI) * 360;
			
			if (sphere.x >= 400) {
				sphere.x = 400;
			}else if (sphere.x <= -400) {
				sphere.x = -400;
			}
			if (sphere.y >= 200) {
				sphere.y = 200;
			}else if (sphere.y <= -200) {
				sphere.y = -200;
			}
		}
		
	}

}

Code Fullscreen

Preview Fullscreen