Forked from:: nutsu's BitmapDataSample7

forked from: BitmapDataSample7

forked:1
favorite:2
lines:61
license : MIT License
modified : 2010-03-01 19:18:09

Embed: Tweet

// forked from nutsu's BitmapDataSample7
// forked from nutsu's BitmapDataSample5
// forked from nutsu's BitmapDataSample4
// forked from nutsu's BitmapDataSample3
// forked from nutsu's BitmapDataSample1
package {
    
    import flash.display.Sprite;
    import flash.display.BitmapData;
    import flash.display.Bitmap;
    import flash.geom.Matrix;
    import flash.geom.ColorTransform;
    import flash.display.BlendMode;
    import flash.filters.BlurFilter;
    import flash.events.Event;
    import flash.events.MouseEvent;
    
    [SWF(width=465,height=465,backgroundColor=0,frameRate=30)]
    public class BitmapDataSample7 extends Sprite {
        
        private var bmpdata:BitmapData;
        private var sprite:Sprite;
        private var matrix:Matrix;
        private var colortrans:ColorTransform;
        private var filter:BlurFilter;
        private var bmpcolortrans:ColorTransform;
        
        public function BitmapDataSample7() {
            //BitmapDataを作成して表示リストに追加
            bmpdata = new BitmapData( 465, 465, false, 0 );
            addChild( new Bitmap(bmpdata) );
            //グラフィックの生成
            sprite = newFig( 0, 0, 80, 0xFFFFFF );
            //Matrix,ColorTransformの初期化
            matrix = new Matrix();
            colortrans = new ColorTransform();
            bmpcolortrans = new ColorTransform( 0.99, 0.99, 0.99 );
            //エフェクトの初期化
            filter = new BlurFilter(15, 0, 5);
            //イベント
            addEventListener( Event.ENTER_FRAME, enterframe );
            stage.addEventListener( MouseEvent.CLICK, reset );
        }
        
        private function enterframe(e:Event):void {
            //エフェクトの適用
            bmpdata.applyFilter( bmpdata, bmpdata.rect, bmpdata.rect.topLeft, filter );
            //変形
            matrix.identity();
            var s:Number = Math.random()*2;
            matrix.scale( s, s );
            matrix.rotate( Math.PI * Math.random() );
            var pX:Number = bmpdata.width * Math.random();
            var pY:Number = bmpdata.height * Math.random();
            matrix.translate( pX, pY );
            //色変換
            colortrans.greenMultiplier = pX / 465;
            colortrans.blueMultiplier  = pY / 465;
            colortrans.alphaMultiplier = Math.random();
            //BitmapDataへ描画
            bmpdata.draw( sprite, matrix, colortrans, BlendMode.ADD );
            bmpdata.colorTransform( bmpdata.rect, bmpcolortrans );
        }
        
        private function reset(e:MouseEvent):void {
            bmpdata.fillRect( bmpdata.rect, 0xFF000000 );
        }
        
        private function newFig( cx:Number, cy:Number, size:Number, col:uint ):Sprite {
            //中心(cx,cy), 幅高さsize, 色col　のグラフィックを生成
            var shape:Sprite = new Sprite();
            shape.graphics.lineStyle( 0, 0x000000, 0.3 );
            shape.graphics.beginFill( col );
            shape.graphics.drawCircle( cx, cy, size*0.5 );
            shape.graphics.drawCircle( cx, cy, size*0.4 );
            var w:Number = size * 0.6;
            var h:Number = size * 0.15;
            shape.graphics.drawRect( cx - w/2, cy - h/2, w, h );
            shape.graphics.endFill();
            return shape;
        }
    }
}

Code Fullscreen

Preview Fullscreen

matacat

NIXin :

blursimple shapes + quick bluring

sort

pv89

forked from: forked from: Bitm..

smallflowergame

forked:0
favorite:0
lines:61 (diff:1)