Easy Benchmark

簡易ベンチマークです。
ランダムな速度で動くボールを毎フレームごとに100個ずつ追加していき、
直近10秒の平均fpsが30以下になった時点のボールの数をスコアとします。
スコアが出るまで少し時間がかかります。
ちょっと待ってね　just a moment!

ton

forked:14
favorite:41
lines:126
license : All rights reserved
modified : 2010-03-03 10:04:27

Embed: Tweet

/*
簡易ベンチマークです。
ランダムな速度で動くボールを毎フレームごとに100個ずつ追加していき、
直近10秒の平均fpsが30以下になった時点のボールの数をスコアとします。
スコアが出るまで少し時間がかかります。
ちょっと待ってね　just a moment!
*/
package {
	import flash.display.Bitmap;
	import flash.display.BitmapData;
	import flash.display.Sprite;
	import flash.events.Event;
	import flash.events.MouseEvent;
	import flash.net.navigateToURL;
	import flash.net.URLRequest;
	import flash.text.TextField;
	import flash.utils.getTimer;
	[SWF(frameRate=240)]
	public class EasyBenchmark extends Sprite {
		private const W:int = 465;
		private const H:int = 465;
		private const MAX_V:int = 10;
		private const MIN_V:int = 3;
		
		private var balls:/*Ball*/Array = [];
		private var frameRates:/*int*/Array = [];
		private var index:int = 0;
		private var ave:int = 120;
		
		private var ballCnt:int = 0;
		private var txtBallCnt:TextField;
		
		private var frameCnt:int = 0;
		private var txtFrameCnt:TextField;
		private var oldTimer:int;
		
		private var bmd:BitmapData;
		private var bmp:Bitmap;
		
		public function EasyBenchmark():void {	
			bmd = new BitmapData(W, H, false);
			bmp = new Bitmap(bmd);
			addChild(bmp);
			
			txtBallCnt = new TextField();
			txtBallCnt.autoSize = "left";
			txtBallCnt.background = true;
			addChild(txtBallCnt);
			
			txtFrameCnt = new TextField();
			txtFrameCnt.autoSize = "left";
			txtFrameCnt.background = true;
			txtFrameCnt.y = 30;
			addChild(txtFrameCnt);
			
			oldTimer = getTimer();			
			addEventListener(Event.ENTER_FRAME, update);
		}
		
		private function update(e:Event):void {
			updateFrame();
			if (ave <= 30) {
				removeEventListener(Event.ENTER_FRAME, update);
				complete();
				return;
			}
			
			for (var i:int = 0; i < 100; i++){
				var ball:Ball = new Ball(randomRange(MAX_V, MIN_V), randomRange(MAX_V, MIN_V));
				ball.x = Math.random() * W;
				ball.y = Math.random() * H;
				balls.push(ball);
				ballCnt++;
			}
			txtBallCnt.text = "score : " + ballCnt;
			
			bmd.fillRect(bmd.rect, 0xffffff);
			for each(ball in  balls) {
				ball.x += ball.vx;
				ball.y += ball.vy;
				bmd.setPixel(ball.x, ball.y, 0xff0000);
				if (ball.x <= 0 || ball.x >= W) {
					ball.vx *= -1;
				}
				if (ball.y <= 0 || ball.y >= H) {
					ball.vy *= -1;
				}
			}
		}
		
		private function complete():void{
			var tf:TextField = new TextField();
			tf.autoSize = "left";
			tf.text = "YOUR SCORE : " + ballCnt;
			tf.scaleX = tf.scaleY = 3;
			tf.x = W / 2 - tf.width / 2;
			tf.y = H / 2 - tf.height;
			addChild(tf);
			
			var button:TextField = new TextField();
			button.background = true;
			button.backgroundColor = 0xcccccc;
			button.autoSize = "left";
			button.selectable = false;
			button.text = "twitterに投稿";
			button.scaleX = button.scaleY = 2;
			button.x = W / 2 - button.width / 2;
			button.y = H / 2;
			button.addEventListener(MouseEvent.CLICK, function():void {
				navigateToURL(new URLRequest("http://twitter.com/?status=Easy Benchmark SCORE : "+ballCnt+" http://bit.ly/a6B5Er %23wonderfl"));
			});
			addChild(button);
			
		}
		
		private function updateFrame():void {
			frameCnt++;
			if (getTimer() - oldTimer >= 1000) {
				frameRates[index] = frameCnt;
				index = ++index % 10;
				ave = average.apply(null, frameRates);
				txtFrameCnt.text = "fps : " + frameCnt + "/" + stage.frameRate + "\nave : " + ave;
				frameCnt = 0;
				oldTimer = getTimer();
			}			
		}
		
		private function average(... rest):Number {
			var sum:Number = 0;
			for each(var n:Number in rest) sum += n;
			return sum / rest.length;
		}
		
		private function randomRange(max:Number, min:Number):Number {
			return Math.random()*(max - min) + min;
		}
		
	}
	
}

class Ball {
	public var x:Number;
	public var y:Number;
	public var vx:Number;
	public var vy:Number;
	
	public function Ball(vx:Number, vy:Number) {
		this.vx = vx;
		this.vy = vy;
	}
}

Code Fullscreen

Preview Fullscreen

自分はwin7 x64, core i7 860, FP10.0.45の環境でSCORE : 286800　でした

by ton
at 2010/03/03 10:49:39

自分はMacOSX 10.6、Core2Duo 2.0GHz、メモリ4Gで以下の結果でした。
FP 10.1 beta3(リリース版)だとScore:147600
FP 10.1 beta3(デバッグ版)だとScore:95600
FP10.0.45だと 65900 (※Safari 64bit起動)

by clockmaker
at 2010/03/03 12:11:00

ローレベルターゲットのご参考に．ネットブック(winXP, Atom Z520，現在のメイン開発環境)．
FP 10.1 beta3(リリース):47300(FF) 45000(IE)

by keim_at_Si
at 2010/03/04 01:12:47

Macを新調したので再掲載。MacOSX 10.6、Core i7 2.66GHz、メモリ8Gで以下の結果でした。
FP 10.1 RC(リリース版)だとScore:240500

by clockmaker
at 2010/04/19 12:39:32

Win7 64bit PL 10,0,45,2 Core2Duo 3.16GHz、Mem4GでSCORE : 262200 でした。

by xxxYukihiroxxx
at 2010/04/19 12:46:16

FP10.1.53.64　SCORE : 321000

by ton
at 2010/06/04 08:11:01

MBP i7 2.66GHz, MEM 8GB, OS X 10.6
FP 10.1.53.64 デバッグ版 SCORE: 176800
FP 10.1.53.64 リリース版 SCORE: 250000

by nariyu
at 2010/06/11 13:27:30

Win7 64bit FP WIN 10,1,53,64 Core2Duo 3.16GHz、Mem4GでSCORE : 312100 でした。

by xxxYukihiroxxx
at 2010/06/20 10:13:12

スマートフォン(Google Nexus One - Android 2.2)の Flash Player 10.1 にて SCORE : 33700 でした。

by clockmaker
at 2010/07/24 19:52:34

FP"Square"Preview1, IE8 64bit, Win7 64bit Easy Benchmark SCORE : 348300
FP10,1,82,76 IE8 32bit, Win7 64bit Easy Benchmark SCORE : 301700
FP"Square"Preview1, IE8 32bit, Win7 64bit Easy Benchmark SCORE : 306300
FP"Square"Preview1はバージョン10,2,161,22

by ton
at 2010/09/16 07:42:20

Android タブレットの「Galaxy Tab」では 20800でした。http://yfrog.com/07fw6uj

by clockmaker
at 2010/10/28 01:32:29

FP10,2,151,49 SCORE : 266600

by ton
at 2010/12/01 09:38:37

atom cpu hp mini 45500

by makc3d
at 2010/12/01 09:55:07

Q6600 2.6hz 83800

by zonnbe
at 2010/12/02 15:37:10

Atom CPU 1.6GHz (VAIO X) 49200 (Windows 7/Flash Player 10,1 Release)

by clockmaker
at 2010/12/05 11:00:59

FP10.2Beta1 IE9x86 SCORE : 294200
FP"Square"Preview3 IE9x64 SCORE : 338000
FP"Square"Preview3はバージョン10,3,162,28

by ton
at 2010/12/05 23:01:29

MBP Mac OS X i5 2.3GHz Mem 4GB GoogleChrome FP10.3.181.14 Easy Benchmark SCORE : 236100

by ton
at 2011/05/29 00:38:38

FP11 Beta1 (11.0.1.60)
IE9 64bit SCORE : 347800
IE9 32bit SCORE : 308800
Chrome 32bit SCORE : 269500

by ton
at 2011/07/14 10:40:44

MacBook Air 13inch
- Mac OS X 10.7
- Intel Core i7 1.8GHz
- メモリ4G
- グラフィックス Intel HD Graphics 3000 384 MB

FP 10.2 (リリース版) - Score:232500

by clockmaker
at 2011/07/26 12:48:46

MacOSX 10.7、Core i7 2.66GHz、メモリ8Gで以下の結果でした。
FP 11 Beta 2 64bit(リリース版)だとScore:323900

by clockmaker
at 2011/09/01 21:24:25

Chrome FP 11.0.1.129 64bit SCORE : 280500

by ton
at 2011/09/07 12:14:50

MBA'13 2011 Core i7 1.8GHz RAM 4GB Safari FP11.0.1.152 SCORE : 340300

by mousepancyo
at 2011/10/04 10:58:34

FP11.0.1.152

MBP MacOSX 10.7 i5 2.3GHz Mem4GB
Chrome14 SCORE : 264500
Safari5.1 SCORE : 332100

Win7 x64, core i7 860 Mem8GB
IE9 32bit SCORE : 318800
IE9 64bit SCORE : 371300
Chrome14 32bit SCORE : 280500
Safari5.1 32bit SCORE : 320100
FF7 32bit SCORE : 279300

by ton
at 2011/10/04 17:05:18

FP 11,0,1,152 (64-bit), Linux, Intel Q9300 @ 2.5GHz, firefox 3.6, SCORE: 194300