zソート等の格納先

forked:0
favorite:10
lines:168
license : MIT License
modified : 2009-12-11 19:12:50

Embed: Tweet

package {

import flash.display.*;
import flash.geom.*;
import flash.events.*;
import flash.text.*;
import flash.utils.*;

public class Main extends Sprite
{
    static private const N:uint = 10;
    static private const M:uint = 10000;
    
    private function _init():void
    {
        _debug(
            "各テスト " + M + " * " + N + " 回処理させた計算結果 [単位 ： ミリ秒]\n" +
            "(誤差は多少生じます)\n"
        );
        
        _measure("カラ運転", function ():void
        {
            for(var j : uint = 0;j < N;j++){
                var a : Array = new Array(M);
                for (var i:uint = 0; i < M; i++) {
                    Math.random();
                    Math.random();
                    Math.random();
                }
            }
        });
        
        _measure("Object格納", function ():void
        {
            for(var j : uint = 0;j < N;j++){
                var a : Array = new Array(M);
                for (var i:uint = 0; i < M; i++) {
                    a[i] = {x:Math.random(), y:Math.random(), z:Math.random()};
                }
            }
        });
        
        _measure("Array格納", function ():void
        {
            for(var j : uint = 0;j < N;j++){
                var a : Array = new Array(M);
                for (var i:uint = 0; i < M; i++) {
                    a[i] = [Math.random(), Math.random(), Math.random()];
                }
            }
        });
        
        _measure("Class格納", function ():void
        {
            for(var j : uint = 0;j < N;j++){
                var a : Array = new Array(M);
                for (var i:uint = 0; i < M; i++) {
                    a[i] = new P(Math.random(), Math.random(), Math.random());
                }
            }
        });
        
        _measure("Vector3D格納", function ():void
        {
            for(var j : uint = 0;j < N;j++){
                var a : Array = new Array(M);
                for (var i:uint = 0; i < M; i++) {
                    a[i] = new Vector3D(Math.random(), Math.random(), Math.random());
                }
            }
        });
        
        _measure("Object格納ソート", function ():void
        {
            for(var j : uint = 0;j < N;j++){
                var a : Array = new Array(M);
                for (var i:uint = 0; i < M; i++) {
                    a[i] = {x:Math.random(), y:Math.random(), z:Math.random()};
                }
                a.sortOn("z", Array.NUMERIC);
            }
        });
        
        _measure("Array格納ソート", function ():void
        {
            for(var j : uint = 0;j < N;j++){
                var a : Array = new Array(M);
                for (var i:uint = 0; i < M; i++) {
                    a[i] = [Math.random(), Math.random(), Math.random()];
                }
                a.sortOn("2", Array.NUMERIC);
            }
        });
        
        _measure("Class格納ソート", function ():void
        {
            for(var j : uint = 0;j < N;j++){
                var a : Array = new Array(M);
                for (var i:uint = 0; i < M; i++) {
                    a[i] = new P(Math.random(), Math.random(), Math.random());
                }
                a.sortOn("z", Array.NUMERIC);
            }
        });
        
        _measure("Vector3D格納ソート", function ():void
        {
            for(var j : uint = 0;j < N;j++){
                var a : Array = new Array(M);
                for (var i:uint = 0; i < M; i++) {
                    a[i] = new Vector3D(Math.random(), Math.random(), Math.random());
                }
                a.sortOn("z", Array.NUMERIC);
            }
        });
        
        _debug("\nClass=Vector3D>Array=Object って感じかしら");
    }
    
    private var _field:TextField;
    private var _time:uint;
    
    public function Main():void
    {
        _setup();
        _init();
    }
    
    private function _measure(title:String, func:Function, ...params):void
    {
        _time = getTimer();
        func.apply(null, params);
        _time = getTimer() - _time;
        
        _debug("[ " + title + " ] --> " + _time + " ms");
    }
    
    private function _debug(log:String):void
    {
        _field.appendText(log + "\n");
    }
    
    private function _setup():void
    {
        _field = new TextField();
        _field.width = stage.stageWidth - 40;
        _field.height = stage.stageHeight - 60;
        _field.x = 20;
        _field.y = 60;
        _field.multiline = true;
        _field.wordWrap = true;
        
        var format:TextFormat = _field.defaultTextFormat;
        format.font = "_sans";
        _field.defaultTextFormat = format;
        
        addChild(_field);
        
        var button:Sprite = new Sprite();
        button.graphics.lineStyle(1, 0xBBBBBB);
        button.graphics.beginFill(0xEEEEEE);
        button.graphics.drawRoundRect(0, 0, 100, 20, 5, 5);
        button.graphics.endFill();
        
        addChild(button);
        
        button.x = 20;
        button.y = 20;
        button.mouseChildren = false;
        button.buttonMode = true;
        
        var field:TextField = new TextField();
        field.width = 100;
        field.height = 20;
        field.htmlText = "<p align='center'><font face='_sans'>再計算</span></p>";
        
        button.addChild(field);
        
        button.addEventListener(MouseEvent.CLICK, function ():void
        {
            _field.text = "";
            _init();
        });
    }
}

}

class P
{
    public var x : Number;
    public var y : Number;
    public var z : Number;
    
    public function P(x_ : Number, y_ : Number, z_ : Number){
        x = x_; y = y_; z = z_;
    }
}

Code Fullscreen

Preview Fullscreen

各自のマシン環境の結果を晒すと良いかも。
Flash Player 10,0,32,18 / Mac OS X 10.6
[ カラ運転 ] --> 35 ms
[ Object格納 ] --> 130 ms
[ Array格納 ] --> 102 ms
[ Class格納 ] --> 93 ms
[ Vector3D格納 ] --> 93 ms
[ Object格納ソート ] --> 209 ms
[ Array格納ソート ] --> 207 ms
[ Class格納ソート ] --> 208 ms
[ Vector3D格納ソート ] --> 194 ms

by clockmaker
at 2009/12/08 19:59:44

晒し
Flash Player 10,0,32,18 / WindowsXP
[ カラ運転 ] --> 113 ms
[ Object格納 ] --> 440 ms
[ Array格納 ] --> 354 ms
[ Class格納 ] --> 207 ms
[ Vector3D格納 ] --> 192 ms
[ Object格納ソート ] --> 763 ms
[ Array格納ソート ] --> 638 ms
[ Class格納ソート ] --> 482 ms
[ Vector3D格納ソート ] --> 524 ms

by nyamogera
at 2009/12/08 20:27:23

一応マシンスペックまで晒し

WinXP(SP3) RAM::3．25GB CUP::Core2Quad 2.4GHz

FP 10．1β(Google Chrome)

[ カラ運転 ] --> 8 ms
[ Object格納 ] --> 88 ms
[ Array格納 ] --> 75 ms
[ Class格納 ] --> 36 ms
[ Vector3D格納 ] --> 37 ms
[ Object格納ソート ] --> 160 ms
[ Array格納ソート ] --> 144 ms
[ Class格納ソート ] --> 112 ms
[ Vector3D格納ソート ] --> 112 ms

FP 10.0.32.18(IE)

[ カラ運転 ] --> 30 ms
[ Object格納 ] --> 138 ms
[ Array格納 ] --> 134 ms
[ Class格納 ] --> 99 ms
[ Vector3D格納 ] --> 101 ms
[ Object格納ソート ] --> 230 ms
[ Array格納ソート ] --> 223 ms
[ Class格納ソート ] --> 177 ms
[ Vector3D格納ソート ] --> 182 ms

ブラウザが違うからバージョンの比較にならないかな？

by zahir
at 2009/12/08 20:47:57

[ カラ運転 ] --> 25 ms
[ Object格納 ] --> 122 ms
[ Array格納 ] --> 129 ms
[ Class格納 ] --> 93 ms
[ Vector3D格納 ] --> 91 ms
[ Object格納ソート ] --> 229 ms
[ Array格納ソート ] --> 183 ms
[ Class格納ソート ] --> 178 ms
[ Vector3D格納ソート ] --> 176 ms

by paq
at 2009/12/08 20:51:10

カラ運転は何十回やっても同じ結果でした。

by paq
at 2009/12/08 20:51:58

WinXP(SP3) / FP 10.0.32.18(Opera)
[ カラ運転 ] --> 16 ms
[ Object格納 ] --> 141 ms
[ Array格納 ] --> 150 ms
[ Class格納 ] --> 83 ms
[ Vector3D格納 ] --> 76 ms
[ Object格納ソート ] --> 300 ms
[ Array格納ソート ] --> 250 ms
[ Class格納ソート ] --> 178 ms
[ Vector3D格納ソート ] --> 187 ms

ブラウザで結構違う

by 178ep3
at 2009/12/09 11:04:10