Forked from:: tail_y's CloudEffect

CloudEffect ちょっと高速化

若干立体感のある、雲っぽい映像を作るよ。
はっきり言って重いので、実用性がちょっと無いよ！！
その代わり、リアルタイムで色合いとか変えられるから、時間に合わせて夕焼けになったりできるかも。

仕組み的にはPhotoShopでの常套手段をFlashで再現したもの。
数値を変えるとかなりリアルなのも作れるけど、これ以上立体感を出すには他の工夫が必要。
台形変形とか、影の位置をずらしたりとかできれば・・・。

雲模様の生成が遅いのはなんとかならないかな～
１オクターブずつ用意して、横にずれた分だけを新しく生成するとかさ。
ちょっと考えてみたけど頭痛くなったからやらなかったよ。

高速化してみた。
自分の環境では4fpsほど改善。

nemu90kWw

forked:2
favorite:19
lines:79
license : MIT License
modified : 2009-06-10 02:44:25

Embed: Tweet

// forked from tail_y's CloudEffect
package {
    
	/*
	 若干立体感のある、雲っぽい映像を作るよ。
	 はっきり言って重いので、実用性がちょっと無いよ！！
	 その代わり、リアルタイムで色合いとか変えられるから、時間に合わせて夕焼けになったりできるかも。
	 
	 仕組み的にはPhotoShopでの常套手段をFlashで再現したもの。
	 数値を変えるとかなりリアルなのも作れるけど、これ以上立体感を出すには他の工夫が必要。
	 台形変形とか、影の位置をずらしたりとかできれば・・・。
	 
	 雲模様の生成が遅いのはなんとかならないかな～
	 １オクターブずつ用意して、横にずれた分だけを新しく生成するとかさ。
	 ちょっと考えてみたけど頭痛くなったからやらなかったよ。
	 */
        /*
         高速化してみた。
         自分の環境では4fpsほど改善。
        */
	
	import flash.display.*;
	import flash.events.*;
	import flash.filters.*;
	import flash.geom.*;
	
	import net.hires.debug.Stats;

public class CloudEffect1 extends Sprite {
		
		public static const STAGE_W:uint = 465;
		public static const STAGE_H:uint = 465;
		
		public static const _H_RATE:Number = 2;	// 上下の圧縮割合
		
		// 雲模様関係
		private var _perlinNoiseSize:Number = 0.25;	// 雲模様を画面全体に描画するのは重くて無理なので、サイズを減らす。
		private var _perlinNoiseSizeW:int = STAGE_W*_perlinNoiseSize;
		private var _perlinNoiseSizeH:int = STAGE_H*_perlinNoiseSize*_H_RATE;
		private var _perlinNoiseBitmapData:BitmapData = new BitmapData(_perlinNoiseSizeW, _perlinNoiseSizeH, false);
		private var _seed:int = Math.random()*int.MAX_VALUE;
		private var _cloudSize:int = _perlinNoiseSize * 240;
		private var _octaves:int = 5;	// 雲模様オクターブ数。レイヤー数みたいなもの。多いほど細かいけど、死ぬほど重くなる。
		private var _offsetList:Array = [];	// 雲のズレ。オクターブの数だけPointが必要。
		private var _offsetSpeedList:Array = [0.5, 0.4, 0.3, 0.2, 0.15];	// 雲をずらす量。
		
		// 立体化関係
		private var _displacementBitmapData:BitmapData = new BitmapData(_perlinNoiseSizeW, _perlinNoiseSizeH, false);
		private var _displacementMapFilter:DisplacementMapFilter;
		
		// 色変換関係
		private var _palette:Array = [];
		private var _nullPalette:Array = [];
		
		// 引き伸ばした画像データ
		private var _scaleChangeBitmap:Bitmap = new Bitmap(_displacementBitmapData);
		
		// ちょっとしたカバー
		private var _cover:Shape = new Shape();
		
		// その他
		private var _point:Point = new Point(0, 0);
		private var _rectSmall:Rectangle = new Rectangle(0, 0, _perlinNoiseSizeW, _perlinNoiseSizeH);
		
		public function CloudEffect1() {
			
			addEventListener(Event.ADDED_TO_STAGE, init);	// flexBuilderとの互換性。
		}
		private function init(e:Event):void {	// ここから開始
			removeEventListener(Event.ADDED_TO_STAGE, init);
			// SWF設定
			stage.frameRate = 30;
			stage.quality = StageQuality.HIGH;
			
			// 雲模様データを用意する
			for (var i:int = 0; i < _octaves; i++) _offsetList.push(new Point());
			
			// 立体化データを用意する
			_displacementMapFilter = new DisplacementMapFilter(_perlinNoiseBitmapData, _point, 0, BitmapDataChannel.RED, 0,
									 100, DisplacementMapFilterMode.CLAMP);
			
			// 色変換データを用意する
			createGradation();
			
			// サイズ
			_scaleChangeBitmap.scaleX = 1/_perlinNoiseSize;
			_scaleChangeBitmap.scaleY = 1/_perlinNoiseSize/_H_RATE;
			_scaleChangeBitmap.smoothing = true;
			
			// 白っぽいカバー
			var matrix:Matrix = new Matrix();
			matrix.createGradientBox(_perlinNoiseSizeW, _perlinNoiseSizeH, Math.PI/2);
			_cover.graphics.beginGradientFill(GradientType.LINEAR, [0x666666, 0xaaaaaa], [1, 1], [128, 255], matrix);
			_cover.graphics.drawRect(0, 0, _perlinNoiseSizeW, _perlinNoiseSizeH);
			
			// 表示
			addChild(_scaleChangeBitmap);
			
			// Stats
			addChild(new Stats());
			
			addEventListener(Event.ENTER_FRAME, frame);
		}
		private function createGradation():void{	// グラデーションを作るよ
			var tmpShape:Shape = new Shape();
			var matrix:Matrix = new Matrix();
			matrix.createGradientBox(255, 0);
			var colorList:Array = [0xa7a7c4, 0xf3f8ff, 0xffffff, 0x418fdf];
			//var colorList:Array = [0x824229, 0xfb8f1b, 0xffc768, 0xa0afac];	// 夕焼けカラーパターン
			var alphaList:Array = [1,        1,        1,        1];
			var ratioList:Array = [0,        80,       100,      200];
			tmpShape.graphics.beginGradientFill(GradientType.LINEAR, colorList, alphaList, ratioList, matrix);
			tmpShape.graphics.drawRect(0, 0, 256, 1);
			var tmpBitmap:BitmapData = new BitmapData(256, 1, false);
			tmpBitmap.draw(tmpShape);
			for (var i:int=0; i<256; i++){
				_palette.push(tmpBitmap.getPixel(i, 0));
				_nullPalette.push(0x000000);
			}
		}
		
		private function frame(event:Event):void{	
			for (var i:int = 0; i < _octaves; i++){	// 雲模様のオフセットを決める
				Point(_offsetList[i]).x += Number(_offsetSpeedList[i]);
			}
			// 雲模様を作成
			_perlinNoiseBitmapData.perlinNoise(_cloudSize, _cloudSize, _octaves, _seed, false, true, 0, true, _offsetList);
			// 立体感を出す
			_displacementBitmapData.lock();
			_displacementBitmapData.applyFilter(_perlinNoiseBitmapData, _rectSmall, _point, _displacementMapFilter);
			_displacementBitmapData.draw(_perlinNoiseBitmapData, null, null, BlendMode.HARDLIGHT);
			// パレットマップで変換
			_displacementBitmapData.paletteMap(_displacementBitmapData, _rectSmall, _point, _palette, _nullPalette, _nullPalette);
			_displacementBitmapData.draw(_cover, null, null, BlendMode.OVERLAY);
			_displacementBitmapData.unlock();
		}
		
	}
}

Code Fullscreen

Preview Fullscreen