line with colorTranform

forked:1
favorite:0
lines:57
license : All rights reserved
modified : 2009-02-04 02:08:55

Embed: Tweet

package 
{ 
    import flash.display.MovieClip; 
    import flash.events.Event; 
    import flash.display.Bitmap; 
    import flash.display.BitmapData; 
    import flash.geom.ColorTransform; 
    import flash.geom.Point; 
     
     
    [SWF(width=400, height=300, backgroundColor="#000000", frameRate=30)] 
    public class Capture extends MovieClip 
    { 
        private const W:uint = 400; 
        private const H:uint = 300; 
        private const POINT_NUM:uint=100; 
         
        private var points:Array=[]; 
        private var org_mc:MovieClip; 
        private var bmp:Bitmap; 
        private var bmpDat:BitmapData; 
         
         
        public function Capture():void 
        { 
            org_mc = new MovieClip(); 
            org_mc.visible=false; 
            //addChild(org_mc); 
             
            bmpDat = new BitmapData(W, H, true, 0xFFFFFF); 
            bmp = new Bitmap(bmpDat); 
            addChild(bmp); 
            for(var i:uint=0; i<POINT_NUM; i++){ 
                var pt:Point=new Point( W*0.5, H*i/POINT_NUM ); 
                points.push( pt ); 
            } 
            addEventListener(Event.ENTER_FRAME, myEnterFrame); 
        } 
         
        private function myEnterFrame(evt:Event):void 
        { 
            org_mc.graphics.clear(); 
             
            var mX:uint = mouseX; 
            var mY:uint = int( (POINT_NUM-1)*mouseY/H ); 
             
            points[mY].x -= (points[mY].x - mX)*0.6; 
            org_mc.graphics.beginFill(0x666600, 0.3); 
            org_mc.graphics.drawCircle(points[mY].x, points[mY].y, 2); 
            org_mc.graphics.endFill(); 
             
             
            for(var i:int=mY-1; i>=0; i--){ 
                points[i].x -= (points[i].x - points[i+1].x)*0.6; 
                org_mc.graphics.beginFill(0x666600, 0.3); 
                org_mc.graphics.drawCircle(points[i].x, points[i].y, 2); 
                org_mc.graphics.endFill(); 
            } 
            for(i=mY+1; i<POINT_NUM; i++){ 
                points[i].x -= (points[i].x - points[i-1].x)*0.6; 
                org_mc.graphics.beginFill(0x660000, 0.3); 
                org_mc.graphics.drawCircle(points[i].x, points[i].y, 2); 
                org_mc.graphics.endFill(); 
            } 
             
            bmpDat.colorTransform( bmpDat.rect, new ColorTransform( 1, 1, 1, 1, 0, 0, 10, -1 ) ); 
            bmpDat.draw( org_mc ); 
             
        } 
         
    } 
     
}

Code Fullscreen

Preview Fullscreen

sort

pv0

forked from: line with colorTr..

SoWhat1983

forked:0
favorite:0
lines:57 (diff:1)