Forked from:: narutohyper's Alternativa3D フラットシェーディングプリミティブ

forked from: Alternativa3D フラットシェーディングプリミティブ

色々高速化の手段はありますが
このままだと結構処理が重いので、4ｘ4ｘ4くらいが限界です
@narutohyper

Alternativa3D フラットシェーディングプリミティブ
papervision3dでできてもAlternativa3Dではどうすれば？シリーズ、第2弾ｗ

Alternativa3DにもDevMaterialというフラットシェーディング風のmaterialはあるのですが
あまりにアレなので自作したものです。

Alternativa3Dブログでは、サンプルとして、色々出てるんですが、ソースは公開されてませんので、
このあたり、世界中の人のもやもやになってるみたいですねｗ

というわけで、前回LookAtやりましたので、それの応用でこれもできちゃいます。
Texture部分は各プリミティブでも使えるようにするには、
もう少し複雑なクラスで構成しないといけませんが、とりあえずこんな感じでできます。的なものです。

きっと、Alternativa3D ver7ではちゃんと実装されるでしょうｗ

@narutohyper

Alternativa3D を簡単に扱うためのベーシックテンプレート
@author Yasu (clockmaker)

narutohyper

forked:0
favorite:4
lines:282
license : MIT License
modified : 2010-10-19 11:13:59

Embed: Tweet

// forked from narutohyper's Alternativa3D フラットシェーディングプリミティブ
// forked from clockmaker's [Alternativa3D] Basic Template

package {
	import alternativ5.engine3d.materials.FillMaterial;
	import alternativ5.engine3d.materials.DevMaterial;
	import alternativ5.engine3d.primitives.Sphere;
	import alternativ5.engine3d.events.MouseEvent3D
	import alternativ5.engine3d.core.Object3D;
	import alternativ5.types.Point3D;
	import flash.display.Sprite;
	
	[SWF(width = 465, height = 465, frameRate = 24)]
	/**
	 * 色々高速化の手段はありますが
	 * このままだと結構処理が重いので、4ｘ4ｘ4くらいが限界です
	 * @narutohyper
	 */

/**
	 * Alternativa3D フラットシェーディングプリミティブ
	 * papervision3dでできてもAlternativa3Dではどうすれば？シリーズ、第2弾ｗ
	 * 
	 * Alternativa3DにもDevMaterialというフラットシェーディング風のmaterialはあるのですが
	 * あまりにアレなので自作したものです。
	 * 
	 * Alternativa3Dブログでは、サンプルとして、色々出てるんですが、ソースは公開されてませんので、
	 * このあたり、世界中の人のもやもやになってるみたいですねｗ
	 * 
	 * というわけで、前回LookAtやりましたので、それの応用でこれもできちゃいます。
	 * Texture部分は各プリミティブでも使えるようにするには、
	 * もう少し複雑なクラスで構成しないといけませんが、とりあえずこんな感じでできます。的なものです。
	 * 
	 * きっと、Alternativa3D ver7ではちゃんと実装されるでしょうｗ
	 * 
	 * @narutohyper
	 */

/**
	 * Alternativa3D を簡単に扱うためのベーシックテンプレート
	 * @author Yasu (clockmaker)
	 */

public class SimpleDemo extends Sprite {

public function SimpleDemo():void {
			// テンプレートを作成します
			var template:BasicTemplate = new BasicTemplate();
			addChild(template);
			template.camera.z = -1500;

// プリミティブを作成します

var light:Sphere = new Sphere(30);
				light.cloneMaterialToAllSurfaces(new FillMaterial(0xCCCC00));
				light.coords=new Point3D(0,200,0);

var boxArray:Array=[];
				var length:uint=300
				var num:uint=4

var block:Object3D=new Object3D()

template.scene.root.addChild(block);

for (var i:uint=0;i<Math.pow(num,3);i++) {
					boxArray.push(new shadingBox(100, 100, 100));
					boxArray[i].originalDevMaterial(0x0000FF);
					template.scene.root.addChild(boxArray[i]);

boxArray[i].x=(i%num)*length-(length*(num-1)/2)
					boxArray[i].y=Math.floor(i/num)*length-(length*(num-1)/2)-(Math.floor(i/Math.pow(num,2))*(length*num))
					boxArray[i].z=Math.floor(i/Math.pow(num,2))*length-(length*(num-1)/2)

block.addChild(boxArray[i]);

}

// 3Dシーンのルートに追加します
				template.scene.root.addChild(light);

var angle:uint=0;			//外周りの箱の為の角度

// Event.ENTER_FRAME 時に実行されるレンダリングのイベントです。
			// レンダリング前に実行したい処理を記述します。
			template.onPreRender = function():void {

// 立方体を回転させます (角度はラジアン)
				angle+=4;
				var radian:Number= angle/180*Math.PI;
				var radian2:Number= angle/180*Math.PI*2;
				light.y=Math.sin(radian)*1000
				light.x=Math.cos(radian)*1000
				light.z=Math.cos(radian)*1000

block.rotationY += 1 * Math.PI / 180;

for (var i:uint=0;i<Math.pow(num,3);i++) {
					boxArray[i].rotationX += 4 * Math.PI / 180;
					boxArray[i].shading(light)
				}

// マウスがステージの高さ何%の位置にあるか算出
				var rateY:Number = mouseY / stage.stageHeight;
				//var rateX:Number = mouseX / stage.stageWidth;
				
				// カメラの高さの座標を調整
				// イージングの公式 対象の値 += (目標値 - 現在の値) * 減速率
				template.camera.y += ( - 1000 * rateY - template.camera.y) * 0.1;
				//template.camera.x += ( - 1000 * rateX - template.camera.x) * 0.1;
				
				// カメラの座標を中央に向かせる

template.cameraContoller.lookAt(new Point3D());
			}
		}

}
}

import flash.display.Bitmap;
import flash.display.BitmapData;
import flash.display.Sprite;
import flash.display.StageAlign;
import flash.display.StageQuality;
import flash.display.StageScaleMode;
import flash.display.BlendMode
import flash.events.Event;
import flash.geom.Rectangle
import flash.geom.ColorTransform

import alternativ5.engine3d.controllers.CameraController;
import alternativ5.engine3d.core.Camera3D;
import alternativ5.engine3d.core.Object3D;
import alternativ5.engine3d.core.Scene3D;
import alternativ5.types.Texture;
import alternativ5.types.Point3D;
import alternativ5.types.Matrix3D;
import alternativ5.engine3d.display.View;

import alternativ5.engine3d.primitives.Box;
import alternativ5.engine3d.primitives.Cone;
import alternativ5.engine3d.events.MouseEvent3D
import alternativ5.engine3d.materials.DevMaterial;
import alternativ5.engine3d.materials.FillMaterial;
import alternativ5.engine3d.materials.SurfaceMaterial;
import alternativ5.engine3d.materials.TextureMaterial
import alternativ5.utils.MathUtils;

/**
 * 追記
 * フラットシェーディングするbox
 */
class shadingBox extends Box{

private var effectUtl:effectUtility;

private var textureObj:Object;

public function shadingBox(width:Number = 100, length:Number = 100, height:Number = 100, widthSegments:uint = 1, lengthSegments:uint = 1, heightSegments:uint = 1, reverse:Boolean = false, triangulate:Boolean = false) {
		super(width, length, height, widthSegments, lengthSegments, heightSegments, reverse, triangulate);
		effectUtl=new effectUtility(this);
		textureObj={}

}

public function lookAt(targetObject:*, upAxis:Point3D=null ):void {
		effectUtl.lookAt(targetObject, this.getFaceById('top_0_0').normal)
	}

public function originalDevMaterial(color:uint):void {
		//originalのフラットシェーディングできるTextureを作成
		textureObj.top		=	new originalDevTexture(color);
		textureObj.front	=	new originalDevTexture(color);
		textureObj.right	=	new originalDevTexture(color);
		textureObj.bottom	=	new originalDevTexture(color);
		textureObj.back		=	new originalDevTexture(color);
		textureObj.left		=	new originalDevTexture(color);

//各materialにTextureをセット
		this.setMaterialToSurface(new TextureMaterial(textureObj.top)			,'top');
		this.setMaterialToSurface(new TextureMaterial(textureObj.front)		,'front');
		this.setMaterialToSurface(new TextureMaterial(textureObj.right)		,'right');
		this.setMaterialToSurface(new TextureMaterial(textureObj.bottom)		,'bottom');
		this.setMaterialToSurface(new TextureMaterial(textureObj.back)			,'back');
		this.setMaterialToSurface(new TextureMaterial(textureObj.left)			,'left');
		
	}

public function shading(targetObject:*):void {
		//光源(targetObject)に対してshadingLvを求め、Textureを変更
		textureObj.top.shadeLv(toDegree(effectUtl.shadowLv(targetObject, this.getFaceById('top_0_0').normal)));
		textureObj.front.shadeLv(toDegree(effectUtl.shadowLv(targetObject, this.getFaceById('front_0_0').normal)));
		textureObj.right.shadeLv(toDegree(effectUtl.shadowLv(targetObject, this.getFaceById('right_0_0').normal)));
		textureObj.bottom.shadeLv(toDegree(effectUtl.shadowLv(targetObject, this.getFaceById('bottom_0_0').normal)));
		textureObj.back.shadeLv(toDegree(effectUtl.shadowLv(targetObject, this.getFaceById('back_0_0').normal)));
		textureObj.left.shadeLv(toDegree(effectUtl.shadowLv(targetObject, this.getFaceById('left_0_0').normal)));

}

private function toDegree(no:Number):uint {
		var result:uint =Math.round(Math.abs(MathUtils.toDegree(no)));
		return result;
	}

}

//originalのフラットシェーディングできるTextureを作成するクラス
class originalDevTexture extends Texture{
	private var shadeBm:Bitmap;
	private var tempSprite:Sprite;

public function originalDevTexture(color:int,_width:Number=10,_height:Number=10) {

tempSprite = new Sprite();
		tempSprite.addChild(new Bitmap(new BitmapData(_width,_height, true, 0xFF000000 | color)))

shadeBm = new Bitmap(new BitmapData(_width,_height, true, 0xFFFFFFFF))
		shadeBm.blendMode=BlendMode.HARDLIGHT
		tempSprite.addChild(shadeBm)

super(new BitmapData(_width,_height, true, 0xFFFFFFFF));

this.bitmapData.draw(tempSprite)
	}

public function shadeLv(_lv:uint):void {
		//shadingLvでTextureをtranceform
		//0:明るい(100%[1])～180:暗い(0%[0])
		var cTransform:ColorTransform  = new ColorTransform();
		var lv:Number=(180-_lv)/180;

cTransform.redMultiplier=lv
		cTransform.greenMultiplier=lv
		cTransform.blueMultiplier=lv
		shadeBm.transform.colorTransform = cTransform;

this.bitmapData.draw(tempSprite)
	}

}

//プリミティブで使う、各種Utilityクラス
class effectUtility {

private var thisObject:*
	public function effectUtility(mc:*) {
		thisObject=mc;
	}

//光源に対してのシャドーLvを返す。
	public function shadowLv(targetObject:*, vAxis:Point3D=null ):Number {

var position :Point3D = thisObject.coords;
		var target	 :Point3D = targetObject.coords;
		var result	 :Number = 0;

//光源に対するZ方向(と距離)
		var zAxis 	 :Point3D = Point3D.difference(target,position);
		//光源への距離
		var length:Number =Math.sqrt(Math.pow(zAxis.x,2)+Math.pow(zAxis.y,2)+Math.pow(zAxis.z,2));

//光源に対するZ方向(正規化)
		zAxis.normalize();

//各面の法線は、faceから直接もらう

if (vAxis) {
			//箱の方向で、各面の法線を回転
			var mtr	:Matrix3D = thisObject.transformation;
			mtr.d=0
			mtr.h=0
			mtr.l=0
			vAxis.transform(mtr)

//内積を求めて、角度に変換(0:明るい～180:暗い)
			result=Math.acos(Point3D.dot(zAxis,vAxis))
		}

return result;

}

public function lookAt(targetObject:*, vAxis:Point3D=null ):void {

var position :Point3D = thisObject.coords;
		var target	 :Point3D = targetObject.coords;

var zAxis 	 :Point3D = Point3D.difference(target,position);
		zAxis.normalize();

if (!vAxis) {
			vAxis=new Point3D(0,1,0)
		}

//var mtr	:Matrix3D = thisObject.transformation;
		//vAxis.transform(mtr)

if( modulo(zAxis) > 0.1 ) {
			var xAxis :Point3D = Point3D.cross(vAxis, zAxis);
			xAxis.normalize();
			var yAxis :Point3D = Point3D.cross( zAxis, xAxis);
			yAxis.normalize();

var look	:Matrix3D = thisObject.transformation;

var mtr:Matrix3D=new Matrix3D()
			mtr.rotate(MathUtils.toRadian(90),MathUtils.toRadian(90),MathUtils.toRadian(90))
			vAxis.transform(mtr)

look.a =	xAxis.x * thisObject.scaleX*reverseCheck(vAxis.x);
			look.e =	xAxis.y * thisObject.scaleX*reverseCheck(vAxis.x);
			look.i =	xAxis.z * thisObject.scaleX*reverseCheck(vAxis.x);
			
			look.b =	yAxis.x * thisObject.scaleY*reverseCheck(vAxis.y);
			look.f =	yAxis.y * thisObject.scaleY*reverseCheck(vAxis.y);
			look.j =	yAxis.z * thisObject.scaleY*reverseCheck(vAxis.y);
			
			look.c =	zAxis.x * thisObject.scaleZ*reverseCheck(vAxis.z);
			look.g =	zAxis.y * thisObject.scaleZ*reverseCheck(vAxis.z);
			look.k =	zAxis.z * thisObject.scaleZ*reverseCheck(vAxis.z);

var rotations:Point3D = look.getRotations();
			
			thisObject.rotationX = rotations.x;
			thisObject.rotationY = rotations.y;
			thisObject.rotationZ = rotations.z;

}

private function modulo(target:Point3D):Number {
		return Math.sqrt( target.x*target.x + target.y*target.y + target.z*target.z );
	}

private function reverseCheck(no:Number):Number {
		var result:Number=1;
		if (no<0) result=-1;
		return result;
	}
	
}

/**
 * BasicTemplate for Alternativa3D
 * Alternativa3Dを扱いやすくするためのテンプレートです
 * @author Yasu
 */
class BasicTemplate extends Sprite{
	/**
	 * シーンインスタンスです。
	 */
	public var scene:Scene3D;
	/**
	 * ビューインスタンスです。
	 */
	public var view:View;
	/**
	 * カメラインスタンスです。
	 */
	public var camera:Camera3D;
	/**
	 * カメラコントローラーです。
	 */
	public var cameraContoller:CameraController;
	
	private var _viewWidth:int;
	private var _viewHeight:int;
	private var _scaleToStage:Boolean;

/**
	 * 新しい BasicTemplate インスタンスを作成します。
	 * @param	viewWidth
	 * @param	viewHeight
	 * @param	scaleToStage
	 */
	public function BasicTemplate(viewWidth:int=640, viewHeight:int=480, scaleToStage:Boolean = true) {
		_viewWidth = viewWidth;
		_viewHeight = viewHeight;
		_scaleToStage = scaleToStage;
		
		// Creating scene
		scene = new Scene3D();
		scene.splitAnalysis = false; // not analysis for performance
		scene.root = new Object3D();
		
		// Adding camera
		camera = new Camera3D();
		camera.z = -1000;
		scene.root.addChild(camera);
		
		// camera contoller
		cameraContoller = new CameraController(this);
		cameraContoller.camera = camera;
		
		// set view
		view = new View();
		view.camera = camera;
		addChild(view);
		
		// stage
		if (stage) init();
		else addEventListener(Event.ADDED_TO_STAGE, init);
	}
	
	/**
	 * 初期化されたときに実行されるイベントです。
	 * 初期化時に実行したい処理をオーバーライドして記述します。
	 */
	protected function atInit():void {}
	
	/**
	 * 初期化されたときに実行されるイベントです。
	 * 初期化時に実行したい処理を記述します。
	 */
	private var _onInit:Function = function():void { };
	public function get onInit():Function { return _onInit; }
	public function set onInit(value:Function):void {
		_onInit = value;
	}
	
	/**
	 * Event.ENTER_FRAME 時に実行されるレンダリングのイベントです。
	 * レンダリング前に実行したい処理をオーバーライドして記述します。
	 */
	protected function atPreRender():void {}
	
	/**
	 * Event.ENTER_FRAME 時に実行されるレンダリングのイベントです。
	 * レンダリング前に実行したい処理を記述します。
	 */
	private var _onPreRender:Function = function():void{};
	public function get onPreRender():Function { return _onPreRender; }
	public function set onPreRender(value:Function):void {
		_onPreRender = value;
	}
	
	/**
	 * Event.ENTER_FRAME 時に実行されるレンダリングのイベントです。
	 * レンダリング後に実行したい処理をオーバーライドして記述します。
	 */
	protected function atPostRender():void {
	}
	
	/**
	 * Event.ENTER_FRAME 時に実行されるレンダリングのイベントです。
	 * レンダリング後に実行したい処理を記述します。
	 */
	protected var _onPostRender:Function = function():void{};
	public function get onPostRender():Function { return _onPostRender; }
	public function set onPostRender(value:Function):void {
		_onPostRender = value;
	}
	
	/**
	 * レンダリングを開始します。
	 */
	public function startRendering():void {
		addEventListener(Event.ENTER_FRAME, onRenderTick);
	}
	/**
	 * レンダリングを停止します。
	 */
	public function stopRendering():void {
		removeEventListener(Event.ENTER_FRAME, onRenderTick);
	}
	
	/**
	 * シングルレンダリング(レンダリングを一回だけ)を実行します。
	 */
	public function singleRender():void {
		onRenderTick();
	}
	
	/**
	 * @private
	 */
	private function init(e:Event = null):void {
		stage.scaleMode = StageScaleMode.NO_SCALE;
		stage.align = StageAlign.TOP_LEFT;
		stage.quality = StageQuality.HIGH;

// resize
		stage.addEventListener(Event.RESIZE, onResize);
		onResize(null);
		
		// render
		startRendering();
		
		atInit();
		_onInit();
		
	}
	
	/**
	 * @private
	 */
	private function onRenderTick(e:Event = null):void {
		atPostRender();
		_onPostRender();
		scene.calculate();
		atPreRender();
		_onPreRender();
	}
	
	/**
	 * @private
	 */
	private function onResize(event:Event = null):void {
		if (_scaleToStage) {
			view.width = stage.stageWidth;
			view.height = stage.stageHeight;
		}else {
			view.width = _viewWidth;
			view.height = _viewHeight;
		}
	}
}

Code Fullscreen

Preview Fullscreen

alexnotkin

color.style...

Goodlife :

３D

cuckoo :

alternativa3d 光线