右クリックとホイールクリック

@see http://wakuworks.jugem.jp/?eid=22
* @see http://help.adobe.com/ja_JP/AIR/1.5/jslr/flash/net/LocalConnection.html

forked:0
favorite:11
lines:47
license : MIT License
modified : 2009-11-15 22:26:18

Embed: Tweet

/**
 * @see http://wakuworks.jugem.jp/?eid=22
 * @see http://help.adobe.com/ja_JP/AIR/1.5/jslr/flash/net/LocalConnection.html
 */

package
{
	import flash.display.Loader;
	import flash.display.Sprite;
	import flash.net.URLRequest;
	import flash.text.TextField;
	
	public class MouseTest extends Sprite 
	{
		private var lc:LocalConnectionEx;
		
		public function MouseTest():void 
		{
			var tf:TextField = new TextField();
			tf.width = 200;
			tf.height = 465;
			tf.text = "右クリック、ホイールクリックしてみてね\n";
			addChild(tf);
			
			var loader:Loader = new Loader();
			var request:URLRequest = new URLRequest("http://flash-scope.com/wonderfl/ClickTest/mouse.swf");
			loader.load(request);
			
			lc = new LocalConnectionEx();
			lc.allowDomain('*');
			lc.connect("_wonderflconnection");
			
			lc.leftDown = function():void {
				tf.appendText("LeftDown\n");
			};
			lc.leftUp = function():void {
				tf.appendText("LeftUp\n");
			};
			lc.rightDown = function():void {
				tf.appendText("RightDown\n");
			};
			lc.rightUp = function():void {
				tf.appendText("RightUp\n");
			};
			lc.wheelDown = function():void {
				tf.appendText("WheelDown\n");
			};
			lc.wheelUp = function():void {
				tf.appendText("WheelUp\n");
			};
			
		}
		
	}
	
}

import flash.net.LocalConnection; 
dynamic class LocalConnectionEx extends LocalConnection  
{
}

/*=======================================================
   mouse.swf [AS2]
=======================================================*/
/*
var lc:LocalConnection = new LocalConnection();
var cl:Boolean = false, pl:Boolean = false;
var cr:Boolean = false, pr:Boolean = false;
var cw:Boolean = false, pw:Boolean = false;
var ch:String = "_wonderflconnection";

onEnterFrame = function() {
	cl  = cr = cw = false;
	
	//Down
	if(Key.isDown(1)){
			cl = true;
			if (!pl && cl) lc.send(ch, "leftDown");
	}
	if(Key.isDown(2)){
			cr = true;
			if (!pr && cr) lc.send(ch, "rightDown");
	}
	if(Key.isDown(4)){
			cw = true;
			if (!pw&& cw) lc.send(ch, "wheelDown");
	}
	
	//Up
	if (pl && !cl) lc.send(ch, "leftUp");
	if (pr && !cr) lc.send(ch, "rightUp");
	if (pw && !cw) lc.send(ch, "wheelUp");
	
	pl = cl;
	pr = cr;
	pw = cw;
}
*/

Code Fullscreen

Preview Fullscreen

Kizuna

PROT830

keim_at_Si

mash

ep91ckok

dizgid

nogud

ysformen

uwi

hacker_nwwsp.. :

クリック

coppieee :

AS2で書かれたswfを読み込んでる。