【ClickEventDispatcher】複数回クリックの判定を容易にする

ClickEventDispatcherは、
あるDisplayObjectに対して複数回のクリックが行われた時に
イベント(ClickEvent)を送出する。
例えば、ダブルクリックした時は
countプロパティが2であるイベントが送出される。
この時、一度目のクリック時にはイベントが送出されないため、
シングルクリックかダブルクリックか判定することができる。

wetcradle

forked:0
favorite:0
lines:145
license : MIT License
modified : 2010-03-20 07:54:31

Embed: Tweet

/*
ClickEventDispatcherは、
あるDisplayObjectに対して複数回のクリックが行われた時に
イベント(ClickEvent)を送出する。
例えば、ダブルクリックした時は
countプロパティが2であるイベントが送出される。
この時、一度目のクリック時にはイベントが送出されないため、
シングルクリックかダブルクリックか判定することができる。
*/

package {
	import flash.display.Sprite;
	import flash.text.TextField;
	import flash.text.TextFieldAutoSize;
	public class ClickEventDispatcherTest extends Sprite {
		private var textField:TextField;
		public function ClickEventDispatcherTest():void {
			var target:TextField = new TextField();
			target.width = 200;
			target.selectable = false;
			target.text = "これを複数回クリックして下さい";
			addChild(target);
			
			var dispatcher:ClickEventDispatcher = new ClickEventDispatcher(target);
			dispatcher.addEventListener(ClickEvent.CLICK, clickHandler);
			dispatcher.max = 3;//最大3回までとする
			
			textField = new TextField();
			textField.autoSize = TextFieldAutoSize.LEFT;
			textField.y = 30;
			addChild(textField);
		}
		private function clickHandler(e:ClickEvent):void {
			textField.appendText(String(e.count)+", ");
		}
	}
}

import flash.display.DisplayObject;
import flash.events.EventDispatcher;
import flash.events.MouseEvent;
import flash.events.TimerEvent;
import flash.utils.Timer;

/**
targetに対する複数回のクリックを検出しClickEventを送出します。
*/
class ClickEventDispatcher extends EventDispatcher {
	
	protected var _delay:Number = 200;
	protected var _max:Number = 2;
	protected var _range:Number = 5;
	protected var _enabled:Boolean = true;
	protected var _target:DisplayObject;
	
	protected var timer:Timer;
	protected var counter:int;
	protected var downInside:Boolean = false;
	protected var downX:Number;
	protected var downY:Number;
	
	////////////////////////////////////////////////////////////
	//////////////コンストラクタ
	////////////////////////////////////////////////////////////
	
	//______________ ClickEventDispatcher ______________//
	public function ClickEventDispatcher(target:DisplayObject):void {
		super();
		
		_target = target;
		target.addEventListener(MouseEvent.MOUSE_DOWN, mouseDownHandler);
		target.addEventListener(MouseEvent.ROLL_OUT, rollOutHandler);
		target.addEventListener(MouseEvent.MOUSE_UP, mouseUpHandler);
		
		timer = new Timer(delay, 1);
		timer.addEventListener(TimerEvent.TIMER_COMPLETE, timerCompleteHandler);
	}
	
	////////////////////////////////////////////////////////////
	//////////////プロパティ
	////////////////////////////////////////////////////////////
	
	//______________ target ______________//
	public function get target():DisplayObject {
		return _target;
	}
	
	//______________ delay ______________//
	public function get delay():Number {
		return _delay;
	}
	public function set delay(value:Number):void {
		_delay = value;
		timer.delay = delay;
	}
	
	//______________ max ______________//
	public function get max():int {
		return _max;
	}
	public function set max(value:int):void {
		_max = value;
	}
	
	//______________ range ______________//
	public function get range():Number {
		return _range;
	}
	public function set range(value:Number):void {
		_range = value;
	}
	
	//______________ enabled ______________//
	public function get enabled():Boolean {
		return _enabled;
	}
	public function set enabled(value:Boolean):void {
		_enabled = value;
	}
	
	////////////////////////////////////////////////////////////
	//////////////メソッド
	////////////////////////////////////////////////////////////
	
	//______________ dispatchClickEvent ______________//
	protected function dispatchClickEvent():void {
		if (enabled && counter > 0) {
			dispatchEvent(new ClickEvent(ClickEvent.CLICK, counter));
		}
		counter = 0;
	}
	
	////////////////////////////////////////////////////////////
	//////////////イベントハンドラ
	////////////////////////////////////////////////////////////
	
	//______________ mouseDownHandler ______________//
	protected function mouseDownHandler(e:MouseEvent):void {
		if (timer.running) {
			timer.stop();
		}
		else {
			counter = 0;
		}
		if (_target.stage) {
			downX = _target.stage.mouseX;
			downY = _target.stage.mouseY;
		}
		downInside = true;
	}
	
	//______________ rollOutHandler ______________//
	protected function rollOutHandler(e:MouseEvent):void {
		dispatchClickEvent();
	}
	
	//______________ mouseUpHandler ______________//
	protected function mouseUpHandler(e:MouseEvent):void {
		if (!downInside) {
			counter = 0;
			return;
		}
		downInside = false;
		if (!_target.stage) {
			counter = 0;
			return;
		}
		var maxDelta:Number = Math.max(Math.abs(_target.stage.mouseX - downX), Math.abs(_target.stage.mouseY - downY));
		if (maxDelta > _range) {
			dispatchClickEvent();
			return;
		}
		counter++;
		if (max && counter >= max) {
			dispatchClickEvent();
			return;
		}
		timer.reset();
		timer.start();
	}
	
	//______________ timerCompleteHandler ______________//
	protected function timerCompleteHandler(e:TimerEvent):void {
		dispatchClickEvent();
	}
}

import flash.events.Event;

class ClickEvent extends Event {
	
	protected var _count:int;
	
	public static const CLICK:String = "ClickEventClick";
	
	////////////////////////////////////////////////////////////
	//////////////コンストラクタ
	////////////////////////////////////////////////////////////
	
	public function ClickEvent(type:String, count:int):void {
		super(type);
		_count = count;
	}
	
	////////////////////////////////////////////////////////////
	//////////////プロパティ
	////////////////////////////////////////////////////////////
	
	//______________ count ______________//
	public function get count():int {
		return _count;
	}
	
	////////////////////////////////////////////////////////////
	//////////////パブリックメソッド
	////////////////////////////////////////////////////////////
	
	//______________ toString ______________//
	override public function toString():String {
		return formatToString("ClickEvent","type","bubbles","cancelable", "count");
	}
	
	//______________ clone ______________//
	override public function clone():Event {
		return new ClickEvent(type, count);
	}
}

Code Fullscreen

Preview Fullscreen